I_PaytRunPlanWeekOfMonthText

@AbapCatalog.sqlViewName: 'IWEEKOFMONTHT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Text of Week in Month'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  usageType: {
    serviceQuality: #B,
    sizeCategory:   #S,
    dataClass:      #META
  },
   resultSet.sizeCategory: #XS
}
@ObjectModel.representativeKey: 'WeekOfMonth'
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view I_PaytRunPlanWeekOfMonthText
  as select from dd07t 
  association to parent I_PaytRunPlanWeekOfMonth as _WeekOfMonth
    on $projection.WeekOfMonth = _WeekOfMonth.WeekOfMonth
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_WeekOfMonth'
      @ObjectModel.text.element: ['WeekOfMonthName']
  key cast( dd07t.domvalue_l as fap_mpp_weekofmonth ) as WeekOfMonth,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      dd07t.ddtext as WeekOfMonthName,
//      cast( dd07t.ddtext as fap_mpp_weekofmonth_name ) as WeekOfMonthName,

      _WeekOfMonth,
      _Language
} 
where dd07t.domname  = 'FAP_MPP_WEEKOFMONTH'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PAYTRUNPLANWEEKOFMONTH"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/