I_OrderOperationStatusBasic

@AccessControl.authorizationCheck: #CHECK
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions:true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.technicalName: 'IORDOPRSTATUSBSC'
@ObjectModel.representativeKey: 'OrderOperationInternalID'
@ObjectModel.semanticKey: ['OrderInternalID', 'OrderOperationInternalID']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Order Operation Status Basic'
define view entity I_OrderOperationStatusBasic as select from I_OrderOperationBasic as afvc
  left outer to one join I_LogisticsOrder as _Order on afvc.OrderInternalID = _Order.OrderInternalBillOfOperations
  left outer to one join I_StatusObjectStatusBasic as _isCreated   on _isCreated.StatusObject   = afvc.ObjectInternalID and _isCreated.StatusCode   = 'I0001' and _isCreated.StatusIsInactive   = '' // OperationIsCreated

  left outer to one join I_StatusObjectStatusBasic as _isReleased  on _isReleased.StatusObject  = afvc.ObjectInternalID and _isReleased.StatusCode  = 'I0002' and _isReleased.StatusIsInactive  = '' // OperationIsReleased  

  left outer to one join I_StatusObjectStatusBasic as _isConfirmed on _isConfirmed.StatusObject = afvc.ObjectInternalID and _isConfirmed.StatusCode = 'I0009' and _isConfirmed.StatusIsInactive = '' // OperationIsConfirmed

  left outer to one join I_StatusObjectStatusBasic as _isPartConf  on _isPartConf.StatusObject  = afvc.ObjectInternalID and _isPartConf.StatusCode  = 'I0010' and _isPartConf.StatusIsInactive  = '' // OperationIsPartiallyConfirmed

  left outer to one join I_StatusObjectStatusBasic as _isDeleted   on _isDeleted.StatusObject   = afvc.ObjectInternalID and _isDeleted.StatusCode   = 'I0013' and _isDeleted.StatusIsInactive   = '' // OperationIsDeleted

  left outer to one join I_StatusObjectStatusBasic as _isTechCompl on _isTechCompl.StatusObject = afvc.ObjectInternalID and _isTechCompl.StatusCode = 'I0045' and _isTechCompl.StatusIsInactive = '' // OperationIsTechnicallyCompleted

  left outer to one join I_StatusObjectStatusBasic as _isClosed    on _isClosed.StatusObject    = afvc.ObjectInternalID and _isClosed.StatusCode    = 'I0046' and _isClosed.StatusIsInactive    = '' // OperationIsClosed

  left outer to one join I_StatusObjectStatusBasic as _isPartDeliv on _isPartDeliv.StatusObject = afvc.ObjectInternalID and _isPartDeliv.StatusCode = 'I0377' and _isPartDeliv.StatusIsInactive = '' // OperationIsPartiallyDelivered

  left outer to one join I_StatusObjectStatusBasic as _isDelivered on _isDelivered.StatusObject = afvc.ObjectInternalID and _isDelivered.StatusCode = 'I0378' and _isDelivered.StatusIsInactive = '' // OperationIsDelivered

 {
    
    key afvc.OrderInternalID,
    key afvc.OrderOperationInternalID,
    
    afvc.Sequence,
    afvc.SuperiorOperationInternalID,
    cast(afvc.Operation as vdm_vornr preserving type) as Operation,
    afvc.ObjectInternalID,
    
    _Order.OrderID,
    afvc.Plant,
    
    // Status

    case when _isCreated.StatusCode   is null then '' else 'X' end as OperationIsCreated,
    case when _isReleased.StatusCode  is null then '' else 'X' end as OperationIsReleased,
    case when _isConfirmed.StatusCode is null then '' else 'X' end as OperationIsConfirmed,
    case when _isPartConf.StatusCode  is null then '' else 'X' end as OperationIsPartiallyConfirmed,
    case when _isDeleted.StatusCode   is null then '' else 'X' end as OperationIsDeleted,
    case when _isTechCompl.StatusCode is null then '' else 'X' end as OperationIsTechlyCompleted,
    case when _isClosed.StatusCode    is null then '' else 'X' end as OperationIsClosed,
    case when _isPartDeliv.StatusCode is null then '' else 'X' end as OperationIsPartiallyDelivered,
    case when _isDelivered.StatusCode is null then '' else 'X' end as OperationIsDelivered,
    
    afvc._OrderInternalID    
}
where afvc.Sequence = '000000'                               //only standard sequence

  and afvc.SuperiorOperationInternalID = '00000000'         //suboperation is not relevant

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDER",
"I_ORDEROPERATIONBASIC",
"I_STATUSOBJECTSTATUSBASIC"
],
"ASSOCIATED":
[
"I_ORDERINTERNALID"
],
"BASE":
[
"I_ORDEROPERATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/