I_PRACostCenter

@EndUserText.label: 'PRA Cost Center'
@Analytics.dataCategory: #DIMENSION
@Metadata.allowExtensions:true
@Analytics.dataExtraction.enabled: true
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPVCOSTCENTER'
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations:true 
@ObjectModel.representativeKey: 'CostCenter'

@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION , #SQL_DATA_SOURCE , #CDS_MODELING_DATA_SOURCE , #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

// This view provides cost center foreign key lookups where controlling area is not passed, rather company

// calling it a basic view so that it can be used in associations


define view I_PRACostCenter
  as select from I_CostCenter
  association [0..*] to I_PRACostCenterText as _Text                on  $projection.CompanyCode     = _Text.CompanyCode
                                                                    and $projection.CostCenter      = _Text.CostCenter
                                                                    and $projection.ValidityEndDate = _Text.ValidityEndDate
  association[1]    to I_ControllingArea    as _ControllingArea     on  $projection.ControllingArea = _ControllingArea.ControllingArea
                                                              
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_CostCenterHierarchyNode'
  key CostCenter,
      @Semantics.businessDate.to: true
  key ValidityEndDate,
  
      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @ObjectModel.foreignKey.association: '_BusinessArea' 
      BusinessArea,
      CostCtrResponsiblePersonName,
      CostCtrResponsibleUser,
      @Semantics.currencyCode: true
      CostCenterCurrency,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      ProfitCenter,
      Department,
      CostingSheet,
      
      /* Associations */
      _BusinessArea,
      _CompanyCode,
      _ControllingArea,
      _CostCenterHierarchyNode,
      _Currency,
      _ProfitCenter,
      _Text
}                    
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTER"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTERHIERARCHYNODE",
"I_CURRENCY",
"I_PRACOSTCENTERTEXT",
"I_PROFITCENTER"
],
"BASE":
[
"I_COSTCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/