I_ProcOrdOpsMgmtConfirmation

@AbapCatalog.sqlViewName: 'IPOROPMGMTCONF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Process order operation confirmations'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@ObjectModel.representativeKey: 'ConfirmationCount'
@ObjectModel.semanticKey: ['ConfirmationGroup', 'ConfirmationCount']
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@UI.headerInfo: {
    title : { type: #STANDARD, value: 'ConfirmationGroup' },
    description : { type: #STANDARD, value: 'ConfirmationCount' },
    typeName: 'All Confirmations',
    typeNamePlural: 'All Confirmations'
}
define view I_ProcOrdOpsMgmtConfirmation
  as select from           I_MfgOrderConfirmation   as afru
    left outer to one join P_ProcOrderOperationDurn as _Op on  _Op.MfgOrderInternalID         = afru.OrderInternalID
                                                           and _Op.ManufacturingOrder         = afru.ManufacturingOrder
                                                           and _Op.OrderOperationInternalID   = afru.OrderOperationInternalID
                                                           and _Op.ManufacturingOrderCategory = '40'
  -- to parent
  association        to parent I_ProcOrdOpsMgmtWorkList as _ProcOrdMgmtOp on  _ProcOrdMgmtOp.OrderInternalBillOfOperations = $projection.OrderInternalBillOfOperations
                                                                          and _ProcOrdMgmtOp.OrderIntBillOfOperationsItem  = $projection.OrderIntBillOfOpItemOfPhase

  association [0..1] to I_WorkCenterActivityTexts       as _ActivityTexts on  $projection.WorkCenterInternalID  = _ActivityTexts.WorkCenterInternalID
                                                                          and _ActivityTexts.WorkCenterTypeCode = 'A'
  {
  key    MfgOrderConfirmationGroup                                           as ConfirmationGroup,
  key    MfgOrderConfirmation                                                as ConfirmationCount,

         afru.ManufacturingOrder                                             as ProcessOrder,


         //Phase

         cast(_Op.ManufacturingOrderOperation as text4 preserving type )     as ManufacturingOrderOperation,

         //Operation

         cast( _Op.MfgOrderPhaseSuperiorOperation as text4 preserving type ) as MfgOrderPhaseSuperiorOperation,

         afru.ManufacturingOrderType,
         afru.OrderInternalID                                                as OrderInternalBillOfOperations,
         afru.OrderOperationInternalID                                       as OrderIntBillOfOperationsItem,
         _Op.OrderIntBillOfOpItemOfPhase,
         afru.SuperiorOperationInternalID,

         afru.ConfirmationText,
         afru.Language,
         afru._MfgOrder.Material,
         @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
         afru._MfgOrder.MfgOrderPlannedTotalQty,
         afru._MfgOrder.ProductionUnit,
         afru.WorkCenterInternalID,

         //Attributes

         FinalConfirmationType,
         IsFinalConfirmation,
         OpenReservationsIsCleared,
         IsReversed,                 // Document was cancelled in earlier times

         IsReversal,                 // Document is cancelled right now, it is triggered from outside

         APIConfHasNoGoodsMovements, // Control flag for "No Goods Movement via API", is triggered from outside

         OrderConfirmationRecordType,

         //Adminitstration

         case MfgOrderConfirmationEntryTime when '240000' then
           cast(cast(concat(MfgOrderConfirmationEntryDate,cast('235959' as tims))as abap.numc(15)) as timestamp)
          else
           cast(cast(concat(MfgOrderConfirmationEntryDate , MfgOrderConfirmationEntryTime)as abap.numc(15)) as timestamp)
          end                                                                as ConfirmedDateTime,
         MfgOrderConfirmationEntryDate,
         MfgOrderConfirmationEntryTime,
         EnteredByUser,
         LastChangeDate,
         LastChangedByUser,
         ConfirmationExternalEntryDate,
         ConfirmationExternalEntryTime,
         EnteredByExternalUser,
         ExternalSystemConfirmation,
         //General Assignments

         afru.Plant,

         //Dates

         PostingDate,

         //Time Events

         ConfirmedExecutionStartDate,
         ConfirmedExecutionStartTime,
         ConfirmedSetupEndDate,
         ConfirmedSetupEndTime,
         ConfirmedProcessingStartDate,
         ConfirmedProcessingStartTime,
         ConfirmedProcessingEndDate,
         ConfirmedProcessingEndTime,
         ConfirmedTeardownStartDate,
         ConfirmedTeardownStartTime,
         ConfirmedExecutionEndDate,
         ConfirmedExecutionEndTime,


         case ConfirmedExecutionStartTime when '240000' then
          cast(cast(concat(ConfirmedExecutionStartDate,cast('235959' as tims))as abap.numc(15)) as timestamp)
          else
          cast(cast(concat(ConfirmedExecutionStartDate , ConfirmedExecutionStartTime)as abap.numc(15)) as timestamp)
          end                                                                as ActualExecutionStartDateTime,

         case ConfirmedExecutionEndTime when '240000' then
          cast(cast(concat(ConfirmedExecutionEndDate,cast('235959' as tims))as abap.numc(15)) as timestamp)
          else
          cast(cast(concat(ConfirmedExecutionEndDate , ConfirmedExecutionEndTime)as abap.numc(15)) as timestamp)
          end                                                                as ActualExecutionEndDateTime,


         //Quantities and UoM

         @Semantics.unitOfMeasure: true
         ConfirmationUnit,
         @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
         ConfirmationYieldQuantity,
         @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
         ConfirmationScrapQuantity,

         case
         when afru.OpConfirmedWorkQuantity1 is not initial then 'X'
         when afru.OpConfirmedWorkQuantity2 is not initial then 'X'
         when afru.OpConfirmedWorkQuantity3 is not initial then 'X'
         when afru.OpConfirmedWorkQuantity4 is not initial then 'X'
         when afru.OpConfirmedWorkQuantity5 is not initial then 'X'
         when afru.OpConfirmedWorkQuantity6 is not initial then 'X'
         else ''
         end                                                                 as ProcOrdConfActyRecgIsPresent,

         afru.OpConfirmedWorkQuantity1,
         // @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit1'

         afru.OpWorkQuantityUnit1,
         _ActivityTexts.WorkCenterActivityText1,

         afru.OpConfirmedWorkQuantity2,
         // @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit2'

         afru.OpWorkQuantityUnit2,
         _ActivityTexts.WorkCenterActivityText2,
         afru.OpConfirmedWorkQuantity3,
         //@Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit3'

         afru.OpWorkQuantityUnit3,
         _ActivityTexts.WorkCenterActivityText3,
         afru.OpConfirmedWorkQuantity4,
         // @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit4'

         afru.OpWorkQuantityUnit4,
         _ActivityTexts.WorkCenterActivityText4,
         afru.OpConfirmedWorkQuantity5,
         //@Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit5'

         afru.OpWorkQuantityUnit5,
         _ActivityTexts.WorkCenterActivityText5,
         afru.OpConfirmedWorkQuantity6,
         //@Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit6'

         afru.OpWorkQuantityUnit6,
         _ActivityTexts.WorkCenterActivityText6,
         afru._LongText.PlainLongText,

         //To Parent

         _ProcOrdMgmtOp
}

where
  afru.ManufacturingOrderCategory = '40';
//and IsReversal                      <> 'X';

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MANUFACTURINGORDER",
"I_MFGORDERCONFIRMATION",
"I_ORDERCONFLONGTEXT",
"I_WORKCENTERACTIVITYTEXTS",
"P_PROCORDEROPERATIONDURN"
],
"ASSOCIATED":
[
"I_PROCORDOPSMGMTWORKLIST",
"I_WORKCENTERACTIVITYTEXTS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/