I_OutboundDeliveryQuickView

@AbapCatalog.sqlViewName: 'IOUTBDQV'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Outbound Delivery Details'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XXL, dataClass: #MIXED}
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations: true
define view I_OutboundDeliveryQuickView
  as select from I_OutboundDeliveryItem as Item
    inner join   I_OutboundDelivery     as _OutboundDelivery on Item.OutboundDelivery = _OutboundDelivery.OutboundDelivery
  association [0..1] to I_CustomerMaterial_2         as _Customer1 on  $projection.SalesOrganization   = _Customer1.SalesOrganization
                                                                   and $projection.DistributionChannel = _Customer1.DistributionChannel
                                                                   and $projection.Customer            = _Customer1.Customer
                                                                   and $projection.Material            = _Customer1.Product
  association [0..1] to I_UnitOfMeasure              as _BaseUnit  on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _SalesUnit on  $projection.SalesUnit = _SalesUnit.UnitOfMeasure
  association [0..1] to I_SDDocumentCompletePartners as _CP        on  $projection.Delivery = _CP.SDDocument
                                                                   and _CP.PartnerFunction  = 'AP'

{
  key Item.OutboundDelivery                                                                                               as Delivery,
  key Item.OutboundDeliveryItem                                                                                           as DeliveryItem,
      _OutboundDelivery.DeliveryDocumentType                                                                              as DeliveryType,
      _OutboundDelivery.DocumentDate,
      ReferenceSDDocument                                                                                                 as ReferenceDocument,
      ReferenceSDDocumentItem                                                                                             as ReferenceDocumentItem,
      _ReferenceSDDocument.SalesDocumentType,
      Material,
      Plant                                                                                                               as MRPPlant,
      _Plant.PlantName                                                                                                    as MRPPlantName,
      MaterialGroup,
      StorageLocation,
      Batch,
      InventorySpecialStockType,

      _Customer1.MaterialByCustomer,
      @Semantics.unitOfMeasure: true
      _Customer1.BaseUnit                                                                                                 as CustomerMaterialBaseUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      _Customer1.MinDeliveryQtyInBaseUnit,

      _OutboundDelivery.SalesOrganization,
      DistributionChannel,
      Division,
      _OutboundDelivery.CustomerGroup,
      _OutboundDelivery.ShipToParty                                                                                       as Customer,
      _OutboundDelivery._ShipToParty.CustomerName,
      concat_with_space(_CP._ContactPerson.FirstName, _CP._ContactPerson.LastName,1)                                      as ContactPersonName,

      case
      when _CP._Address._DefaultPhoneNumber.PhoneNumber <> ''
      then concat_with_space(_CP._Address._DefaultPhoneNumber.PhoneNumber,_CP._Address._DefaultPhoneNumber.PhoneNumberExtension,1)
      else _OutboundDelivery._ShipToParty._StandardAddress.PhoneNumber
      end                                                                                                                 as ContactPersonPhoneNumber,

      case
      when _CP._Address._DefaultEmailAddress.EmailAddress <> ''
      then _CP._Address._DefaultEmailAddress.EmailAddress
      else _OutboundDelivery._ShipToParty._StandardAddress._DefaultEmailAddress.EmailAddress
      end                                                                                                                 as ContactPersonEmailAddress,

      _OutboundDelivery.DeliveryBlockReason,
      _OutboundDelivery._DeliveryBlockReason._Text[1: Language = $session.system_language ].DeliveryBlockReasonText       as DeliveryBlockReasonText,

      case _OutboundDelivery.DeliveryBlockReason
        when '' then ''
        else 'X'
      end                                                                                                                 as DeliveryIsBlocked,

      _OutboundDelivery.DeliveryPriority,
      _OutboundDelivery._DeliveryPriority._Text[1: Language = $session.system_language ].DeliveryPriorityDesc             as DeliveryPriorityDesc,
      _OutboundDelivery.CompleteDeliveryIsDefined,

      case _OutboundDelivery.CompleteDeliveryIsDefined
        when '' then case DeliveryGroup
          when '000' then case PartialDeliveryIsAllowed
            when '' then 'X'
            when 'D' then 'X'
            else ''
            end
          else ''
          end
        else ''
      end                                                                                                                 as PartialDeliveryIsAllowed,
      @Semantics.booleanIndicator:true 
      case _OutboundDelivery.OverallGoodsMovementStatus
        when 'C' then 'X'
        else ''
      end                                                                                                                 as DeliveryIsPostedGoodsIssue,
      --    MaxNumberOfPartialDelivery,  //not yet available


      // Dates

      _OutboundDelivery.DeliveryDate                                                                                      as RequestedDeliveryDate,
      _OutboundDelivery.LoadingDate                                                                                       as RequestedLoadingDate,
      _OutboundDelivery.PlannedGoodsIssueDate                                                                             as RequestedGoodsIssueDate,
      ProductAvailabilityDate,

      // Quantities and UoM

      @Semantics.unitOfMeasure: true
      BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      ActualDeliveredQtyInBaseUnit                                                                                        as DeliveredQuantityInBaseUnit,
      @Semantics.unitOfMeasure: true
      DeliveryQuantityUnit                                                                                                as SalesUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SalesUnit'
      ActualDeliveryQuantity                                                                                              as DeliveredQuantityInSalesUnit,

      //QuickviewCategory,

      //      '002'                                                                                                               as QuickViewCategory,


      // Associations

      
      _BaseUnit,
      _SalesUnit,
      _OutboundDelivery
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_ADDRESSPHONENUMBER",
"I_CONTACTPERSON",
"I_CUSTOMER",
"I_CUSTOMERMATERIAL_2",
"I_DELIVERYBLOCKREASON",
"I_DELIVERYBLOCKREASONTEXT",
"I_DELIVERYPRIORITY",
"I_DELIVERYPRIORITYTEXT",
"I_OUTBOUNDDELIVERY",
"I_OUTBOUNDDELIVERYITEM",
"I_PLANT",
"I_SALESDOCUMENT",
"I_SDDOCUMENTCOMPLETEPARTNERS"
],
"ASSOCIATED":
[
"I_CUSTOMERMATERIAL_2",
"I_OUTBOUNDDELIVERY",
"I_SDDOCUMENTCOMPLETEPARTNERS",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_OUTBOUNDDELIVERYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/