I_PFMFootprintCategoryText

@EndUserText.label: 'Footprint Category - Text'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

//@Analytics.dataExtraction.enabled: true


@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'PFMFootprintCategory'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     //#EXTRACTION_DATA_SOURCE,

                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
                                     
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass:      #META
@ObjectModel.usageType.sizeCategory:   #S

@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_PFMFootprintCategoryText 
  as select from dd07t 
    association to parent I_PFMFootprintCategory as _PFMFootprintCategory on $projection.PFMFootprintCategory = _PFMFootprintCategory.PFMFootprintCategory
    association [0..1] to I_Language             as _Language             on $projection.Language             = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
  
      @ObjectModel.foreignKey.association: '_PFMFootprintCategory'
      @ObjectModel.text.element: ['PFMFootprintCategoryName']
  key cast( dd07t.domvalue_l as pfmfootprintcategory ) as PFMFootprintCategory,
  
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as pfmfootprintcategoryname preserving type ) as PFMFootprintCategoryName,
      
      _PFMFootprintCategory,
      _Language
} 
where dd07t.domname  = 'PFMFOOTPRINTCATEGORY'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PFMFOOTPRINTCATEGORY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/