I_PSDProduct

@AbapCatalog:{ sqlViewName: 'IPSDPRODUCT',
               compiler.compareFilter: true,
               preserveKey: true
             }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'PSD Product'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM:{ viewType: #BASIC,
       lifecycle.contract.type: #NONE }
@ObjectModel:{ usageType.serviceQuality: #A,
               usageType.sizeCategory: #M,
               usageType.dataClass: #MASTER }

define view I_PSDProduct
  as select from           /sapapo/psdpro
  --  Join with Mara table enables search based on  Material number
    inner join             mara        as mara        on /sapapo/psdpro.matid = mara.scm_matid_guid22
  --  Join with Location table enables search based on  Location  : Location is not mandatory
    left outer to one join /sapapo/loc as /sapapo/loc on /sapapo/psdpro.locid = /sapapo/loc.locid
{

  key /sapapo/psdpro.def_set_id                       as ProductStorageDefinition,
  key /sapapo/psdpro.storprod_id                      as PSDProduct,
      @Semantics.uuid: true
      /sapapo/psdpro.matid                            as ProductInternalUUID,
      @Semantics.uuid: true
      /sapapo/psdpro.locid                            as LocationUUID,
      /sapapo/psdpro.io_indicator                     as PSDInputOutputHandling,
      @Semantics.quantity.unitOfMeasure: 'PSDProductBaseUnit'
      /sapapo/psdpro.base_qty                         as PSDProductBaseQuantity,
      /sapapo/psdpro.is_gr_dur_applied                as GoodsReceiptDurationIsApplied,
      /sapapo/psdpro.consumption_type                 as PSDConsumptionType,
      @Semantics.uuid: true
      /sapapo/psdpro.compid                           as PSDComponentUUID,
      /sapapo/psdpro.is_set_by_extsys                 as PSDIsSetByExternalSystem,
      @Semantics.user.createdBy: true
      /sapapo/psdpro.user_created                     as CreatedByUserName,
      @Semantics.systemDate.createdAt: true
      /sapapo/psdpro.time_stamp_cre                   as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      /sapapo/psdpro.user_modified                    as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      /sapapo/psdpro.time_stamp_mod                   as LastChangeDateTime,
      @Semantics.unitOfMeasure: true
      /sapapo/psdpro.base_uom                         as PSDProductBaseUnit,
      /sapapo/psdpro.is_tdpp_dur_applied              as PSDIsTDPPDurationApplied,
      @Semantics.quantity.unitOfMeasure: 'PSDActivityDurationOffsetUnit'
      /sapapo/psdpro.duration_offset                  as PSDActivityDurationOffset,
      /sapapo/psdpro.duration_offset_unit             as PSDActivityDurationOffsetUnit,
      /sapapo/psdpro.is_comp_blocked_for_planning     as PSDCompIsBlockedForPlanning,
      mara.matnr                                      as AdvancedPlanningProductName,
      /sapapo/loc.locno                               as Location
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SAPAPO/LOC",
"/SAPAPO/PSDPRO",
"MARA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/