I_OrderHierarchyNodeText

@AbapCatalog.sqlViewName: 'IFIORDERHNT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Order Hierarchy Node Text'
@ObjectModel.representativeKey: 'HierarchyNode'
//@Analytics: { dataExtraction.enabled: true}

@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #TEXT
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true


define view I_OrderHierarchyNodeText
  as select from hrrp_nodet_n

  association [0..1] to I_Language       as _Language  on $projection.Language = _Language.Language

  association [0..*] to I_OrderHierarchy as _Hierarchy on $projection.OrderHierarchy = _Hierarchy.OrderHierarchy

{
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast ( hrrp_nodet_n.hryid_42 as fis_iorder preserving type ) as OrderHierarchy,
      @ObjectModel.text.element: 'HierarchyNodeText'
  key hrrp_nodet_n.hrynode                   as HierarchyNode,
      @Semantics.businessDate.to: true
  key hrrp_nodet_n.hryvalto                  as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet_n.spras                     as Language,
      //  hrrp_nodet.hryver   as HierarchyVersion,

      //  hrrp_nodet.parnode as ParentNode,

      @Semantics.text: true
      hrrp_nodet_n.nodetxt                   as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet_n.nodetxt, 1, 20) as HierarchyNodeShortText,

      @Semantics.businessDate.from: true
      hrrp_nodet_n.hryvalfrom                as ValidityStartDate,
      _Language,
      _Hierarchy
}
where
  hrrp_nodet_n.hrytyp = '0103';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODET_N"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_ORDERHIERARCHY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/