I_OperationSetupGroupText

@AbapCatalog.sqlViewName: 'IPPOPSETUPGRPTXT'
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'OperationSetupGroup'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Setup Group - Text'

define view I_OperationSetupGroupText
  as select from t425t as txt
  association [0..1] to I_Language                    as _Language                    on  $projection.Language = _Language.Language
  association [1..1] to I_Plant                       as _Plant                       on  $projection.Plant = _Plant.Plant
  association [1..1] to I_OperationSetupGroupCategory as _OperationSetupGroupCategory on  $projection.Plant                       = _OperationSetupGroupCategory.Plant
                                                                                      and $projection.OperationSetupGroupCategory = _OperationSetupGroupCategory.OperationSetupGroupCategory
{
      @ObjectModel.foreignKey.association: '_Plant'
  key txt.werks as Plant,
      @ObjectModel.foreignKey.association: '_OperationSetupGroupCategory'
  key cast(txt.rfgrp as pph_rfgrp preserving type) as OperationSetupGroupCategory,
      @ObjectModel.text.element: 'OperationSetupGroupName'
  key cast(txt.rfsch as pph_rfsch preserving type) as OperationSetupGroup,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key txt.spras as Language,
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8,ranking: #HIGH}
      @Semantics.text: true
      txt.txt   as OperationSetupGroupName,

      // Associations

      _Plant,
      _OperationSetupGroupCategory,
      _Language
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T425T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_OPERATIONSETUPGROUPCATEGORY",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/