I_MfgOrderPickList

@AbapCatalog.sqlViewName: 'IPPMORPICKLIST'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Mfg Order Header (Pick List)'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE

define view I_MfgOrderPickList
  as select from    I_ManufacturingOrder as MfgOrder
    left outer join I_OrderItem          as Item on  Item.OrderID   = MfgOrder.ManufacturingOrder
                                                 and Item.OrderItem = '0001'

  association [1..1] to I_UnitOfMeasure      as _ProductionUnit     on $projection.ProductionUnit = _ProductionUnit.UnitOfMeasure
  association [1..1] to I_ManufacturingOrder as _ManufacturingOrder on $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [1..1] to E_LogisticsOrder     as _Extension          on $projection.ManufacturingOrder = _Extension.OrderID // Extensibility


{

  key MfgOrder.ManufacturingOrder                                 as ManufacturingOrder,

      // Internal Order ID

      MfgOrder.MfgOrderInternalID                                 as OrderInternalBillOfOperations,

      // Internal id for status

      MfgOrder.ObjectInternalID                                   as ManufacturingObject,

      // Order text

      MfgOrder.ManufacturingOrderText                             as ManufacturingOrderText,

      // Plants

      MfgOrder.ProductionPlant                                    as ProductionPlant,
      MfgOrder._ProductionPlant.PlantName                         as PlantName,
      MfgOrder.PlanningPlant                                      as MRPPlant,

      // Material

      MfgOrder.Material                                           as Material,

      // Batch number

      Item.Batch                                                  as Batch,

      // Order type

      MfgOrder.ManufacturingOrderType                             as ManufacturingOrderType,
      MfgOrder.ManufacturingOrderCategory                         as ManufacturingOrderCategory,

      // Production Supervisor

      MfgOrder.ProductionSupervisor                               as ProductionSupervisor,
      MfgOrder._ProductionSupervisor.ProductionSupervisorName     as ProductionSupervisorName,

      MfgOrder.MRPController                                      as MRPController,
      MfgOrder._MRPController.MRPControllerName                   as MRPControllerName,
      MfgOrder.ProductionSchedulingProfile                        as ProductionSchedulingProfile,

      MfgOrder.Reservation                                        as Reservation,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrder.MfgOrderPlannedTotalQty                            as MfgOrderPlannedTotalQty,
      @Semantics.unitOfMeasure: true
      MfgOrder.ProductionUnit                                     as ProductionUnit,

      MfgOrder.MfgOrderScheduledStartDate                         as MfgOrderScheduledStartDate,
      MfgOrder.MfgOrderScheduledEndDate                           as MfgOrderScheduledEndDate,
      MfgOrder.CreationDate                                       as MfgOrderCreationDate,

      // Assignments

      MfgOrder.SalesOrder                                         as SalesOrder,
      MfgOrder.SalesOrderItem                                     as SalesOrderItem,

      _ProductionUnit,
      _ManufacturingOrder // Used by Data Source Extensibility

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MANUFACTURINGORDER",
"I_MRPCONTROLLER",
"I_ORDERITEM",
"I_PLANT",
"I_PRODUCTIONSUPERVISOR"
],
"ASSOCIATED":
[
"E_LOGISTICSORDER",
"I_MANUFACTURINGORDER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/