I_ProdEWMPartyToDispose

@AbapCatalog.sqlViewName: 'IPRDEWMPRTYDISP'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
    usageType: {
      serviceQuality: #C,
      sizeCategory: #L,
      dataClass: #MIXED
    }
}
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: ['BusinessPartner','Warehouse']
@EndUserText.label: 'Basic View - Entitled to Dispose'
@AccessControl.personalData.blocking: #REQUIRED
define view I_ProdEWMPartyToDispose
  as select from /scwm/tmapstloc             as Storage
    inner join   I_Plant                     as Plant                   on Plant.Plant = Storage.plant
    inner join   I_SupplierToBusinessPartner as BusinessPartnerSupplier on BusinessPartnerSupplier.Supplier = Plant.PlantSupplier
{
  key   Storage.lgnum                                                              as Warehouse,
        @Search.defaultSearchElement: true
        @Search.fuzzinessThreshold: 0.8
        @Search.ranking: #HIGH
        @ObjectModel.text.element: ['BusinessPartnerName']
  key   BusinessPartnerSupplier._BusinessPartner.BusinessPartner                   as BusinessPartner,

        @ObjectModel.text.element: ['PlantName']
        Plant.Plant                                                                as Plant,
        BusinessPartnerSupplier.Supplier                                           as BusinessPartnerSupplier,
        BusinessPartnerSupplier._BusinessPartner.BusinessPartnerName               as BusinessPartnerName,
        BusinessPartnerSupplier._BusinessPartner.AuthorizationGroup                as AuthorizationGroup,
        BusinessPartnerSupplier._BusinessPartner.IsBusinessPurposeCompleted        as IsBusinessPurposeCompleted,
        Plant.PlantName                                                            as PlantName,
        
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataControllerSet,
        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController1,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController2,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController3,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController4,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController5,
        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController6,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController7,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController8,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController9,
        //added only for DCL check

        @Consumption.hidden:true
        @UI.hidden:true
        BusinessPartnerSupplier._BusinessPartner.DataController10     
}
where
  BusinessPartnerSupplier._BusinessPartner.IsBusinessPurposeCompleted = ''
group by
  lgnum,
  BusinessPartnerSupplier._BusinessPartner.BusinessPartner,
  Plant.Plant,
  Supplier,
  BusinessPartnerSupplier._BusinessPartner.BusinessPartnerName,
  BusinessPartnerSupplier._BusinessPartner.AuthorizationGroup,
  BusinessPartnerSupplier._BusinessPartner.IsBusinessPurposeCompleted,
  Plant.PlantName,
  BusinessPartnerSupplier._BusinessPartner.DataControllerSet,
  BusinessPartnerSupplier._BusinessPartner.DataController1,
  BusinessPartnerSupplier._BusinessPartner.DataController2,
  BusinessPartnerSupplier._BusinessPartner.DataController3,
  BusinessPartnerSupplier._BusinessPartner.DataController4,
  BusinessPartnerSupplier._BusinessPartner.DataController5,
  BusinessPartnerSupplier._BusinessPartner.DataController6,
  BusinessPartnerSupplier._BusinessPartner.DataController7,
  BusinessPartnerSupplier._BusinessPartner.DataController8,
  BusinessPartnerSupplier._BusinessPartner.DataController9,
  BusinessPartnerSupplier._BusinessPartner.DataController10
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_PLANT",
"I_SUPPLIERTOBUSINESSPARTNER",
"/SCWM/TMAPSTLOC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/