I_OrderTypeConfirmationParam

@AbapCatalog.sqlViewName: 'IORDTYPECONFPARM'
@AbapCatalog.buffering: {status: #ACTIVE, type: #FULL, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true 
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Type Based Control Parameters for Confirmation'

define view I_OrderTypeConfirmationParam as select from tcoru as tcoru

  association [1..1] to I_Plant     as _Plant     on $projection.Plant     = _Plant.Plant
  association [1..1] to I_OrderType as _OrderType on $projection.OrderType = _OrderType.OrderType

{
      @ObjectModel.foreignKey.association: '_Plant'
  key tcoru.werks as Plant,
      @ObjectModel.foreignKey.association: '_OrderType'
  key tcoru.auart as OrderType,

      // Control Parameters

      tcoru.untli as UnderDeliveryTolIsChecked,
      tcoru.uebli as OverDeliveryTolIsChecked,
      tcoru.ausor as OpenReservationIsFinallyIssued,
      tcoru.aueru as FinalConfirmationType, 
      tcoru.vssmg as QuantitiesAreProposed,
      tcoru.vssle as ActivitiesAreProposed,
      tcoru.vsszt as DatesAreProposed,
      tcoru.vsszu as PersonnelDataAreProposed,
      tcoru.mrflg as SequenceOfOperationsIsChecked,
      tcoru.acomp as AllComponentsAreProposed,
      tcoru.trmzk as FutureDateIsAllowed,
      tcoru.nodat as ActualDateIsNotUpdated,

      // Associations

      _Plant,
      _OrderType
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TCORU"
],
"ASSOCIATED":
[
"I_ORDERTYPE",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/