I_ProfitCenterForCompanyCode

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.sqlViewName: 'IFIPRCTRBUKRS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Profit Center For Company Code'
@Analytics: { dataCategory: #DIMENSION }
@AccessControl.privilegedAssociations:  [ '_ProfitCenterHierarchyNode']
@Metadata.allowExtensions: true
@ObjectModel.representativeKey: 'ProfitCenter'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #M
}
@Search.searchable: true
@Consumption.filter.businessDate.at: true

define view I_ProfitCenterForCompanyCode as select from I_ProfitCenter 
                                            inner join tka02 on I_ProfitCenter.ControllingArea = tka02.kokrs
                                            
association [1..1] to I_CompanyCode               as _CompanyCode             on  $projection.CompanyCode = _CompanyCode.CompanyCode

association [1..1] to I_ProfitCenter              as _ProfitCenter            on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                              and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                              and $projection.ValidityEndDate = _ProfitCenter.ValidityEndDate

association[1..1] to E_ProfitCenter               as _Extension               on  $projection.ControllingArea   = _Extension.ControllingArea
                                                                              and $projection.ProfitCenter      = _Extension.ProfitCenter
                                                                              and $projection.ValidityEndDate   = _Extension.ValidityEndDate
                                            
{
@Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
@ObjectModel.foreignKey.association: '_CompanyCode'
key tka02.bukrs as CompanyCode,

@Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ProfitCenterVH',
                     element: 'ProfitCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
@ObjectModel.text.association: '_Text'
@ObjectModel.hierarchy.association: '_ProfitCenterHierarchyNode'
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
key I_ProfitCenter.ProfitCenter,
 
@Semantics.businessDate.to: true 
key I_ProfitCenter.ValidityEndDate, 


@Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ControllingArea',
                     element: 'ControllingArea' }
        }]
//@ObjectModel.text.association: '_ControllingAreaText'

@ObjectModel.foreignKey.association: '_ControllingArea'
I_ProfitCenter.ControllingArea, 
I_ProfitCenter.ProfitCtrResponsiblePersonName, 
I_ProfitCenter.ProfitCtrResponsibleUser,
@Semantics.businessDate.from: true 
I_ProfitCenter.ValidityStartDate, 
I_ProfitCenter.Department, 
I_ProfitCenter.ProfitCenterStandardHierarchy, 
@Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_SegmentStdVH',
                     element: 'Segment' }
        }]
//@ObjectModel.text.association: '_SegmentText'

@ObjectModel.foreignKey.association: '_Segment' 
I_ProfitCenter.Segment, 
I_ProfitCenter.ProfitCenterIsBlocked, 
I_ProfitCenter.FormulaPlanningTemplate, 
I_ProfitCenter.FormOfAddress, 
I_ProfitCenter.AddressName, 
I_ProfitCenter.AdditionalName, 
I_ProfitCenter.ProfitCenterAddrName3, 
I_ProfitCenter.ProfitCenterAddrName4, 
I_ProfitCenter.StreetAddressName, 
I_ProfitCenter.POBox, 
I_ProfitCenter.CityName, 
I_ProfitCenter.PostalCode, 
I_ProfitCenter.District, 
@ObjectModel.foreignKey.association: '_Country'
I_ProfitCenter.Country, 
@ObjectModel.foreignKey.association: '_Region'
I_ProfitCenter.Region, 
I_ProfitCenter.TaxJurisdiction,
@Semantics.language:true
@ObjectModel.foreignKey.association: '_Language'
I_ProfitCenter.Language, 
I_ProfitCenter.PhoneNumber1, 
I_ProfitCenter.PhoneNumber2, 
I_ProfitCenter.TeleboxNumber, 
I_ProfitCenter.TelexNumber, 
I_ProfitCenter.FaxNumber, 
I_ProfitCenter.DataCommunicationPhoneNumber, 
I_ProfitCenter.ProfitCenterPrinterName, 
I_ProfitCenter.ProfitCenterCreatedByUser, 
I_ProfitCenter.ProfitCenterCreationDate, 
 
_CompanyCode, 
_ProfitCenter,
I_ProfitCenter._ControllingArea, 
//@Consumption.hidden: true

//I_ProfitCenter._ControllingAreaText, 

I_ProfitCenter._Country, 
I_ProfitCenter._Language, 
I_ProfitCenter._ProfitCenterHierarchyNode, 
I_ProfitCenter._Region, 
I_ProfitCenter._Segment, 
//@Consumption.hidden: true

//I_ProfitCenter._SegmentText, 

I_ProfitCenter._Text  
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROFITCENTER",
"TKA02"
],
"ASSOCIATED":
[
"E_PROFITCENTER",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_LANGUAGE",
"I_PROFITCENTER",
"I_PROFITCENTERHIERARCHYNODE",
"I_PROFITCENTERTEXT",
"I_REGION",
"I_SEGMENT"
],
"BASE":
[
"I_PROFITCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/