I_ProdSpecStdCmpstn

@AbapCatalog.sqlViewName: 'IPRODSPCOMPS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@EndUserText.label: 'Product Specification Std. Composition'
define view I_ProdSpecStdCmpstn
  as select distinct from I_SpecValAssgmtItem       as item
    inner join            I_ProdSpecStdCmpstnHeader as header on  header.ProdSpecCmpstnHeader           =  item.SpecValAssgmt
                                                              and header.ProdSpecCmpstnHdrValdtyStrtDte <= item.SpecValAssgmtItemValdtyEndDte
                                                              and header.ProdSpecCmpstnHdrValdtyEndDte  >= item.SpecValAssgmtItemValdtyStrtDte

  association [1..*] to I_ProductSpecification    as _ProductSpecification    on _ProductSpecification.ProductSpecificationInternalID = $projection.ProductSpecificationInternalID
  association [1..1] to I_ProdSpecNonHistoric     as _ProdSpecNonHistoric     on _ProdSpecNonHistoric.ProductSpecificationInternalID = $projection.ProductSpecificationInternalID
  association [1..*] to I_ProdSpecStdCmpstnHeader as _ProdSpecStdCmpstnHeader on _ProdSpecStdCmpstnHeader.ProdSpecCmpstnHeader = $projection.ProdSpecCmpstnHeader
{
  key cast(item.SpecValAssgmtItem as /plmb/spc_comp_int_id preserving type )                       as ProdSpecComponentItem,
  key cast(item.SpecValAssgmtItemChangeState as /plmb/spc_comp_chg_state preserving type )         as ProdSpecCompItemChangeState,

      header.ProdSpecCmpstnHeader,
      header.ProductSpecificationInternalID,

      cast(item.SpecValAssgmtItemValdtyStrtDte as /plmb/spc_comp_val_strt_dat preserving type )    as ProdSpecCompItemValdtyStrtDte, //necessary for join

      cast(item.SpecValAssgmtItemValdtyEndDte as /plmb/spc_comp_val_end_dat preserving type )      as ProdSpecCompItemValdtyEndDte,
      cast(item.SpecValAssgmtItemIsDeleted as /plmb/spc_comp_item_deleted preserving type )        as ProdSpecCompItemIsDeleted,
      cast(item.SpecValAssgmtItemChangeNumber as /plmb/spc_comp_item_chg_number  preserving type ) as ProdSpecCompItemChangeNumber,

      cast(item.CompSpecComponentType as /plmb/spc_pure_comp_type preserving type )                as PureSubstanceComponentType,
      cast(item.ComponentSpecificationIntID as /plmb/spc_pure_int_id preserving type )             as PureSubstanceInternalID,
      cast(item.CompSpecLowerLimitOperator as /plmb/spc_quant_precl preserving type)               as PureSubstLowrLmtQtyOperator,
      cast(item.CompSpecLowerLimit as /plmb/spc_quant_compllow preserving type)                    as PureSubstLowerLimitQuantity,
      cast(item.CompSpecUpperLimitOperator as /plmb/spc_quant_precu preserving type)               as PureSubstUprLmtQtyOperator,
      cast(item.CompSpecUpperLimit as /plmb/spc_quant_complupp preserving type)                    as PureSubstUpperLimitQuantity,
      cast(item.CompSpecQuantity as /plmb/spc_pure_quantity preserving type)                       as PureSubstanceQuantity,
      cast(item.CompSpecUnit as /plmb/spc_pure_uom preserving type)                                as PureSubstanceUnit,

      //Association

      _ProdSpecStdCmpstnHeader,
      _ProductSpecification,
      _ProdSpecNonHistoric,
      header._ProdSpecificationLastChange
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODSPECSTDCMPSTNHEADER",
"I_SPECVALASSGMTITEM"
],
"ASSOCIATED":
[
"I_PRODSPECIFICATIONLASTCHANGE",
"I_PRODSPECNONHISTORIC",
"I_PRODSPECSTDCMPSTNHEADER",
"I_PRODUCTSPECIFICATION"
],
"BASE":
[
"I_PRODSPECSTDCMPSTNHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/