I_ProductValuationCosting

@AbapCatalog.sqlViewName: 'IPRODVALCOST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@EndUserText.label: 'Product Valuation Costing Core Entity'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true

@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #EXTRACTION_DATA_SOURCE ]
@Analytics:{
    dataExtraction: {
        enabled: true,
       delta.changeDataCapture :{
          mapping: [
          { table: 'MBEW',
            role: #MAIN,
            viewElement: ['Product','ValuationArea','ValuationType'],
            tableElement: ['MATNR','BWKEY','BWTAR'] },

          { table: 'T001K',
            role: #LEFT_OUTER_TO_ONE_JOIN,
            viewElement: ['ValuationArea'],
            tableElement: ['BWKEY']},

          { table: 'T001',
            role: #LEFT_OUTER_TO_ONE_JOIN,
            viewElement: ['CompanyCode'],
            tableElement: ['BUKRS']
          } ]
           }
    }
}
define view I_ProductValuationCosting
  as select from P_ProductValuationBasic as ProdCosting
    inner join   t001k on ProdCosting.ValuationArea = t001k.bwkey
    inner join   t001  on t001.bukrs = t001k.bukrs

  association [1..1] to I_Product          as _Product          on  $projection.Product = _Product.Product
  association [0..1] to E_Productvaluation as _ProdValuationExt on  $projection.Product       = _ProdValuationExt.Product
                                                                and $projection.ValuationArea = _ProdValuationExt.ValuationArea
                                                                and $projection.ValuationType = _ProdValuationExt.ValuationType
{

  key ProdCosting.Product,
  key ProdCosting.ValuationArea,
  key ProdCosting.ValuationType,  
      ProdCosting.IsMaterialCostedWithQtyStruc,
      @Semantics.booleanIndicator
      ProdCosting.IsMaterialRelatedOrigin,
      ProdCosting.CostOriginGroup,
      @ObjectModel.sapObjectNodeTypeReference:'CostingOverheadGroup'
      ProdCosting.CostingOverheadGroup,
      @Semantics.amount.currencyCode: 'Currency'
      ProdCosting.PlannedPrice1InCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      ProdCosting.PlannedPrice2InCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      ProdCosting.PlannedPrice3InCoCodeCrcy,
      ProdCosting.FuturePlndPrice1ValdtyDate,
      ProdCosting.FuturePlndPrice2ValdtyDate,
      ProdCosting.FuturePlndPrice3ValdtyDate,
      @Semantics.amount.currencyCode: 'Currency'
      ProdCosting.PlannedPrice,
      @Semantics.currencyCode: true
      t001.waers        as Currency,
      t001.bukrs        as CompanyCode,
      _Product

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PRODUCTVALUATIONBASIC",
"T001",
"T001K"
],
"ASSOCIATED":
[
"E_PRODUCTVALUATION",
"I_PRODUCT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/