I_ProjectDemandWorkPackageText

@EndUserText.label: 'Textual information for work packages including project data'
@AbapCatalog: { 
    sqlViewName: 'IPRJDMNWPGTXT',
    compiler.compareFilter: true,
    dataMaintenance: #RESTRICTED,
    preserveKey:true
}

@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   semanticKey:       [ 'ProjectElement' ],
   representativeKey: 'ProjectElementUUID',
   dataCategory: #TEXT,   
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #L
    }
} 

define view I_ProjectDemandWorkPackageText as 
        select from R_PPM_ProjectTask as Element                 
        
    association [1..1] to I_EnterpriseProjectElement  as _ProjectElement    on $projection.ProjectElementUUID = _ProjectElement.ProjectElementUUID
    association [1..1] to I_EnterpriseProject         as _Project           on $projection.ProjectUUID = _Project.ProjectUUID 
    association [0..*] to I_PPM_ProcessingStatusText  as _StatusText        on $projection.ProcessingStatus = _StatusText.ProcessingStatus
    
{
  @UI.facet: [
   {
     purpose: #QUICK_VIEW,
     type: #FIELDGROUP_REFERENCE,
     targetQualifier: 'WPPOPOVER'
   }
]
//    @UI.hidden: true  

    @UI.textArrangement: #TEXT_ONLY
    @ObjectModel.text.element: 'ProjectElementDescription'
    @EndUserText.label: 'WBS Element'
    key Element.ProjectElementUUID,   

    @UI.textArrangement: #TEXT_FIRST
    @ObjectModel.text.element: 'ProjectElementDescription'
    
    @EndUserText.label: 'WBS Element'
     @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER', position: 10}]
  }
    cast( Element.ProjectElement as tv_proj_dmnd_wrkpkg preserving type )   as ProjectElement,
    
    @Semantics.text: true
    @EndUserText.label: 'WBS Element Description'
    @EndUserText.quickInfo: 'WBS Element Description'
      @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER', position: 20}]
  }
    Element.ProjectElementDescription,
    @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER', position: 30}]
  }
    Element.PlannedStartDate,
  @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER', position: 40}]
  }
    Element.PlannedEndDate,
    
    Element.WBSElementInternalID,
    
 
     @EndUserText.label: 'ProjectUUID' 
    Element.ProjectUUID as ProjectUUID,
       
    
    cast( Element._EnterpriseProject.Project as tv_proj_dmnd_project preserving type )     as Project,
    
    Element.ProjectInternalID,
    
    @Semantics.text: true
    @EndUserText.label: 'Project Description'
    Element._EnterpriseProject.ProjectDescription as ProjectDescription,

    Element._EnterpriseProject.ProjectStartDate,

    Element._EnterpriseProject.ProjectEndDate,
        
    // Only for auth check    

    @Consumption.hidden: true
    Element.ControllingArea,
    @Consumption.hidden: true
      @UI: {
      fieldGroup:     [{ qualifier:'WPPOPOVER', position: 50}]
  }
    Element.ProfitCenter,
    
    //CE2308 - Further fields added for auth check

    @Consumption.hidden: true
    Element.CompanyCode,
    
    @Consumption.hidden: true
    Element.ResponsibleCostCenter,
    
    @Consumption.hidden: true
    Element.Plant,
    
    @Consumption.hidden: true
    Element.FunctionalArea,
    
    // Used in value help for object selecton only    

    @Consumption.hidden: true    
    @ObjectModel.foreignKey.association: '_ProcessingStatus'
    @ObjectModel.text.association: '_StatusText'
    Element.ProcessingStatus,
    
    _Project,
    _ProjectElement,
    _ProcessingStatus,
    _StatusText,
    
    Element._ControllingArea,
    Element._ProfitCenter

    
} where Element._EnterpriseProject.ProjectCategory = '6' 
  and   Element.WBSElementInternalID <> '00000000' // not a milestone

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_ENTERPRISEPROJECT",
"R_PPM_PROJECTTASK"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_ENTERPRISEPROJECT",
"I_ENTERPRISEPROJECTELEMENT",
"I_PPM_PROCESSINGSTATUS",
"I_PPM_PROCESSINGSTATUSTEXT",
"I_PROFITCENTER"
],
"BASE":
[
"R_PPM_PROJECTTASK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/