I_MfgProcgExecBatchStock

@AbapCatalog.sqlViewName: 'IMPEBATCHSTOCK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XXL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Batch Stock in Manufacturing Processing Execution'

define view I_MfgProcgExecBatchStock
  as select from P_MfgProcgExecBatchStock as stock
--    inner join   I_MfgProcgExecBatch    as batch on  batch.Material = stock.Material
--                                                 and batch.Batch    = stock.Batch
      inner join I_BatchDistinct          as batch on  batch.Material = stock.Material
                                                   and batch.Batch    = stock.Batch
                                                   and batch.BatchIsMarkedForDeletion    = ' '
                                                   and batch.MatlBatchIsInRstrcdUseStock = ' '

  association [0..1] to I_SalesDocument           as _SalesDocument     on  $projection.SalesDocument = _SalesDocument.SalesDocument
  association [0..1] to I_SalesDocumentItem       as _SalesDocumentItem on  $projection.SalesDocument     = _SalesDocumentItem.SalesDocument
                                                                        and $projection.SalesDocumentItem = _SalesDocumentItem.SalesDocumentItem
  association [0..1] to I_WBSElementByInternalKey as _WBSElement        on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID  
{
      // Stock Identifier

      @ObjectModel.foreignKey.association: '_Material'
  key stock.Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key stock.Plant,
      @ObjectModel.foreignKey.association: '_StorageLocation'
  key stock.StorageLocation,
--    @ObjectModel.foreignKey.association: '_Batch'
  key cast(stock.Batch                as charg_d     preserving type) as Batch,
      @ObjectModel.foreignKey.association: '_Supplier'
  key cast(stock.Supplier             as lifnr       preserving type) as Supplier,
      @ObjectModel.foreignKey.association: '_SalesDocument'
  key cast(stock.SalesDocument        as co_kdauf    preserving type) as SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem'
  key cast(stock.SalesDocumentItem    as co_kdpos    preserving type) as SalesDocumentItem,
      @ObjectModel.foreignKey.association: '_WBSElement'  
  key cast(stock.WBSElementInternalID as ps_s4_pspnr preserving type) as WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_Customer'
  key cast(stock.Customer             as kunnr       preserving type) as Customer,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
  key stock.InventorySpecialStockType,
      // Unit of measure

      @Semantics.unitOfMeasure
  key stock.MaterialBaseUnit,

      // Quantity

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
--      @DefaultAggregation : #SUM
      stock.VltdUnrestrictedUseStkQty,

      // Associations

      stock._UnitOfMeasure,
      stock._Material,
      stock._Plant,
      stock._StorageLocation,
      stock._Supplier,
      _SalesDocument,
      _SalesDocumentItem,
      _WBSElement,
      stock._Customer,
      stock._InventorySpecialStockType
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHDISTINCT",
"P_MFGPROCGEXECBATCHSTOCK"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_PLANT",
"I_PRODUCT",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[
"P_MFGPROCGEXECBATCHSTOCK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/