I_PriceChangeCauseText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Origin of Material Price Change - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'PriceChangeCause'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #BASIC
define view entity I_PriceChangeCauseText
  as select from dd07t
  association        to parent I_PriceChangeCause as _PriceChangeCause on $projection.PriceChangeCause = _PriceChangeCause.PriceChangeCause
  association [0..1] to I_Language                as _Language         on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )                    as Language,
      @ObjectModel.foreignKey.association: '_PriceChangeCause'
      @ObjectModel.text.element: ['PriceChangeCauseName']
  key cast( dd07t.domvalue_l as fml_price_change_origin )                  as PriceChangeCause,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                     as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as fml_price_change_origin_name preserving type ) as PriceChangeCauseName,

      _PriceChangeCause,
      _Language
}

where
      dd07t.domname  = 'FML_PRICE_CHANGE_ORIGIN'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PRICECHANGECAUSE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/