I_MiscPRTByInternalKey

@AbapCatalog.sqlViewName: 'IPPMISCPRTIK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'ProductionResourceInternalID'
@ObjectModel.semanticKey: 'MiscProductionResourceTool'
@Analytics.dataCategory: #DIMENSION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Miscellaneous PRT by Internal Key'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_MiscPRTByInternalKey
  as select from I_ProdnRsceToolMasterData as PRT
    inner join   crvs_a on  crvs_a.objty = PRT.ProductionResourceType
                        and crvs_a.objid = PRT.ProductionResourceInternalID

  association [0..*] to I_MiscProdnRsceToolText as _Text on  $projection.ProductionResourceType       = _Text.ProductionResourceType
                                                         and $projection.ProductionResourceInternalID = _Text.ProductionResourceInternalID

{
      @ObjectModel.foreignKey.association: '_ProductionResourceType'
  key PRT.ProductionResourceType,
      @ObjectModel.text.association: '_Text'
  key PRT.ProductionResourceInternalID,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      cast(crvs_a.sfhnr as pph_sfhnr preserving type) as MiscProductionResourceTool,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      PRT.ProductionResourceToolGroup1,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      PRT.ProductionResourceToolGroup2,
      PRT.ProductionResourceUsage,
      ProdnRsceToolControlProfile,
      PRT.ChangeNumber,
      ProdnRsceToolStandardTextCode,
      ProdnRsceToolTotQtyCalcFormula,
      ProdnRsceToolUsageQtyCalcFmla,
      StartDateOffsetReferenceCode,
      EndDateOffsetReferenceCode,
      // Reference Indicators

      EndDateOffsetDurnIsReferenced,
      StartDateOffstDurnIsReferenced,
      EndDteOffstRefCodeIsReferenced,
      StartDateOffsetRefCodeIsRefcd,
      PRTTotQtyCalcFmlaIsReferenced,
      PRTUsgeQtyCalcFmlaIsReferenced,
      PRTControlProfileIsReferenced,
      PRTStdTextCodeIsReferenced,

      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      StartDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      StartDateOffsetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      EndDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      EndDateOffsetDurationUnit,

      // Admin

      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,

      PRT.MiscPRTAuthorizationGroup,

      // Associations

      _ProductionResourceType,
      _Text,
      _ProdnRsceToolGroup1,
      _ProdnRsceToolGroup2,
      _ProductionResourceUsage,
      _ProdnRsceToolControlProfile,
      _ProdnRsceToolStandardText,
      _ProdnRsceToolTotQtyCalcFmla,
      _ProdnRsceToolUsageQtyCalcFmla,
      _StartDateOffsetReferenceCode,
      _EndDateOffsetReferenceCode,
      _StartDateOffsetDurationUnit,
      _EndDateOffsetDurationUnit,

      _CreatedByUser,
      _LastChangedByUser,
      _ChangeMaster
}
where
  PRT.ProdnRsceToolCategory = 'S' // Miscellaneous

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODNRSCETOOLMASTERDATA",
"CRVS_A"
],
"ASSOCIATED":
[
"I_CHANGEMASTER",
"I_MISCPRODNRSCETOOLTEXT",
"I_OPERATIONDATEOFFSETREFCODE",
"I_PRODNRSCETOOLCONTROLPROFILE",
"I_PRODNRSCETOOLGROUP",
"I_PRODNRSCETOOLQTYCALCFORMULA",
"I_PRODNRSCETOOLSTANDARDTEXT",
"I_PRODUCTIONRESOURCETYPE",
"I_PRODUCTIONRESOURCEUSAGE",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[
"I_PRODNRSCETOOLMASTERDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/