I_PPM_ObjectPageChecklistItem

@EndUserText.label: 'Determines Checklist Items'
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPPMCHEKLISTITOP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: 'XL'
@ObjectModel.usageType.dataClass:  #MIXED

@ObjectModel.representativeKey: 'ChecklistItemUUID'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_PPM_ObjectPageChecklistItem
  as select from    I_PPM_ChecklistItem      as ChecklistItem
  
    left outer join I_PPM_ProjectSummaryTask as Project                     on Project.ProjectUUID = ChecklistItem.ProjectUUID
    left outer join I_PPM_Text               as ProjectTextUserLang         on (
               ProjectTextUserLang.LanguageCode                                                                        = $session.system_language
             )
                                                                            and(
                                                                              ProjectTextUserLang.ReferencedObjectUUID = Project.ProjectSummaryTaskUUID
                                                                            )
  
                                                                            
    left outer join I_PPM_Text               as ChecklistItemTextUserLang   on (
         ChecklistItemTextUserLang.LanguageCode                                                                              = $session.system_language
       )
                                                                            and(
                                                                              ChecklistItemTextUserLang.ReferencedObjectUUID = ChecklistItem.ChecklistItemUUID
                                                                            )
    left outer join I_PPM_Text               as ChecklistItemTextMasterLang on (
       ChecklistItemTextMasterLang.LanguageCode                                                                                = Project.MasterLanguage
     )
                                                                            and(
                                                                              ChecklistItemTextMasterLang.ReferencedObjectUUID = ChecklistItem.ChecklistItemUUID
                                                                            )   
    left outer join /s4ppm/cds_dummy                                        on ChecklistItem.ChecklistItemUUID = /s4ppm/cds_dummy.dummy_key

  association [0..1] to I_PPM_SingleResponsibleForObj as _Responsible           on _Responsible.ReferencedObjectUUID = $projection.ChecklistItemUUID
  association [1..1] to I_PPM_ChecklistItemSeverity   as _ChecklistItemSeverity on $projection.ChecklistItemUUID = _ChecklistItemSeverity.ReferencedObjectUUID
{
  key ChecklistItem.ChecklistItemUUID                                    as   ChecklistItemUUID,
      ChecklistItem.ObjectType,
      ChecklistItem.ChecklistParentObjectUUID,
      ChecklistItem.ProjectUUID,
      Project.Project,
      Project.MasterLanguage,
      ChecklistItem.IsApprovalRelevant,
      ChecklistItem.ChecklistItem,
      ChecklistItem.IsChecklistItemChangeable,
      ChecklistItem.FailureModeEfctAnlysDetection,
      ChecklistItem.IsDurationZero,
      ChecklistItem.FailureModeEfctAnlysOccurence,
      ChecklistItem.ChecklistItemProcessingStatus,
      ChecklistItem.ChecklistItemParentProcStatus,
      ChecklistItem.FailureModeEfctAnlysRiskPrioNo,
      ChecklistItem.ProjectVersionNumber,
      ChecklistItem.FailureModeEfctAnlysSeverity,
      ChecklistItem.PriorityCode,
      @Semantics.user.createdBy: true
      ChecklistItem.CreatedByUser,
      @Semantics.businessDate.createdAt: true
      ChecklistItem.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      ChecklistItem.LastChangedByUser,
      @Semantics.businessDate.lastChangedAt: true
      ChecklistItem.LastChangeDateTime,
      ChecklistItem.ActualFinishDate,
      ChecklistItem.LatestFinishDate,
      ChecklistItem.ChecklistItemResult,
      
      case
      when ProjectTextUserLang.ObjectName > '' then
        ProjectTextUserLang.ObjectName
      else Project.ProjectName      
      end                                                                  as   ProjectName,
      ProjectTextUserLang.ObjectName                                       as   ProjectNameUserLanguage,
      Project.ProjectName                                                  as   ProjectNameMasterLanguage,
      
      case
      when ChecklistItemTextUserLang.ObjectName > '' then
      ChecklistItemTextUserLang.ObjectName      
    
      else 
        case
          when ChecklistItemTextMasterLang.ObjectName > '' then
            ChecklistItemTextMasterLang.ObjectName
          else ChecklistItem.ChecklistItem
        end
      end
                                                                           as   ChecklistItemName,
      ChecklistItemTextUserLang.ObjectName                                 as   ChecklistItemNameUserLanguage,
      ChecklistItemTextMasterLang.ObjectName                               as   ChecklistItemNameMasterLangu,
      /s4ppm/cds_dummy.dummy_string                                        as   ProjectElementDescription,
      ChecklistItem._ChecklistItemResult,
      ChecklistItem._ChecklistItemStatus,
      ChecklistItem._CreatedByUser,
      ChecklistItem._IsApprovalRelevant,
      ChecklistItem._LastChangedByUser,
      ChecklistItem._Priority,
      _Responsible,
      _ChecklistItemSeverity,
      ChecklistItem._AuthUser,
      ChecklistItem._AuthSubst,
      ChecklistItem._AuthRole,
      ChecklistItem._AuthGroup
      
} 
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PPM_CHECKLISTITEM",
"I_PPM_PROJECTSUMMARYTASK",
"I_PPM_TEXT",
"/S4PPM/CDS_DUMMY"
],
"ASSOCIATED":
[
"I_INDICATOR",
"I_PPM_AUTHZNBYSUBSTITH",
"I_PPM_AUTHZNBYUSERROLEH",
"I_PPM_AUTHZNBYUSRGRPH",
"I_PPM_AUTHZNBYUSRH",
"I_PPM_CHECKLISTITEMRESULT",
"I_PPM_CHECKLISTITEMSEVERITY",
"I_PPM_PRIORITY",
"I_PPM_PROCESSINGSTATUS",
"I_PPM_SINGLERESPONSIBLEFOROBJ",
"I_PPM_USER"
],
"BASE":
[
"I_PPM_CHECKLISTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/