I_ProdUnivHierNodeText_2

@AbapCatalog: {
  sqlViewName: 'IPRDUNIVHIERNDT2',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@EndUserText.label: 'Product Hierarchy Node - Text'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  representativeKey: 'HierarchyNode',
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #XL
  },
  dataCategory: #TEXT
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #LANGUAGE_DEPENDENT_TEXT,
                                      #EXTRACTION_DATA_SOURCE
]
@Analytics:{  
    internalName: #LOCAL,
    dataExtraction: {
        enabled: true
    }
}
define view I_ProdUnivHierNodeText_2
  as select from hrrp_nodet     as nodet
    inner join   hrrp_directory as dir on  dir.hryid    = nodet.hryid
                                       and dir.hryvalto = nodet.hryvalto
                                       and dir.hryver   = nodet.hryver
  //                                    and dir.hrytyp   = 'MD01'

  //[1..*] as they are temporal assoc

  association [1..*] to I_ProdUnivHierarchyBasic     as _ProductHierarchy     on  $projection.ProdUnivHierarchy = _ProductHierarchy.ProdUnivHierarchy

  association [1..*] to I_ProdUnivHierarchyNodeBasic as _ProductHierarchyNode on  $projection.ProdUnivHierarchy = _ProductHierarchyNode.ProdUnivHierarchy
                                                                              and $projection.HierarchyNode     = _ProductHierarchyNode.HierarchyNode

{

      @Semantics.language: true
  key spras                                                                     as Language,
      @ObjectModel.foreignKey.association: '_ProductHierarchy'
  key cast(substring( nodet.hryid, 6, 26 ) as prod_hier_id )                    as ProdUnivHierarchy,
      @ObjectModel.foreignKey.association: '_ProductHierarchyNode'
  key nodet.hrynode                                                             as HierarchyNode,
      @Semantics.businessDate.to: true
  key cast(nodet.hryvalto as prodhierarchyvalidityenddate preserving type )     as ProdHierarchyValidityEndDate,
      @Semantics.businessDate.from: true
      cast(nodet.hryvalfrom as prodhierarchyvaliditystartdate preserving type ) as ProdHierarchyValidityStartDate,
      @Semantics.text: true
      cast(nodetxt as prod_hier_node_value_text)                                as ProdUnivHierarchyNodeText,
      _ProductHierarchy,
      _ProductHierarchyNode // Make association public

}
where
     dir.hrytyp = 'MD01'
  or dir.hrytyp = 'MD02'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIRECTORY",
"HRRP_NODET"
],
"ASSOCIATED":
[
"I_PRODUNIVHIERARCHYBASIC",
"I_PRODUNIVHIERARCHYNODEBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/