I_ProdStrucVariantChangeState

@AbapCatalog.sqlViewName: 'IPSVARCHGSTATE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.representativeKey: 'ProdStrucVariantChgStateIntID'


@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY ]

@EndUserText.label: 'Product Structure Variant Change State'
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_ProdStrucVariantChangeState
  as select  from pvcmp
    left outer join       aenr on pvcmp.aennr = aenr.aennr
  association [0..1] to I_ProdStrucVariantBasic as _VariantBasic on $projection.ProductStructureVariantUUID = _VariantBasic.ProductStructureVariantUUID
  association [0..1] to I_ProdStrucLogAccMActive  as _LogAccMObjectTypeActive       on  $projection.productstructuregnrcobjtype = _LogAccMObjectTypeActive.LogAccMObjectType 
  association [0..*] to I_ProdStrucLogAccMSecureAssgmt as _LogAccMObjSecureIDAssgmt on  $projection.prodstrucvariantuniqueid = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                    and $projection.productstructuregnrcobjtype = _LogAccMObjSecureIDAssgmt.LogAccMObjectType
  association [0..*] to I_ProdStrucLogAccMUserAuthzn  as _LogAccMObjectUserAuthzn  on  $projection.prodstrucvariantuniqueid = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                // and (

                                                                                   // _LogAccMObjectUserAuthzn.LogAccMObjectType          = 'PLM_PPEPV'

                                                                                   // or _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_PPEPIV'

                                                                                 // )

                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject    = 'PLM_PPEPV'
                                                                                   or _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_PPEPIV'
                                                                                 )
                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom      = '03'
                                                                                   or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom   = '*'
                                                                                 )
                                                                                and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField    = 'ACTVT'
                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserEntityID        = $session.user
                                                                                   or _LogAccMObjectUserAuthzn.UserID                  = $session.user
                                                                                 )
{
      @ObjectModel.foreignKey.association: '_VariantBasic'
  key pvcmp.pvguid                       as ProductStructureVariantUUID,
  key pvcmp.pvcnt                        as ProdStrucVariantChgStateIntID,
      ///bintohex( pvguid )                 as ProdStrucVariantUniqueID,

      _VariantBasic.ProdStrucVariantUniqueID,
      pvcmp.pvcdcnt                      as ProdStrucVarBasicDataChgState,
      pvcmp.aennr                        as ProdStrucVariantChangeNumber,
      pvcmp.delflg                       as ProdStrucVarIsMrkdForDeletion,
      aenr.aetxt                         as ProdStrucVarChgNmbrDescription,
      aenr.aenbe                         as AuthorizationGroup,
      _VariantBasic.ProductStructureGnrcObjType,
      //_LogAccMObjSecureIDAssgmt.LogAccMObjectID,

      _VariantBasic,
      _LogAccMObjectTypeActive,
      _LogAccMObjSecureIDAssgmt,
      _LogAccMObjectUserAuthzn
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODSTRUCVARIANTBASIC",
"AENR",
"PVCMP"
],
"ASSOCIATED":
[
"I_PRODSTRUCLOGACCMACTIVE",
"I_PRODSTRUCLOGACCMSECUREASSGMT",
"I_PRODSTRUCLOGACCMUSERAUTHZN",
"I_PRODSTRUCVARIANTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/