I_ProdSlsDelivRepeatKeyTxt

@AbapCatalog.sqlViewName: 'IPRDSLSDELRPTKYT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Text View Prod Sales Delvry Repeat Key'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory : #S
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #TEXT
@Search.searchable: true
@ObjectModel.representativeKey: [ 'ProdSlsDelivRepeatKey' ]

define view I_ProdSlsDelivRepeatKeyTxt
  as select from dd07t
  association [1..1] to I_ProdSlsDelivRepeatKey as _ProdSlsDelivRepeatKey on $projection.ProdSlsDelivRepeatKey = _ProdSlsDelivRepeatKey.ProdSlsDelivRepeatKey
  association [1..1] to I_Language              as _Language              on $projection.Language = _Language.Language

{
      @Semantics.language
      @ObjectModel.foreignKey.association: '_Language'
  key cast( ddlanguage as spras preserving type )                                   as Language,
      @ObjectModel.foreignKey.association: '_ProdSlsDelivRepeatKey'
  key cast ( domvalue_l as kwdht )                                                  as ProdSlsDelivRepeatKey,
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      cast ( ddtext as val_text )                                                   as Name,
      _Language,
      _ProdSlsDelivRepeatKey
}
where
      domname  = 'KWDHT'
  and as4local = 'A'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PRODSLSDELIVREPEATKEY"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/