I_NominationDocNumberVH

@AbapCatalog.sqlViewName: 'INOMRDOCNUM'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:{
              usageType.serviceQuality: #B,
              usageType.sizeCategory: #XL,
              usageType.dataClass: #TRANSACTIONAL,
              dataCategory:#VALUE_HELP
                }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Nomination Document Number'
@Consumption.ranked: true
define view I_NominationDocNumberVH
  as select from ekpo
    inner join   ekko on ekpo.ebeln = ekko.ebeln
  association [0..1] to I_Customer as _ShipToParty on $projection.ShipToParty = _ShipToParty.Customer
  association [0..1] to I_Customer as _SoldToParty on $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_Customer as _Customer    on $projection.Customer = _Customer.Customer
  association [0..1] to I_Supplier as _Supplier    on $projection.Supplier = _Supplier.Supplier
{
      @Search.defaultSearchElement: true
      @Search: { ranking: #HIGH, fuzzinessThreshold: 0.8 }
  key ekpo.ebeln                  as NominationReferenceDocument,
      @EndUserText.label: 'Ref. Document Item'
      @Search: { defaultSearchElement: true,
                 ranking: #LOW,
                 fuzzinessThreshold: 0.8 }
  key cast(ebelp as abap.char(6)) as NominationReferenceDocItem,
      //dpp relevant fields added

      ekko.lifnr                  as Supplier,
      ekpo.kunnr                  as Customer,
      @EndUserText.label: 'Ship To Party'
      @Search: { defaultSearchElement: true,
                 ranking: #LOW,
                 fuzzinessThreshold: 0.8 }
      cast(' ' as abap.char(10))  as ShipToParty,
      @EndUserText.label: 'Sold To Party'
      @Search: { defaultSearchElement: true,
                 ranking: #LOW,
                 fuzzinessThreshold: 0.8 }
      cast(' ' as abap.char(10))  as SoldToParty,
      _Customer,
      _ShipToParty,
      _SoldToParty,
      _Supplier
}
union

select from  vbap
  inner join vbak on vbap.vbeln = vbak.vbeln
association [0..1] to I_Customer as _ShipToParty on $projection.ShipToParty = _ShipToParty.Customer
association [0..1] to I_Customer as _SoldToParty on $projection.SoldToParty = _SoldToParty.Customer
association [0..1] to I_Customer as _Customer    on $projection.Customer = _Customer.Customer
association [0..1] to I_Supplier as _Supplier    on $projection.Supplier = _Supplier.Supplier
{
      @Search.defaultSearchElement: true
  key vbak.vbeln                 as NominationReferenceDocument,
  key posnr                      as NominationReferenceDocItem,
      //dpp relevant fields added

      cast(' ' as abap.char(10)) as Supplier,
      cast(' ' as abap.char(10)) as Customer,
      // vbap.oid_ship                     as ShipToParty,

      cast(' ' as abap.char(10)) as ShipToParty,
      vbak.kunnr                 as SoldToParty,
      _Customer,
      _ShipToParty,
      _SoldToParty,
      _Supplier
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EKKO",
"EKPO",
"VBAK",
"VBAP"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/