I_OrderOperationBySemKey

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'OrderOperation'
@ObjectModel.semanticKey: ['OrderID', 'Sequence', 'OrderOperation']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Operation Basic'
// To be used mainly for search/foreign key purposes using the semantic key of order operations


define view entity I_OrderOperationBySemKey
  as select from   I_OrderOperationBasic as afvc
    inner join     I_LogisticsOrderBasic as afko on afko.OrderInternalID = afvc.OrderInternalID
      
  association [1..1] to I_LogisticsOrder         as _Order                    on  $projection.OrderID = _Order.OrderID
  association [0..1] to I_OrderSequenceBySemKey  as _OrderSequence            on  $projection.OrderID  = _OrderSequence.OrderID
                                                                              and $projection.Sequence = _OrderSequence.Sequence
  association [1..1] to I_OrderOperation         as _OrderOperationInternalID on  $projection.OrderInternalID          = _OrderOperationInternalID.OrderInternalID
                                                                              and $projection.OrderOperationInternalID = _OrderOperationInternalID.OrderOperationInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_Order'
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.9}  
  key afko.OrderID,
      @ObjectModel.foreignKey.association: '_OrderSequence'
  key afvc.Sequence,
      @ObjectModel.text.element: ['OperationText', 'OperationSecondText']
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}  
  key afvc.Operation_2 as OrderOperation,

      // Internal Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
      afvc.OrderInternalID,
      @ObjectModel.foreignKey.association: '_OrderOperationInternalID'  
      afvc.OrderOperationInternalID,

      // Text

      @Semantics.text: true
      afvc.OperationText,
      @Semantics.text: true
      afvc.OperationSecondText,

      // Associations

      _Order,
      _OrderSequence,
      _OrderOperationInternalID,
      afvc._OrderInternalID
}
where afvc.SuperiorOperationInternalID = '00000000'; // no suboperation

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDERBASIC",
"I_ORDEROPERATIONBASIC"
],
"ASSOCIATED":
[
"I_LOGISTICSORDER",
"I_ORDERINTERNALID",
"I_ORDEROPERATION",
"I_ORDERSEQUENCEBYSEMKEY"
],
"BASE":
[
"I_ORDEROPERATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/