I_ProcessOrder

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser', '_MRPController', '_ProductionSupervisor']
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Process Order'
// CDS view for linkage between SOT "Process Order" and VDM

// Not for general usage, not for consumption, not for C1-release! 

// Please use DDLS I_ManufacturingOrder for all other purposes.


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_ProcessOrder
  as select from I_ManufacturingOrder as head

  -- to child: Items
  association [1..*] to I_ManufacturingOrderItem      as _ProcessOrderItem      on $projection.ProcessOrder = _ProcessOrderItem.ManufacturingOrder
  -- to child: Operations
  association [1..*] to I_ManufacturingOrderOperation as _ProcessOrderOperation on $projection.OrderInternalID = _ProcessOrderOperation.MfgOrderInternalID
  -- to child: Components
  association [0..*] to I_ManufacturingOrderComponent as _ProcessOrderComponent on $projection.Reservation = _ProcessOrderComponent.Reservation

{
      // Key

  key head.ManufacturingOrder,

      @ObjectModel.text.element: ['OrderDescription']
      cast(head.ManufacturingOrder as co_aufnr preserving type)         as ProcessOrder,

      // Text

      @Semantics.text: true
      cast(head. ManufacturingOrderText as pph_auftext preserving type) as OrderDescription,
      head.ManufacturingOrderHasLongText                                as OrderHasLongText,
      head.LongTextLanguageCode                                         as LongTextLanguageCode,

      // Attributes

      head.IsMarkedForDeletion,
      head.IsCompletelyDelivered,

      // Admin data

      @Semantics.systemDate.createdAt: true
      head.CreationDate,
      @Semantics.systemTime.createdAt: true
      head.CreationTime,
      @Semantics.user.createdBy: true
      head.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      head.LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      head.LastChangeTime,
      @Semantics.user.lastChangedBy: true
      head.LastChangedByUser,

      // Header Material data

      head.Product,
      head.StorageLocation,
      head.Batch,

      // Asssignments

      head.ManufacturingOrderType                                as OrderType,
      cast(head.MfgOrderInternalID as pph_aufpl preserving type) as OrderInternalID,
      head.ReferenceOrder,
      head.Currency,
      head.ProductionPlant,
      head.PlanningPlant,
      head.MRPController,
      head.ProductionSupervisor,
      head.ProductionSchedulingProfile,
      head.ResponsiblePlannerGroup,
      head.ProductionVersion,
      head.SalesOrder,
      head.SalesOrderItem,
      head.Reservation,
      head.SettlementReservation,
      head.PlannedOrder,
      head.CapacityRequirement,
      head.ChangeNumber,

      // Assignments BOO

      head.BillOfOperationsMaterial,
      head.BillOfOperationsType,
      head.BillOfOperationsGroup,
      head.BillOfOperationsVariant,
      head.BOOInternalVersionCounter,
      head.BillOfOperationsApplication,
      head.BillOfOperationsUsage,
      head.BillOfOperationsVersion,
      head.BOOExplosionDate,

      // Assignments BOM

      head.BillOfMaterialCategory,
      head.BillOfMaterialInternalID,
      head.BillOfMaterialVariant,
      head.BillOfMaterialVariantUsage,
      head.BillOfMaterialVersion,
      head.BOMExplosionDate,

      // Assignments FI/CO

      head.BusinessArea,
      head.CompanyCode,
      head.ControllingArea,
      head.ProfitCenter,
      head.CostCenter,
      head.CostElement,
      head.CostingSheet,
      head.GLAccount,
      head.ProductCostCollector,
      head.ActualCostsCostingVariant,
      head.PlannedCostsCostingVariant,
      head.ControllingObjectClass,
      head.FunctionalArea,
      head.EventBasedPostingMethod,

      // Dates and Times

      head.MfgOrderPlannedStartDate       as PlannedStartDate,
      head.MfgOrderPlannedStartTime       as PlannedStartTime,
      head.MfgOrderPlannedEndDate         as PlannedEndDate,
      head.MfgOrderPlannedEndTime         as PlannedEndTime,
      head.MfgOrderPlannedReleaseDate     as PlannedReleaseDate,
      head.MfgOrderScheduledStartDate     as ScheduledBasicStartDate,
      head.MfgOrderScheduledStartTime     as ScheduledBasicStartTime,
      head.MfgOrderScheduledEndDate       as ScheduledBasicEndDate,
      head.MfgOrderScheduledEndTime       as ScheduledBasicEndTime,
      head.MfgOrderScheduledReleaseDate   as ScheduledReleaseDate,
      head.MfgOrderActualStartDate        as ActualStartDate,
      head.MfgOrderActualStartTime        as ActualStartTime,
      head.MfgOrderActualEndDate          as ActualEndDate,
      head.MfgOrderActualReleaseDate      as ActualReleasedDate,
      head.MfgOrderConfirmedEndDate       as ConfirmedEndDate,
      head.MfgOrderConfirmedEndTime       as ConfirmedEndTime,
      head.MfgOrderActualCompletionDate   as TechnicalCompletionDate,
      head.MfgOrderItemActualDeliveryDate as ActualDeliveryDate, 

      // Quantities and UoM

      head.ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      head.MfgOrderPlannedTotalQty   as OrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      head.MfgOrderPlannedScrapQty   as OrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      head.MfgOrderConfirmedYieldQty as OrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      head.MfgOrderConfirmedScrapQty as OrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      head.ExpectedDeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      head.ActualDeliveredQuantity,

      -- for DCLS purposes only
      @Consumption.hidden: true
      head.ManufacturingOrderCategory as OrderCategory,

      // Associations

      _ProcessOrderItem,
      _ProcessOrderOperation,
      _ProcessOrderComponent,
      head._CreatedByUser,
      head._LastChangedByUser,
      head._LongTextLanguage,
      head._ProductionUnit,
      head._Currency,
      head._OrderInternalID,
      head._BillOfOperationsMaterial,
      head._BillOfOperationsType,
      head._Reservation,
      head._SettlementReservation,
      head._ProductionPlant,
      head._PlanningPlant,
      head._Product,
      head._StorageLocation,
      head._MRPController,
      head._ProductionSupervisor,
      head._ProductionSchedulingProfile,
      head._ResponsiblePlannerGroup,
      head._CapacityRequirement,
      head._ChangeNumber  

}
where head.ManufacturingOrderCategory = '40';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MANUFACTURINGORDER"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSTYPE",
"I_CAPACITYREQUIREMENT",
"I_CHANGEMASTER",
"I_CURRENCY",
"I_LANGUAGE",
"I_MANUFACTURINGORDERCOMPONENT",
"I_MANUFACTURINGORDERITEM",
"I_MANUFACTURINGORDEROPERATION",
"I_MRPCONTROLLER",
"I_ORDERINTERNALID",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTIONSCHEDULINGPROFILE",
"I_PRODUCTIONSUPERVISOR",
"I_RESERVATIONDOCUMENTHEADER",
"I_RESPONSIBLEPLANNERGROUP",
"I_STORAGELOCATION",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[
"I_MANUFACTURINGORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/