I_ProjectClaimsCause

DDL: I_PROJECTCLAIMSCAUSE Type: view BASIC

Project Claims Cause

I_ProjectClaimsCause is a Basic CDS View that provides data about "Project Claims Cause" in SAP S/4HANA. It reads from 1 data source (qmur) and exposes 11 fields with key fields ProjectClaim, ProjectClaimCauseItem, ProjectClaimCauseIdentifier. It has 4 associations to related views.

1 data source(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
qmur qmur from

Associations (4)

CardinalityTargetAliasCondition
[1..1] I_ProjectClaim _ProjectClaim $projection.ProjectClaim = _ProjectClaim.ProjectClaim
[0..1] I_NotifCauseCodeCatalog _NotifCauseCodeCatalog $projection.ProjectClaimCauseCodeCatalog = _NotifCauseCodeCatalog.NotificationCauseCodeCatalog
[0..1] I_NotifCauseCodeGroup _NotifCauseCodeGroup $projection.ProjectClaimCauseCodeCatalog = _NotifCauseCodeGroup.NotificationCauseCodeCatalog and $projection.ProjectClaimCauseCodeGroup = _NotifCauseCodeGroup.NotificationCauseCodeGroup
[0..1] I_NotifCauseCode _NotifCauseCode $projection.ProjectClaimCauseCodeCatalog = _NotifCauseCode.NotificationCauseCodeCatalog and $projection.ProjectClaimCauseCodeGroup = _NotifCauseCode.NotificationCauseCodeGroup and $projection.ProjectClaimCauseCode = _NotifCauseCode.NotificationCauseCode

Annotations (11)

NameValueLevelField
EndUserText.label Project Claims Cause view
AbapCatalog.sqlViewName IPRJCLMCAUSE view
VDM.viewType #BASIC view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
AccessControl.personalData.blocking #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Search.searchable true view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.representativeKey ProjectClaim view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY ProjectClaim qmur qmnum
KEY ProjectClaimCauseItem qmur fenum
KEY ProjectClaimCauseIdentifier qmur urnum
ProjectClaimCauseCodeCatalog qmur urkat
ProjectClaimCauseCodeGroup qmur urgrp
ProjectClaimCauseCode qmur urcod
ProjectClaimCauseText qmur urtxt
_NotifCauseCodeCatalog _NotifCauseCodeCatalog
_NotifCauseCodeGroup _NotifCauseCodeGroup
_NotifCauseCode _NotifCauseCode
_ProjectClaim _ProjectClaim 
@EndUserText.label: 'Project Claims Cause'
@AbapCatalog: {
                sqlViewName: 'IPRJCLMCAUSE',
                compiler.compareFilter,
                preserveKey
              }
@VDM:{
       viewType: #BASIC
     }
@AccessControl:{
                 authorizationCheck: #PRIVILEGED_ONLY,
                 personalData.blocking: #NOT_REQUIRED
               }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@ObjectModel:{
               usageType:{
                           sizeCategory: #L,
                           serviceQuality: #C,
                           dataClass:#TRANSACTIONAL
                         },
               representativeKey: 'ProjectClaim'
             }

define view I_ProjectClaimsCause
  as select from qmur
  association [1..1] to I_ProjectClaim as _ProjectClaim on $projection.ProjectClaim = _ProjectClaim.ProjectClaim
  association [0..1] to I_NotifCauseCodeCatalog as _NotifCauseCodeCatalog on  $projection.ProjectClaimCauseCodeCatalog = _NotifCauseCodeCatalog.NotificationCauseCodeCatalog
  association [0..1] to I_NotifCauseCodeGroup   as _NotifCauseCodeGroup   on  $projection.ProjectClaimCauseCodeCatalog = _NotifCauseCodeGroup.NotificationCauseCodeCatalog
                                                                          and $projection.ProjectClaimCauseCodeGroup   = _NotifCauseCodeGroup.NotificationCauseCodeGroup
  association [0..1] to I_NotifCauseCode        as _NotifCauseCode        on  $projection.ProjectClaimCauseCodeCatalog = _NotifCauseCode.NotificationCauseCodeCatalog
                                                                          and $projection.ProjectClaimCauseCodeGroup   = _NotifCauseCode.NotificationCauseCodeGroup
                                                                          and $projection.ProjectClaimCauseCode        = _NotifCauseCode.NotificationCauseCode

{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key qmur.qmnum                                                                                            as ProjectClaim,

  key qmur.fenum                                                                                            as ProjectClaimCauseItem,

  key qmur.urnum                                                                                            as ProjectClaimCauseIdentifier,

      @ObjectModel.foreignKey.association: '_NotifCauseCodeCatalog'
      qmur.urkat                                                                                            as ProjectClaimCauseCodeCatalog,

      @ObjectModel.foreignKey.association: '_NotifCauseCodeGroup'
      qmur.urgrp                                                                                            as ProjectClaimCauseCodeGroup,

      @ObjectModel.foreignKey.association: '_NotifCauseCode'
      qmur.urcod                                                                                            as ProjectClaimCauseCode,

      @Semantics.text: true
      qmur.urtxt                                                                                            as ProjectClaimCauseText,

      _NotifCauseCodeCatalog,
      _NotifCauseCodeGroup,
      _NotifCauseCode,
      _ProjectClaim

}

where
_ProjectClaim.ProjectClaimOrigin = 'C1' or
_ProjectClaim.ProjectClaimOrigin = 'C2'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTCLAIM",
"QMUR"
],
"ASSOCIATED":
[
"I_NOTIFCAUSECODE",
"I_NOTIFCAUSECODECATALOG",
"I_NOTIFCAUSECODEGROUP",
"I_PROJECTCLAIM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More