I_ProbSolvingProcStp

@AbapCatalog.sqlViewName: 'IPRSOLPROCSTP'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter:true 
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Problem-Solving Process Step'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #A },
    representativeKey: 'ProbSolvingProcStp',
    semanticKey:  [ 'ProbSolvingProc', 'ProbSolvingProcStp' ]
}

define view I_ProbSolvingProcStp as select from qprbslvprcstep
  inner join I_ProbSolvingProc as _ProbSolvingProcJ on qprbslvprcstep.probsolvingprocess = _ProbSolvingProcJ.ProbSolvingProc

  association [1..1] to I_ProbSolvingProc as _ProbSolvingProc on $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc
 
 //=== other views

  association [1..1] to I_Language as _Language on $projection.MasterLanguage = _Language.Language
  association [1..1] to I_ProbSolvingProcStpConfign as _ProbSolvingProcStpConfign on  $projection.ProbSolvingProcType = _ProbSolvingProcStpConfign.ProbSolvingProcType and
                                                                                      $projection.ProbSolvingProcStp = _ProbSolvingProcStpConfign.ProbSolvingProcStp
  association [0..1] to I_ProbSolvingProcStpLfcycSts as _ProbSolvingProcStpLfcycSts on $projection.ProbSolvingProcStpLfcycSts = _ProbSolvingProcStpLfcycSts.ProbSolvingProcStpLfcycSts                                                                                    

// Contact card

  association [0..1] to I_UserContactCard as _CreatedByUserContactCard     on $projection.CreatedByUser     = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard as _LastChangedByUserContactCard on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID

{
      @ObjectModel.foreignKey.association: '_ProbSolvingProc'
  key probsolvingprocess      as ProbSolvingProc,
      @ObjectModel.foreignKey.association: '_ProbSolvingProcStpConfign'
  key probsolvingprocessstep  as ProbSolvingProcStp,
      sortnumber              as ProbSolvingProcStpSortNumber,
      _ProbSolvingProcJ.ProbSolvingProcType       as ProbSolvingProcType,

      @ObjectModel.foreignKey.association: '_Language'
      qprbslvprcstep.masterlanguage as MasterLanguage,
      
      @ObjectModel.foreignKey.association: '_ProbSolvingProcStpLfcycSts'
      qprbslvprcstep.statlcycle as ProbSolvingProcStpLfcycSts,
      
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      @Semantics.user.createdBy: true
      created_by              as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      created_on              as ProbSolvingStpCreatedDateTime,
      
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      @Semantics.user.lastChangedBy: true
      changed_by              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      changed_on              as ProbSolvingStpLastChgdDteTime,
      
      /* Step Configuration - Content Area Flags */      
      probsolvingprocstphasteam          as ProbSolvingProcStpHasTeam,
      probsolvingprocstphasprobdesc      as ProbSolvingProcStpHasProbDesc,
      probsolvingprocstphasfreetasks     as ProbSolvingProcStpHasFreeTasks,
      probsolvingprocstphascauses        as ProbSolvingProcStpHasCauses,
      probsolvingprocstphasplndtsks      as ProbSolvingProcStpHasPlndTsks,
      probsolvingprocstphasfnshdtsks     as ProbSolvingProcStpHasFnshdTsks,
      probsolvingprocstphascomments      as ProbSolvingProcStpHasComments,
      probsolvingprocstphasassmt         as ProbSolvingProcStpHasAssmt,
      probsolvingprocstphastimeline      as ProbSolvingProcStpHasTimeLine,
      
//=== exposed associations      

      _ProbSolvingProc,
      _ProbSolvingProcType,
      _Language,
      _ProbSolvingProcStpConfign,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard,
      _ProbSolvingProcStpLfcycSts
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROBSOLVINGPROC",
"QPRBSLVPRCSTEP"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PROBSOLVINGPROC",
"I_PROBSOLVINGPROCSTPCONFIGN",
"I_PROBSOLVINGPROCSTPLFCYCSTS",
"I_PROBSOLVINGPROCTYPE",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_PROBSOLVINGPROC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/