I_ProjDmndRsceReqDistribution

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #PUBLIC_LOCAL_API

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@AbapCatalog: {
    sqlViewName: 'IPRJDMNDRSCERD',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE ],
   representativeKey: 'ProjDmndRsceReqDistrUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Analytics: {
  dataExtraction: { 
    enabled: true,
    delta.changeDataCapture: {
      automatic: true
    }
  }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Resource Req Distribution for Rsce Dmnd'

define view I_ProjDmndRsceReqDistribution
  as select from R_ProjDmndRsceReqDistribution

  association [1]    to I_ProjectDemand                as _Root                        on $projection.ProjectDemandUUID = _Root.ProjectDemandUUID  
  association [1]    to I_ProjectDemandResourceRequest as _ProjDmndRsceReq             on $projection.ProjDmndResourceRequestUUID = _ProjDmndRsceReq.ProjDmndResourceRequestUUID

  association [0..1] to I_UnitOfMeasure                as _ProjDmndRsceReqDistrQtyUnit on $projection.ProjDmndRsceReqDistrQtyUnit = _ProjDmndRsceReqDistrQtyUnit.UnitOfMeasure
  association [0..1] to I_Currency                     as _DmndRsceReqDistrPerdAmtCur  on $projection.ProjDmndRsceReqDistrPerdAmtCur = _DmndRsceReqDistrPerdAmtCur.Currency
  association [0..1] to I_Currency                     as _DmndRsceReqDistrRevnAmtCur  on $projection.ProjDmndRsceReqDistrRevnAmtCur = _DmndRsceReqDistrRevnAmtCur.Currency

{
  key ProjDmndRsceReqDistrUUID       as ProjDmndRsceReqDistrUUID,
      ProjDmndResourceRequestUUID    as ProjDmndResourceRequestUUID,      
      ProjectDemandUUID              as ProjectDemandUUID,
      ProjDmndRsceReqDistrYearVal    as ProjDmndRsceReqDistrYearVal,
      ProjDmndRsceReqDistrPerdVal    as ProjDmndRsceReqDistrPerdVal,

      @Semantics: { quantity : {unitOfMeasure: 'ProjDmndRsceReqDistrQtyUnit'} }
      ProjDmndRsceReqDistrQuantity   as ProjDmndRsceReqDistrQuantity,

      ProjDmndRsceReqDistrQtyUnit    as ProjDmndRsceReqDistrQtyUnit,

      @Semantics: { amount : {currencyCode: 'ProjDmndRsceReqDistrPerdAmtCur'} }
      ProjDmndRsceReqDistrPerdAmt    as ProjDmndRsceReqDistrPerdAmt,

      @ObjectModel.foreignKey.association:    '_DmndRsceReqDistrPerdAmtCur'
      ProjDmndRsceReqDistrPerdAmtCur as ProjDmndRsceReqDistrPerdAmtCur,

      @Semantics: { amount : {currencyCode: 'ProjDmndRsceReqDistrRevnAmtCur'} }
      ProjDmndRsceReqDistrRevenueAmt as ProjDmndRsceReqDistrRevenueAmt,

      @ObjectModel.foreignKey.association:    '_DmndRsceReqDistrRevnAmtCur'
      ProjDmndRsceReqDistrRevnAmtCur as ProjDmndRsceReqDistrRevnAmtCur,

      ProjDmndRsceReqDistrStartDate  as ProjDmndRsceReqDistrStartDate,
      ProjDmndRsceReqDistrEndDate    as ProjDmndRsceReqDistrEndDate,

      @Semantics.user.createdBy: true
      CreatedByUser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime               as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime             as LastChangeDateTime,

      /* BO internal Associations */
      _Root,
      _ProjDmndRsceReq,

      /* External Associations */
      _ProjDmndRsceReqDistrQtyUnit,
      _DmndRsceReqDistrPerdAmtCur,
      _DmndRsceReqDistrRevnAmtCur
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PROJDMNDRSCEREQDISTRIBUTION"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_PROJECTDEMAND",
"I_PROJECTDEMANDRESOURCEREQUEST",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/