I_ProjSchedMaintOrderBasicData

@AbapCatalog.sqlViewName: 'IPRSCMAINTORDBD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
//@VDM.private: true

@VDM.viewType: #BASIC
@EndUserText.label: 'Project Schedule Data for Work Order Basic'
define view I_ProjSchedMaintOrderBasicData
  as select from afih
  association [0..1] to I_MaintenancePlannerGroup     as _MaintenancePlannerGroup     on  $projection.MaintenancePlannerGroup  = _MaintenancePlannerGroup.MaintenancePlannerGroup
                                                                                      and $projection.MaintenancePlanningPlant = _MaintenancePlannerGroup.MaintenancePlanningPlant
  association [0..1] to I_WorkCenter                  as _MainWorkCenter              on  $projection.WorkCenterInternalID = _MainWorkCenter.WorkCenterInternalID
                                                                                      and $projection.WorkCenterTypeCode   = _MainWorkCenter.WorkCenterTypeCode
  association [0..*] to I_GenericPriorityText         as _PriorityText                on  _PriorityText.GenericPriorityType = $projection.MaintPriorityType
                                                                                      and _PriorityText.PriorityCode        = $projection.MaintPriority
  association [0..1] to I_EAMProcessPhase             as _EAMProcessPhase             on  $projection.MaintOrdProcessPhaseCode = _EAMProcessPhase.EAMProcessPhaseCode
  association [0..1] to I_EAMProcessSubPhase          as _EAMProcessSubPhase          on  $projection.MaintOrdProcessSubPhaseCode = _EAMProcessSubPhase.EAMProcessSubPhaseCode
  association [0..1] to I_ProjSchedMaintOrdRespPerson as _ProjSchedMaintOrdRespPerson on  $projection.MaintOrdPersonResponsible = _ProjSchedMaintOrdRespPerson.MaintOrdPersonResponsible

{
  key afih.aufnr                                                    as MaintenanceOrder,
      afih.ingpr                                                    as MaintenancePlannerGroup,
      afih.priok                                                    as MaintPriority,
      afih.artpr                                                    as MaintPriorityType,
      afih.qmnum                                                    as MaintenanceNotification,
      afih.maintordpersonresponsible                                as MaintOrdPersonResponsible,
      afih.iwerk                                                    as MaintenancePlanningPlant,
      cast( afih.ilart as eam_maint_activity_type preserving type ) as MaintenanceActivityType,
      afih.gewrk                                                    as WorkCenterInternalID,
      afih.pm_objty                                                 as WorkCenterTypeCode,
      afih.anlzu                                                    as OperationSystemCondition,
      cast(afih.lacd_date as vdm_lacd_date preserving type )        as LatestAcceptableCompletionDate,
      afih.maintordovrlprocphase                                    as MaintOrdProcessPhaseCode,
      afih.maintordovrlprocsubphase                                 as MaintOrdProcessSubPhaseCode,

      _MainWorkCenter,
      _MaintenancePlannerGroup,
      _PriorityText,
      _EAMProcessPhase,
      _EAMProcessSubPhase,
      _ProjSchedMaintOrdRespPerson
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AFIH"
],
"ASSOCIATED":
[
"I_EAMPROCESSPHASE",
"I_EAMPROCESSSUBPHASE",
"I_GENERICPRIORITYTEXT",
"I_MAINTENANCEPLANNERGROUP",
"I_PROJSCHEDMAINTORDRESPPERSON",
"I_WORKCENTER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/