I_PostedMCAJournalEntry

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.sqlViewName: 'IGLEMCAPOST'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@AbapCatalog.preserveKey: true
@Analytics.dataCategory: #CUBE
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.internalName: #LOCAL
@Metadata: {    allowExtensions:true,
                ignorePropagatedAnnotations: true
}
@ObjectModel: { usageType.sizeCategory: #XL,
                usageType.serviceQuality: #D,
                usageType.dataClass: #MIXED
}
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Posted MCA Journal Entry details'
define view I_PostedMCAJournalEntry
  as select from bseg        as _Item
    inner join   bkpf        as _Header    on  _Header.bukrs = _Item.bukrs
                                           and _Header.belnr = _Item.belnr
                                           and _Header.gjahr = _Item.gjahr
    inner join   P_MCAdocref as _mcadocref on  _mcadocref.bukrs = _Item.bukrs
                                           and _mcadocref.belnr = _Item.belnr
                                           and _mcadocref.gjahr = _Item.gjahr
    inner join   P_RUNADMID  as _RUNADM    on _RUNADM.Runid = _mcadocref.Runid
{
  key _Item.bukrs                              as CompanyCode,
  key _Item.belnr                              as AccountingDocument,
  key _Item.gjahr                              as FiscalYear,
  key _Item.buzei                              as AccountingDocumentItem,
      _mcadocref.Runid                         as MCARunID,
      _mcadocref.Rldnr                         as Ledger,
      _RUNADM.Fileid                           as MCAFileID,
      _Header.ldgrp                            as LedgerGroup,
      _Header.blart                            as AccountingDocumentType,
      @Semantics.currencyCode:true
      _Header.hwaer                            as CompanyCodeCurrency,
      @Semantics.currencyCode:true
      _Header.hwae2                            as AdditionalCurrency1,
      @Semantics.currencyCode:true
      _Header.hwae3                            as AdditionalCurrency2,
      @Semantics.currencyCode:true
      _Header.waers                            as AccountCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @Aggregation.default: #SUM
      _Item.dmbtr                              as TransactionAmountInLocalCrcy,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      @Aggregation.default: #SUM
      _Item.dmbe2                              as AmountInAdditionalCurrency1,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      @Aggregation.default: #SUM
      _Item.dmbe3                              as AmountInAdditionalCurrency2,
      @Semantics.amount.currencyCode: 'AccountCurrency'
      @Aggregation.default: #SUM
      _Item.wrbtr                              as PurchasingDocumentAmount,
      _Header.ppnam                            as ParkedByUser,
      _Header.usnam                            as ApprovedByUser,
      _Item.prctr                              as ProfitCenter,
      _Item.kostl                              as CostCenter,
      _Item.segment                            as Segment,
      _Item.vbund                              as TradingPartner,
      _Item.bschl                              as PostingKey,
      _Header.bldat                            as DocumentDate,
      _Header.budat                            as PostingDate,
      _Header.monat                            as FiscalMonth,
      _Header.bktxt                            as AccountingDocumentHeaderText,
      cast( _Header.kursx as abap.dec(28,14) ) as MarketDataExchangeRate,
      _Header.xblnr                            as DocumentReferenceID,
      _Header.stodt                            as PlannedReversalDate,
      _Header.stgrd                            as ReversalReason,
      _Item.hkont                              as GLAccount,
      _Item.pprct                              as PartnerProfitCenter,
      _Item.psegment                           as PartnerSegment,
      _Item.valut                              as ValueDate,
      _Item.sgtxt                              as DocumentItemText,
      _Item.zuonr                              as AssignmentReference
}
where
      _mcadocref.FippCreated != ''
  and _mcadocref.Prccat      = 'MEJ'
  and _mcadocref.DocCategory = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_MCADOCREF",
"P_RUNADMID",
"BKPF",
"BSEG"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/