I_ProjectMilestoneData

@AbapCatalog.sqlViewName: 'IPROJMLSTDATA'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey:true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.representativeKey: 'ProjectMilestone'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@EndUserText.label: 'Project Milestone Data'
define view I_ProjectMilestoneData
  as select from mlst
  association [0..1] to I_Projectmilestonetext         as _Text               on  $projection.ProjectMilestone           = _Text.ProjectMilestone
                                                                              and $projection.ProjectMilestoneInternalID = _Text.ProjectMilestoneInternalID
  association [0..1] to I_ProjectNetworkBasicData      as _ProjectNetwork     on  $projection.ProjectNetworkInternalID = _ProjectNetwork.ProjectNetworkInternalID
                                                                              and _ProjectNetwork.OrderCategory        = '20'
  association [0..1] to I_NetworkActivityByInternalKey as _NetworkActivity    on  _NetworkActivity.ProjectNetworkInternalID  = $projection.ProjectNetworkInternalID
                                                                              and _NetworkActivity.NetworkActivityInternalID = $projection.NetworkActivityInternalID

  association [0..1] to I_WBSElementData_2             as _WBSElement         on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_Projectmilestoneusage        as _UsageText          on  $projection.UsageCode = _UsageText.UsageCode
  association [1..1] to E_ProjectMilestone             as _Extension          on  mlst.mlst_zaehl = _Extension.ProjectMilestone
  // Multilanguage Short text

  association [0..1] to I_ProjectObjectShortText       as _MilestoneShortText on  _MilestoneShortText.Language                     = $session.system_language
                                                                              and _MilestoneShortText.ProjectApplicationIdentifier = 'PS'
                                                                              and (
                                                                                 _MilestoneShortText.ProjectObjectType             = 'MW'
                                                                                 or _MilestoneShortText.ProjectObjectType          = 'ML'
                                                                               )
                                                                              and $projection.ProjectMilestone                     = _MilestoneShortText.RelatedProjectObject
  association [0..*] to I_SystemStatusText             as _SystemStatusText   on  _SystemStatusText.Language = $session.system_language
  association [0..*] to I_UserStatusText               as _UserStatusText     on  _UserStatusText.Language = $session.system_language

  //added 27.07.2023

  association [0..1] to I_StatusProfile                as _StatusProfile      on  _StatusProfile.StatusProfile = $projection.StatusProfile

{

      @EndUserText.label: 'Milestone Number'
  key mlst.mlst_zaehl                                   as ProjectMilestone,
      @ObjectModel.text.association: '_Text'
  key mlst.zaehl                                        as ProjectMilestoneInternalID,
      cast (mlst.loekz as ps_s4_loevm)                  as IsDeleted,
      mlst.mlstn                                        as UsageCode,
      mlst.aufpl                                        as ProjectNetworkInternalID,
      mlst.aplzl                                        as NetworkActivityInternalID,
      cast (mlst.pspnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      @Semantics.calendar.dayOfMonth: true
      cast(mlst.tedat as ps_s4_mlst_tedat)              as ScheduledBasicDate,
      @Semantics.calendar.dayOfMonth: true
      cast(mlst.edatu as lop_fix_date)                  as FixedBasicDate,
      @Semantics.calendar.dayOfMonth: true
      cast(mlst.tpdat as ps_s4_mlst_tpdat)              as ScheduledForecastedDate,
      @Semantics.calendar.dayOfMonth: true
      cast(mlst.pdatu as ps_s4_mlst_pdatu)              as ForecastedFixedDate,

      cast(mlst.kz_trend as ps_s4_mlst_trend)           as MlstnIsRelevantForTrendAnlys,

      cast(mlst.kz_lstwr as ps_s4_mlst_lstwr)           as MlstnIsRelevantForPrgrsAnlys,

      cast(mlst.kz_faktp as ps_s4_mlst_faktp)           as MlstnIsRelevantForDteInSlsDoc,
      @Semantics.calendar.dayOfMonth: true
      cast (mlst.lst_actdt as ppe_actual_date)          as ActualEndDate,
      cast(mlst.autyp as cowb_autyp)                    as OrderCategory,

      @Semantics.calendar.dayOfMonth: true
      cast (mlst.dateh as erdat)                        as CreationDate,
      @Semantics.calendar.dayOfMonth: true
      @Semantics.businessDate.lastChangedAt
      cast (mlst.datev as ps_s4_updat)                  as LastChangeDate,
      cast (mlst.userh as ernam)                        as CreatedByUser,
      cast (mlst.userv as ps_s4_aenam)                  as LastChangedByUser,

      cast(mlst.relsu as ps_s4_mlst_relsu)              as MlstnIsMarkedForRelFllwngActy,
      cast(mlst.relms as ps_s4_mlst_relms)              as MlstnIsMarkedForRelUptoStopInd,
      cast(mlst.incsn as ps_s4_mlst_incsn)              as MlstnIsMarkedForIncludeStdNtwk,
      cast(mlst.incnw as ps_s4_mlst_incnw)              as MlstnIsMarkedForCreateNtwk,
      cast(mlst.incpn as ps_s4_mlst_incpn)              as MlstnIsMarkedForIncludeSubNtwk,
      cast(mlst.wkflw  as ps_s4_mlst_wkflw)             as MlstnIsMarkedForStrtWrkflwTsk,

      cast(mlst.kz_frmst as ps_s4_kz_frmst)             as MlstnReleaseStopIsActive,

      cast(mlst.kz_wflow as ps_s4_mlst_wflow)           as MlstnIsUsedforMlstnFunc,
      cast (mlst.begru as begru)                        as AuthorizationGroup,

      cast(mlst.dltas as ps_s4_mlst_dltas)              as DateIsOffsetToParentEndDate,
      cast(mlst.prcnt as ps_s4_mlst_prcnt)              as MlstnDateOffsetPercent,
      @Semantics.unitOfMeasure: true
      cast(mlst.delte as ps_s4_mlst_delte)              as MlstnDateOffsetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'MlstnDateOffsetDurationUnit'
      mlst.delta                                        as MlstnDateOffsetDuration,
      cast(mlst.lated as ps_s4_mlst_late)               as DateIsOffsetToParentLtstDates,
      cast(lst_fertg as ps_s4_cgpl_completion)          as CompletionRateInPercent,
      cast(fproz as fproz)                              as ProjCostToBeInvoicedPercent,
      @EndUserText.label: 'Workflow Task'
      mlst.task_id                                      as WorkflowTask,

      mlst.lst_acttm                                    as ActualMilestoneTime,
      mlst.pzeit                                        as FixedForecastMilestoneTime,
      mlst.ezeit                                        as FixedBasicMilestoneTime,
      mlst.tptim                                        as ScheduledForecastMilestoneTime,
      mlst.tetim                                        as ScheduledBasicMilestoneTime,

      //Added 27.07.2023

      mlst.relsu_ss                                     as SystStsForRelFllwngActivities,
      mlst.relms_ss                                     as SystStsForRelUpToStopIndCode,
      mlst.incsn_ss                                     as SystStsForIncldStandardNetwork,
      mlst.incnw_ss                                     as SystemStatusForCreateNetwork,
      mlst.incpn_ss                                     as SystStatusForIncludeSubNetwork,
      mlst.wkflw_ss                                     as SystStatusForStartWorkflowTask,

      mlst.relsu_us                                     as UserStsForRelFllwngActivities,
      mlst.relms_us                                     as UserStsForRelUpToStopIndCode,
      mlst.incsn_us                                     as UserStsForIncldStandardNetwork,
      mlst.incnw_us                                     as UserStatusForCreateNetwork,
      mlst.incpn_us                                     as UserStatusForIncludeSubNetwork,
      mlst.wkflw_us                                     as UserStatusForStartWorkflowTask,

      mlst.relsu_sm                                     as SelPrflForRelFllwngActivities,
      mlst.relms_sm                                     as SelPrflForRelUpToStopIndCode,
      mlst.incsn_sm                                     as SelPrflForIncldStandardNetwork,
      mlst.incnw_sm                                     as SelProfileForCreateNetworkCode,
      mlst.incpn_sm                                     as SelProfileForIncludeSubNetwork,
      mlst.wkflw_sm                                     as SelProfileForStartWorkflowTask,

      mlst.relsu_ch                                     as StsChgForRelFllwngActivities,
      mlst.relms_ch                                     as StsChgForRelUpToStopIndCode,
      mlst.incsn_ch                                     as StsChgForIncldStandardNetwork,
      mlst.incnw_ch                                     as StatusChangeForCreateNetwork,
      mlst.incpn_ch                                     as StsChangeForIncludeSubNetwork,
      mlst.wkflw_ch                                     as StsChangeForStartWorkflowTask,

      mlst.relsu_sg                                     as MlstnIsRelFllwngActiesExecOnce,
      mlst.relms_sg                                     as MlstnIsRelUpToStpIndExectOnce,
      mlst.incsn_sg                                     as MlstnIsIncldStdNtwkExecuteOnce,
      mlst.incnw_sg                                     as MlstnIsCrteNtwkExectOnce,
      mlst.incpn_sg                                     as MlstnIsIncldSubNtwkExecuteOnce,
      mlst.wkflw_sg                                     as MlstnIsStrtWrkflwTskExectOnce,

      mlst.relsu_tr                                     as ActvtFuncForRelFllwngActies,
      mlst.relms_tr                                     as ActvtFuncForRelUpToStopIndCode,
      mlst.incsn_tr                                     as ActvtFuncForIncldStdNetwork,
      mlst.incnw_tr                                     as ActvtFuncForCreateNetwork,
      mlst.incpn_tr                                     as ActvtFuncForIncludeSubNetwork,
      mlst.wkflw_tr                                     as ActvtFuncForStartWorkflowTask,

      mlst.stdnr_icsn                                   as StdNtwkForIncldStandardNetwork,
      mlst.altnr_icsn                                   as AltvStdNtwkForIncldStdNetwork,
      cast(mlst.oprst_icsn as char4 preserving type)    as NtwkActyPrecdgStdNtwkToBeIncld,
      cast(mlst.opren_icsn as char4 preserving type)    as NtwkActyFllwngStdNtwkToBeIncld,

      mlst.auart_icnw                                   as StdNetworkTypeForCreateNetwork,
      mlst.stdnr_icnw                                   as StdNetworkForCreateNetwork,
      mlst.altnr_icnw                                   as AltvStdNetworkForCreateNetwork,

      mlst.stdnr_icpn                                   as StdNetworkForIncludeSubNetwork,
      mlst.altnr_icpn                                   as AltStdNtwkForIncludeSubNetwork,
      cast(mlst.vornr_icpn as char4 preserving type)    as NtwkActyForIncludeSubNetwork,

      mlst.stsma                                        as StatusProfile,

      _StatusProfile.MasterLanguage                     as MasterLanguage,

      //Associations

      _Text,
      _ProjectNetwork,
      _NetworkActivity,
      _WBSElement,
      _UsageText,
      _MilestoneShortText,
      _SystemStatusText,
      _UserStatusText,

      //Added 27.07.2023

      _StatusProfile
}
where
     mlst.pspnr <> '00000000'
  or mlst.aplzl <> '00000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STATUSPROFILE",
"MLST"
],
"ASSOCIATED":
[
"E_PROJECTMILESTONE",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_PROJECTMILESTONETEXT",
"I_PROJECTMILESTONEUSAGE",
"I_PROJECTNETWORKBASICDATA",
"I_PROJECTOBJECTSHORTTEXT",
"I_STATUSPROFILE",
"I_SYSTEMSTATUSTEXT",
"I_USERSTATUSTEXT",
"I_WBSELEMENTDATA_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/