I_ProductAllocationPeriodUnitT

@EndUserText.label: 'Product Allocation Period Unit - Text' 
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
//@Analytics.dataCategory: #TEXT // does not exist any more, do not replace it with #DIMENSION

@Analytics.dataExtraction.enabled: false
@ObjectModel.representativeKey: 'ProductAllocationPeriodUnit'
@AccessControl.authorizationCheck: #NOT_REQUIRED //or #CHECK 

@AbapCatalog.sqlViewName: 'IPAPERDUNITT'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #META
@ObjectModel.modelingPattern:           #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities:  [  #LANGUAGE_DEPENDENT_TEXT,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #SQL_DATA_SOURCE,
                                        //#EXTRACTION_DATA_SOURCE,

                                        #SEARCHABLE_ENTITY                   ]
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
define view I_ProductAllocationPeriodUnitT  
   as select from dd07t
   association to parent I_ProductAllocationPeriodUnit as _ProductAllocationPeriodUnit 
      on $projection.ProductAllocationPeriodUnit = _ProductAllocationPeriodUnit.ProductAllocationPeriodUnit
   association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language
    key cast( ddlanguage as spras preserving type ) as Language,
    @ObjectModel.foreignKey.association: '_ProductAllocationPeriodUnit'
    @ObjectModel.text.element: ['ProdAllocationPeriodUnitDesc']
    key cast( substring( domvalue_l, 1, 2 ) as productallocationperiodunit preserving type ) as ProductAllocationPeriodUnit,
    @Search.defaultSearchElement: true
    @Search.ranking: #HIGH
    @Search.fuzzinessThreshold: 0.8
    @Semantics.text
    cast( ddtext as prodallocationperiodunitdesc preserving type ) as ProdAllocationPeriodUnitDesc, 
    @Analytics.hidden: true
    @Consumption.hidden: true
    domvalue_l as DomainValue,
    _ProductAllocationPeriodUnit,
    _Language 
}
where domname  = 'PRODUCTALLOCATIONPERIODUNIT' 
  and as4local = 'A'
  and as4vers  = '0000'
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PRODUCTALLOCATIONPERIODUNIT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/