I_ProductionVersionConstcyLog

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Production Version Consistency Log'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #BASIC
@Search.searchable: true
define view entity I_ProductionVersionConstcyLog
  as select from mkalconstcylog              as _ConstcyLog
  //  inner join with configuration; to get latest config value

    inner join   I_ProdnVersInconstcyIssType as _InconstcyIssType on _ConstcyLog.issuetype = _InconstcyIssType.ProdnVersConsistencyIssueType

  association [1..1] to I_Material                  as _Material  on  $projection.Material = _Material.Material
  association [1..1] to I_Plant                     as _Plant     on  $projection.Plant = _Plant.Plant
  association [1..1] to I_ProductionVersion         as _ProdnVers on  $projection.Material          = _ProdnVers.Material
                                                                  and $projection.Plant             = _ProdnVers.Plant
                                                                  and $projection.ProductionVersion = _ProdnVers.ProductionVersion
  association [1..1] to I_ProdnVersInconstcyIssType as _IssueType on  $projection.ProdnVersConsistencyIssueType = _IssueType.ProdnVersConsistencyIssueType

{
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.foreignKey.association: '_Material'
  key _ConstcyLog.matnr                             as Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key _ConstcyLog.werks                             as Plant,
      @ObjectModel.foreignKey.association: '_ProdnVers'
  key _ConstcyLog.verid                             as ProductionVersion,
  key _ConstcyLog.issueid                           as ProdnVersConstcyIssue,
      @ObjectModel.foreignKey.association: '_IssueType'
      _ConstcyLog.issuetype                         as ProdnVersConsistencyIssueType,
      _InconstcyIssType.ProdnVersConstcyIssSvrtyLvl as ProdnVersConstcyIssSvrtyLvl,
      _ConstcyLog.occurreddatetime                  as IssueOccurredDateTime,
      _ConstcyLog.eventstatus                       as ProductionVersionConstcyStatus,
      _ConstcyLog.eventresp                         as ProducerEventType,
      _ConstcyLog.eventbusobj                       as ProducerBusinessObjectType,
      _ConstcyLog.msgid                             as ProdnVersConstcyLogMsgClass,
      _ConstcyLog.msgno                             as ProdnVersConstcyLogMsgNumber,
      _ConstcyLog.msgv1                             as ProdnVersConstcyLgMsgVarbl1Txt,
      _ConstcyLog.msgv2                             as ProdnVersConstcyLgMsgVarbl2Txt,
      _ConstcyLog.msgv3                             as ProdnVersConstcyLgMsgVarbl3Txt,
      _ConstcyLog.msgv4                             as ProdnVersConstcyLgMsgVarbl4Txt,

      /* Associations */
      _ProdnVers,
      _Material,
      _Plant,
      _IssueType
}
where
  _InconstcyIssType.ProdnVersConstcyIssSvrtyLvl is not initial

//To get checked successful records from Consistency Log

union select from mkalconstcylog as _ConstcyLog

association [1..1] to I_Material                  as _Material  on  $projection.Material = _Material.Material
association [1..1] to I_Plant                     as _Plant     on  $projection.Plant = _Plant.Plant
association [1..1] to I_ProductionVersion         as _ProdnVers on  $projection.Material          = _ProdnVers.Material
                                                                and $projection.Plant             = _ProdnVers.Plant
                                                                and $projection.ProductionVersion = _ProdnVers.ProductionVersion
association [1..1] to I_ProdnVersInconstcyIssType as _IssueType on  $projection.ProdnVersConsistencyIssueType = _IssueType.ProdnVersConsistencyIssueType
{
  key _ConstcyLog.matnr            as Material,
  key _ConstcyLog.werks            as Plant,
  key _ConstcyLog.verid            as ProductionVersion,
  key _ConstcyLog.issueid          as ProdnVersConstcyIssue,
      _ConstcyLog.issuetype        as ProdnVersConsistencyIssueType,
      cast('S' as abap.char( 1 ) ) as ProdnVersConstcyIssSvrtyLvl,
      _ConstcyLog.occurreddatetime as IssueOccurredDateTime,
      _ConstcyLog.eventstatus      as ProductionVersionConstcyStatus,
      _ConstcyLog.eventresp        as ProducerEventType,
      _ConstcyLog.eventbusobj      as ProducerBusinessObjectType,
      _ConstcyLog.msgid            as ProdnVersConstcyLogMsgClass,
      _ConstcyLog.msgno            as ProdnVersConstcyLogMsgNumber,
      _ConstcyLog.msgv1            as ProdnVersConstcyLgMsgVarbl1Txt,
      _ConstcyLog.msgv2            as ProdnVersConstcyLgMsgVarbl2Txt,
      _ConstcyLog.msgv3            as ProdnVersConstcyLgMsgVarbl3Txt,
      _ConstcyLog.msgv4            as ProdnVersConstcyLgMsgVarbl4Txt,
      /* Associations */
      _ProdnVers,
      _Material,
      _Plant,
      _IssueType
}
where
  _ConstcyLog.issuetype is initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODNVERSINCONSTCYISSTYPE",
"MKALCONSTCYLOG"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_PLANT",
"I_PRODNVERSINCONSTCYISSTYPE",
"I_PRODUCTIONVERSION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/