I_ProductionSupplyArea

@AbapCatalog.sqlViewName: 'IPPPRODNSUPAREA'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Production Supply Area'

@Metadata.ignorePropagatedAnnotations:true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_ResponsiblePerson', '_Address']
@Metadata.allowExtensions: true
@ObjectModel.representativeKey: 'ProductionSupplyArea'
@ObjectModel.semanticKey: 'ProductionSupplyArea'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #MASTER }
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE, #ANALYTICAL_DIMENSION ]
@ObjectModel.sapObjectNodeType.name: 'ProductionSupplyArea'
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction: { enabled: true, delta.changeDataCapture: { automatic : true } }

@Search.searchable: true

define view I_ProductionSupplyArea
  as select from pvbe as pvbe
  association [1..1] to I_Plant                    as _Plant             on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation          as _StorageLocation   on  $projection.Plant           = _StorageLocation.Plant
                                                                         and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..1] to I_MRPController            as _ResponsiblePerson on  $projection.Plant                          = _ResponsiblePerson.Plant
                                                                         and $projection.ProductionSupplyAreaRespPerson = _ResponsiblePerson.MRPController
  association [0..*] to I_ProductionSupplyAreaText as _Text              on  $projection.Plant                = _Text.Plant
                                                                         and $projection.ProductionSupplyArea = _Text.ProductionSupplyArea
  association [0..1] to I_OrganizationAddress      as _Address           on  $projection.AddressID = _Address.AddressID 
                                                                         and _Address.AddressPersonID is initial
                                                                         and _Address.AddressRepresentationCode is initial                                                                         
  association [0..1] to I_ShiftGrouping            as _ShiftGrouping     on  $projection.ShiftGrouping = _ShiftGrouping.ShiftGrouping
  association [0..1] to I_ShiftSequence            as _ShiftSequence     on  $projection.ShiftSequence = _ShiftSequence.ShiftSequence
                                                                         and $projection.ShiftGrouping = _ShiftSequence.ShiftGrouping
{
      // Key

      @ObjectModel.text.association: '_Text'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key cast(pvbe.prvbe as vdm_prvbe preserving type) as ProductionSupplyArea,
      @ObjectModel.foreignKey.association: '_Plant'
  key pvbe.werks                                    as Plant,

      // Attributes

      @ObjectModel.foreignKey.association: '_StorageLocation'
      cast(pvbe.lgort as pph_lgort preserving type) as StorageLocation,
      @Semantics.text: true
      pvbe.ablad                                    as UnloadingPointName,
      pvbe.pvadr                                    as AddressID,
      @ObjectModel.foreignKey.association: '_ResponsiblePerson'
      pvbe.rgver                                    as ProductionSupplyAreaRespPerson,
      cast(pvbe.fabklv as fabkl preserving type)    as FactoryCalendar,
      @ObjectModel.foreignKey.association: '_ShiftGrouping'
      pvbe.schgrupv                                 as ShiftGrouping,
      @ObjectModel.foreignKey.association: '_ShiftSequence'
      pvbe.sprogv                                   as ShiftSequence,
      pvbe.pintvd                                   as PullIntervalInWorkdays,
      // pvbe.pintvm                                         as PullIntervalInHoursAndMinutes,

      cast(pvbe.pintvm as pintv_hrs_min)            as PullIntervalInHoursAndMinutes, // cast to identical type to avoid conversion exit

      pvbe.lgbzo                                    as UnloadingWarehouseStagingArea,
      pvbe.lastchange_datetime                      as LastChangeDateTime,
      pvbe.loadingpoint                             as AutomotiveLoadingPoint,

      // Associations

      _Plant,
      _Text,
      _StorageLocation,
      _Address,
      _ResponsiblePerson,
      _ShiftGrouping,
      _ShiftSequence

};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PVBE"
],
"ASSOCIATED":
[
"I_MRPCONTROLLER",
"I_ORGANIZATIONADDRESS",
"I_PLANT",
"I_PRODUCTIONSUPPLYAREATEXT",
"I_SHIFTGROUPING",
"I_SHIFTSEQUENCE",
"I_STORAGELOCATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/