I_ProjectByExternalID

@AbapCatalog.sqlViewName: 'IPROJBYEXTKEY'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@Analytics: { dataCategory: #DIMENSION }
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations:true 
@EndUserText.label: 'Project by formatted external ID'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    compositionRoot: true,
    //Keys

    representativeKey: 'ProjectExternalID',
    //semanticKey: [ 'Project' ],

    
    usageType: {
        serviceQuality: #B,
        sizeCategory : #L,
        dataClass: #TRANSACTIONAL
    },
    
    supportedCapabilities: [ #ANALYTICAL_DIMENSION ]
}
define view I_ProjectByExternalID as select from proj
  association [0..1] to I_WBSElementBasicData     as _RootWBSElement          on  $projection.ProjectInternalID = _RootWBSElement.ProjectInternalID 
                                                                                  and $projection.ProjectExternalID = _RootWBSElement.WBSElementExternalID    
                                                                                  
  association [0..*] to I_WBSElementBasicData as _WBSElement      on  $projection.ProjectInternalID = _WBSElement.ProjectInternalID
  association [0..1] to I_CompanyCode         as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea     as _ControllingArea on  $projection.ControllingArea = _ControllingArea.ControllingArea
  //association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea

  association [0..*] to I_ProfitCenter        as _ProfitCenter    on  $projection.ControllingArea  =  _ProfitCenter.ControllingArea
                                                                  and $projection.ProfitCenter     =  _ProfitCenter.ProfitCenter
                                                                  //and $projection.PlannedStartDate <= _ProfitCenter.ValidityEndDate

                                                                  //and $projection.PlannedStartDate >= _ProfitCenter.ValidityStartDate

  association [0..1] to I_AvailabilityCtrlProfile as _AvailabilityCtrlProfile     on  $projection.AvailabilityControlProfile = _AvailabilityCtrlProfile.AvailabilityControlProfile                     
{
      @ObjectModel.text.element: 'ProjectDescription'
  key proj.pspid_edit                                            as ProjectExternalID,
  cast ( proj.pspnr as ps_s4_proj_pspnr preserving type )        as ProjectInternalID,
      @Semantics.text: true
      cast ( proj.post1 as ps_s4_proj_post1_v1 preserving type  )as ProjectDescription,
      proj.profl                                                 as ProjectProfileCode,

      //Organisational fields

      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast ( proj.vbukr as bukrs preserving type )               as CompanyCode,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      cast ( proj.vkokr as kokrs preserving type )               as ControllingArea,
      //@ObjectModel.foreignKey.association: '_FunctionalArea'

      cast ( proj.func_area as fkber preserving type )       as FunctionalArea,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      proj.prctr                                             as ProfitCenter,

      //Dimensions

      proj.objnr                                             as ProjectObject,

      //Dates

      @Semantics.calendar.dayOfMonth: true
      proj.plfaz                                             as PlannedStartDate,
      @Semantics.calendar.dayOfMonth: true
      proj.plsez                                             as PlannedEndDate,
      
      proj.avc_profile                                       as AvailabilityControlProfile,
      proj.avc_active                                        as AvailabilityControlIsActive,
      proj.jibcl                                             as JntIntrstBillgClass,
      proj.jibsa                                             as JntIntrstBillgSubClass,
      @Consumption.hidden: true
      proj.werks                                             as Plant, 

      //Associations

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _WBSElement,
      _CompanyCode,
      _ControllingArea,
      //_FunctionalArea,

      @Consumption.filter.businessDate.at : true
      _ProfitCenter,
      @Consumption.hidden: true
      _RootWBSElement
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PROJ"
],
"ASSOCIATED":
[
"I_AVAILABILITYCTRLPROFILE",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_PROFITCENTER",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/