I_ProjSchedMaintOrderData

@AbapCatalog.sqlViewName: 'IPRSCMAINTORD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@EndUserText.label: 'Project Schedule Data for Work Order'
define view I_ProjSchedMaintOrderData
  as select from afko
    inner join   aufk on afko.aufnr = aufk.aufnr
  association [0..1] to I_OrderType                    as _OrderType                    on  $projection.OrderType = _OrderType.OrderType
  association [0..1] to I_ProjectBasicData             as _Project                      on  $projection.ProjectInternalID = _Project.ProjectInternalID

  association [1..1] to I_NetworkActivityByInternalKey as _NetworkActivityByInternalKey on  $projection.SuperiorProjectNetworkIntID    = _NetworkActivityByInternalKey.ProjectNetworkInternalID
                                                                                        and $projection.SuperiorNtwkActivityInternalID = _NetworkActivityByInternalKey.NetworkActivityInternalID
  association [1..1] to I_Plant                        as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Prioritycode                 as _PriorityCode                 on  $projection.PriorityCode = _PriorityCode.PriorityCode
  association [0..1] to I_ControllingArea              as _ControllingArea              on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BusinessArea                 as _BusinessArea                 on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..*] to I_ProfitCenter                 as _ProfitCenter                 on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                        and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..*] to I_CostCenterText               as _ResponsibleCostCenterText    on  $projection.ControllingArea                  = _ResponsibleCostCenterText.ControllingArea
                                                                                        and $projection.ResponsibleCostCenter            = _ResponsibleCostCenterText.CostCenter
                                                                                        and _ResponsibleCostCenterText.ValidityStartDate <= $session.system_date
                                                                                        and _ResponsibleCostCenterText.ValidityEndDate   >= $session.system_date
  //  association [0..1] to I_MaintenanceOrder             as _MaintenanceOrder             on  $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder

  association [0..1] to I_WBSElementData_2             as _WBSElementData               on  _WBSElementData.WBSElementInternalID = $projection.WBSElementInternalID
  association [0..*] to I_SchedulingTypeText           as _SchedulingTypeText           on _SchedulingTypeText.SchedulingType = $projection.BasicSchedulingType
{
  key afko.aufnr                                       as MaintenanceOrder,
      afko.aufpl                                       as OrderInternalBillOfOperations,
      afko.plart                                       as ProdAvailyCheckPlanningType,
      cast( afko.pronr as ps_pspnr )                   as ProjectInternalID,
      aufk.autyp                                       as OrderCategory,
      aufk.kokrs                                       as ControllingArea,
      aufk.auart                                       as OrderType,
      cast(aufk.ktext as pph_auftext preserving type)  as OrderDescription,
      afko.aufnt                                       as SuperiorProjectNetwork,
      afko.aufpt                                       as SuperiorProjectNetworkIntID,
      afko.aplzt                                       as SuperiorNtwkActivityInternalID,
      aufk.vaplz                                       as MainWorkCenter,
      aufk.kdauf                                       as SalesOrder,
      aufk.kdpos                                       as SalesOrderItem,
      aufk.bukrs                                       as CompanyCode,
      aufk.gsber                                       as BusinessArea,
      cast(aufk.pspel as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      aufk.objnr                                       as ObjectInternalID,
      aufk.prctr                                       as ProfitCenter,
      afko.gstrp                                       as PlannedStartDate,
      afko.gltrp                                       as PlannedEndDate,
      afko.gstrs                                       as ScheduledBasicStartDate,
      afko.gltrs                                       as ScheduledBasicEndDate,
      afko.gstri                                       as ActualStartDate,
      afko.getri                                       as ActualEndDate,
      afko.aprio                                       as PriorityCode,
      aufk.loekz                                       as IsMarkedForDeletion,
      afko.gstpp                                       as ForecastedStartDate,
      afko.gltpp                                       as ForecastedEndDate,
      afko.gstps                                       as ScheduledForecastedStartDate,
      afko.gltps                                       as ScheduledForecastedEndDate,
      aufk.erdat                                       as CreationDate,
      aufk.ernam                                       as CreatedByUser,
      aufk.aedat                                       as LastChangeDate,
      aufk.kostl                                       as CostCenter,
      aufk.kostv                                       as ResponsibleCostCenter,
      afko.terkz                                       as BasicSchedulingType,
      aufk.wawrk                                       as MainWorkCenterPlant,
      //Add Properties for DCL

      aufk.werks                                       as Plant,
      afko.dispo                                       as MRPController,
      _OrderType,
      _Project,
      _NetworkActivityByInternalKey,
      _Plant,
      _PriorityCode,
      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _ProfitCenter,
      _ResponsibleCostCenterText,
      _WBSElementData,
      _SchedulingTypeText
      //      _MaintenanceOrder

}
where
  aufk.autyp = '30'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AFKO",
"AUFK"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTERTEXT",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_ORDERTYPE",
"I_PLANT",
"I_PRIORITYCODE",
"I_PROFITCENTER",
"I_PROJECTBASICDATA",
"I_SCHEDULINGTYPETEXT",
"I_WBSELEMENTDATA_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/