I_PhysicalAgent

@EndUserText.label: 'Physical Agent'
@Analytics: { dataCategory:#DIMENSION , dataExtraction.enabled:true }
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'PhysicalAgentUUID'
@Metadata.allowExtensions:true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_CreatedByUser','_LastChangedByUser']

@AbapCatalog.sqlViewName: 'IAGTROOT'
@AbapCatalog.compiler.compareFilter: true

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #S,         // < 1000

                         dataClass: #MASTER }       
                         
                         

define view I_PhysicalAgent
  as select from ehhssd_agt_root
  association [1..1] to I_Hazard                as _Hazard            on $projection.Hazard = _Hazard.Hazard
  association [0..*] to I_PhysicalAgentNameText as _Name              on $projection.PhysicalAgentUUID = _Name.PhysicalAgentUUID
  association [0..1] to I_User                  as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                  as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
{
  @ObjectModel.text.association: '_Name'
   key cast ( db_key as ehhss_agent_uuid_ref preserving type ) as PhysicalAgentUUID,
   _Name,

   datetime_cr as CreationDateTime,
   user_id_cr  as CreatedByUser,
   _CreatedByUser,

   datetime_ch as LastChangeDateTime,
   user_id_ch  as LastChangedByUser,
   _LastChangedByUser,

   id          as PhysicalAgentID,
   
   migration_src as PhysicalAgentMigrationSource,

   @ObjectModel.foreignKey.association: '_Hazard'
   hazard      as Hazard,
   @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes:true
   _Hazard

}          
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHHSSD_AGT_ROOT"
],
"ASSOCIATED":
[
"I_HAZARD",
"I_PHYSICALAGENTNAMETEXT",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/