I_OneTimeAccountBP

@EndUserText.label: 'One Time Business Partner - obsolete'
@Analytics: { dataCategory:#DIMENSION}
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IONETIMEBP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AbapCatalog.buffering.type: #NONE
@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.serviceQuality:#A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ObjectModel.representativeKey: 'AccountingDocumentItem'
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_Address']

@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_JournalEntryItemOneTimeData'

define view I_OneTimeAccountBP 

as select from bsec

association [1..1] to I_CompanyCode as _CompanyCode               on  $projection.CompanyCode        = _CompanyCode.CompanyCode

association [0..1] to I_JournalEntry as _AccountingDocument       on  $projection.CompanyCode        = _AccountingDocument.CompanyCode
                                                                  and $projection.AccountingDocument = _AccountingDocument.AccountingDocument
                                                                  and $projection.FiscalYear         = _AccountingDocument.FiscalYear

association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear   on  $projection.FiscalYear  = _FiscalYear.FiscalYear 
                                                                  and $projection.CompanyCode = _FiscalYear.CompanyCode
                                                                  
association [0..1] to I_Address as _Address                       on $projection.AddressID = _Address.AddressID
                                                                            
{
   @ObjectModel.foreignKey.association: '_CompanyCode'
   key bsec.bukrs as CompanyCode,  
   @ObjectModel.foreignKey.association: '_AccountingDocument' 
   key bsec.belnr as AccountingDocument,
   @ObjectModel.foreignKey.association: '_FiscalYear'
   key bsec.gjahr as FiscalYear,
   key bsec.buzei as AccountingDocumentItem,
       cast(bsec.name1 as ad_name1)   as BusinessPartnerName1,
       cast(bsec.name2 as ad_name2)   as BusinessPartnerName2,
       cast(bsec.name3 as ad_name3)   as BusinessPartnerName3,
       cast(bsec.name4 as ad_name4)   as BusinessPartnerName4,
       bsec.land1 as Country,
       cast(bsec.ort01 as ad_city1)   as CityName,
       bsec.pfach                     as POBox,
       bsec.pstl2                     as POBoxPostalCode,
       bsec.pstlz                     as PostalCode,
       bsec.stkzu                     as IsVATLiable,
       bsec.regio                     as Region,
       bsec.stcd1                     as TaxID1,
       bsec.stcd2                     as TaxID2,
       bsec.stcd3                     as TaxID3,
       bsec.stcd4                     as TaxID4,
       bsec.stcd5                     as TaxID5,
       bsec.stras                     as StreetAddressName,
       bsec.fityp                     as ResponsibleType,
       bsec.stcdt                     as TaxNumberType,
       bsec.j_1kftbus                 as BusinessType,
       bsec.j_1kftind                 as IndustryType,
       bsec.anred                     as OneTimeAccountBPSalutationText,
       bsec.adrnr                     as AddressID,
       cast(bsec.stkzn as bu_natural_person) as IsNaturalPerson,
       _CompanyCode,
       _AccountingDocument,
       _FiscalYear,
       _Address 
}                                                             
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BSEC"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_COMPANYCODE",
"I_FISCALYEARFORCOMPANYCODE",
"I_JOURNALENTRY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/