I_MfgOrderOperationConf

@AbapCatalog.sqlViewName: 'IPPMFGORDOPCONF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_MRPController', '_ProductionSupervisor', '_User', '_LongText']
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'MfgOrderConfirmationCount'
@ObjectModel.semanticKey: ['MfgOrderConfirmation', 'MfgOrderConfirmationCount']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@EndUserText.label: 'Manufacturing Order Operation Confirmation'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_MfgOrderOperationConf
  as select from I_OrderConfirmationBasic as afru
    inner join   I_LogisticsOrder         as aufv on aufv.OrderID = afru.OrderID

  association [1..1] to I_ManufacturingOrder          as _ManufacturingOrder          on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [1..1] to I_MfgOrder                    as _MfgOrder                    on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_MfgOrderSequence            as _MfgOrderSequence            on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [1..1] to I_MfgOrderOperationBasic      as _MfgOrderOperation           on  $projection.OrderInternalBillOfOperations = _MfgOrderOperation.OrderInternalBillOfOperations
                                                                                      and $projection.OrderIntBillOfOperationsItem  = _MfgOrderOperation.OrderIntBillOfOperationsItem
  association [1..1] to I_MfgOrderCategory            as _MfgOrderCategory            on  $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
  association [1..1] to I_MfgOrderType                as _MfgOrderType                on  $projection.ManufacturingOrderType = _MfgOrderType.ManufacturingOrderType
  association [1..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations
  association [1..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID
  association [1..1] to I_Plant                       as _ProductionPlant             on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_BusinessProcess             as _BusinessProcess             on  $projection.ControllingArea = _BusinessProcess.ControllingArea
                                                                                      and $projection.BusinessProcess = _BusinessProcess.BusinessProcess
{
      // Key

      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
  key afru.ConfirmationGroup                                                   as MfgOrderConfirmation,
      @ObjectModel.text.element: ['ConfirmationText']
  key afru.OrderConfirmation                                                   as MfgOrderConfirmationCount,

      // Order and operation data

      @ObjectModel.foreignKey.association: '_MfgOrder'
      cast(afru.OrderID as manufacturingorder preserving type)                 as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      cast(afru.Sequence as manufacturingordersequence preserving type)        as ManufacturingOrderSequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ManufacturingOrderOperation_2'
      cast(afru.OrderOperation as manufacturingorderoperation preserving type) as ManufacturingOrderOperation,   // with conv. exit NUMCV

--    @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      afru.OrderOperation_2                                                    as ManufacturingOrderOperation_2, // w/o conversion exit

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      cast(aufv.OrderCategory as manufacturingordercategory preserving type)   as ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      cast(aufv.OrderType as manufacturingordertype preserving type)           as ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      cast(aufv.Plant as pwwrk preserving type)                                as ProductionPlant,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      cast(aufv.ProductionSupervisor as pph_fevor preserving type)             as ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_MRPController'
      cast(aufv.MRPController as pph_dispo preserving type)                    as MRPController,

      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
      cast(afru.OrderInternalID as orderinternalbillofoperations preserving type)         as OrderInternalBillOfOperations,
      @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      cast(afru.OrderOperationInternalID as orderintbillofoperationsitem preserving type) as OrderIntBillOfOperationsItem,

      // Assignments

      @ObjectModel.foreignKey.association: '_Plant'
      afru.Plant,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      afru.WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      afru. WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_Capacity'
      afru.CapacityInternalID,
      afru.CapacityRequirementSplit,
      @ObjectModel.foreignKey.association: '_ShiftGrouping'
      afru.ShiftGrouping,
--    @ObjectModel.foreignKey.association: '_ShiftDefinition'
      afru.ShiftDefinition,    

      // Short Text

      @Semantics.text: true
      afru.ConfirmationText,
      @ObjectModel.foreignKey.association: '_Language'
      afru.Language,
      @ObjectModel.foreignKey.association: '_LongTextIndicator'
      afru.LongTextExists,
                                              
      // Admin

      @Semantics.systemDate.createdAt: true
      afru.ConfirmationEntryDate as MfgOrderConfirmationEntryDate,
      @Semantics.systemTime.createdAt: true
      afru.ConfirmationEntryTime as MfgOrderConfirmationEntryTime,
      @Semantics.user.createdBy: true
      afru.EnteredByUser,
      @Semantics.systemDate.lastChangedAt: true
      afru.LastChangeDate,
      @Semantics.user.lastChangedBy: true
      afru.LastChangedByUser,
      @Semantics.systemDate.createdAt: true
      afru.ConfirmationExternalEntryDate,
      @Semantics.systemTime.createdAt: true
      afru.ConfirmationExternalEntryTime,
      afru.EnteredByExternalUser,

      // Attributes

      @ObjectModel.foreignKey.association: '_FinalConfirmationType'
      afru.FinalConfirmationType,
      afru.IsFinalConfirmation,
      afru.OpenReservationsIsCleared,
      afru.IsReversed,
      afru.IsReversal,
      afru.CancldMfgOrderConfCount as CancldMfgOrderOpConfCount,
      @ObjectModel.foreignKey.association: '_ConfirmationRecordType'
      afru.OrderConfirmationRecordType,

      // Milestone

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MilestoneConfirmationType'      
      afru.MilestoneIsConfirmed,            // wrong data type for indicators

      afru.MilestoneConfirmationType,
      afru.IsConfirmedByMilestoneConf,
      @ObjectModel.foreignKey.association: '_MilestoneConfirmationGroup'
      afru.MilestoneConfirmationGroup,
      @ObjectModel.foreignKey.association: '_MilestoneConfirmation'
      afru.MilestoneConfirmation,

      // Assignments FI/CO

      @ObjectModel.foreignKey.association: '_BusinessArea'
      aufv.BusinessArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      aufv.CompanyCode,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      aufv.ControllingArea,
--    @ObjectModel.foreignKey.association: '_ProfitCenter'
      aufv.ProfitCenter,
      @ObjectModel.foreignKey.association: '_ProductCostCollector'
      cast(aufv.ProductCostCollector as pkosa_d preserving type) as ProductCostCollector,

      // Assignments HR

      afru.Personnel,
      afru.TimeRecording,
      afru.EmployeeWageType,
      @ObjectModel.foreignKey.association: '_EmployeeWageGroup'
      afru.EmployeeWageGroup,
      @ObjectModel.foreignKey.association: '_EmployeeSuitability'      
      afru.EmployeeSuitability,
      afru.NumberOfEmployees,

      // Dates

      @Semantics.businessDate.at: true
      afru.PostingDate,

      // Time Events

      afru.ConfirmedExecutionStartDate,
      afru.ConfirmedExecutionStartTime,
      afru.ConfirmedSetupEndDate,
      afru.ConfirmedSetupEndTime,
      afru.ConfirmedProcessingStartDate,
      afru.ConfirmedProcessingStartTime,
      afru.ConfirmedProcessingEndDate,
      afru.ConfirmedProcessingEndTime,
      afru.ConfirmedTeardownStartDate,
      afru.ConfirmedTeardownStartTime,
      afru.ConfirmedExecutionEndDate,
      afru.ConfirmedExecutionEndTime,
      afru.ActualForecastEndDate,
      afru.ActualForecastEndTime,

      // Confirmation Quantities and UoM

      @ObjectModel.foreignKey.association: '_VarianceReason'
      afru.VarianceReasonCode,
      @Semantics.unitOfMeasure: true
      afru.ConfirmationUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationReworkQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationTotalQuantity,

      @Semantics.unitOfMeasure: true
      cast(afru.OrderQuantityUnit as productionunit preserving type) as ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      afru.ConfirmedYieldQtyInOrderUnit                              as ConfYieldQtyInProductionUnit,

      @Semantics.unitOfMeasure: true
      afru.OperationUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afru.OpPlannedTotalQuantity,

      // Header Quantities and UoM

      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      cast(aufv.OrderConfirmedYieldQty as co_igmng preserving type)  as MfgOrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      cast(aufv.OrderConfirmedScrapQty as co_iasmg preserving type)  as MfgOrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      aufv.MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      cast((aufv.OrderConfirmedYieldQty + aufv.OrderConfirmedScrapQty + aufv.MfgOrderConfirmedReworkQty) as pph_tmnga) as MfgOrderConfirmedTotalQty,

      // Work Quantities and UoM

      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit1,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit1'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity1,
      afru.NoFurtherOpWorkQuantity1IsExpd,
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit2,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit2'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity2,
      afru.NoFurtherOpWorkQuantity2IsExpd,
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit3,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit3'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity3,
      afru.NoFurtherOpWorkQuantity3IsExpd,
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit4,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit4'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity4,
      afru.NoFurtherOpWorkQuantity4IsExpd,
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit5,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit5'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity5,
      afru.NoFurtherOpWorkQuantity5IsExpd,
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit6,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit6'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity6,
      afru.NoFurtherOpWorkQuantity6IsExpd,

      // Business Process

      @ObjectModel.foreignKey.association: '_BusinessProcess'
      afru.BusinessProcess,
      @Semantics.unitOfMeasure: true
      afru.BusinessProcessEntryUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcessEntryUnit'
      @Aggregation.default: #SUM
      afru.BusinessProcessConfirmedQty,
      afru.NoFurtherBusinessProcQtyIsExpd,
      @Semantics.unitOfMeasure: true
      afru.BusinessProcRemainingQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcRemainingQtyUnit'
      @Aggregation.default: #SUM
      afru.BusinessProcessRemainingQty,

      // Durations

      @Semantics.unitOfMeasure: true
      afru.BreakDurationUnit,
      @Semantics.calendarItem.duration: true
      afru.ConfirmedBreakDuration,

      // Associations

      afru._ConfirmationGroup,
      _ManufacturingOrder,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ManufacturingOrder'
      _MfgOrder,
      _MfgOrderSequence,
      _MfgOrderOperation,
      _MfgOrderCategory,
      _MfgOrderType,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_OrderInternalID'
      _OrdInternalBillOfOperations,
      _OrderInternalID,
      afru._FinalConfirmationType,
      afru._ConfirmationRecordType,
      afru._ConfirmationUnit,
      afru._MilestoneConfirmationGroup,
      afru._MilestoneConfirmation,
      afru._User,
      afru._Language,
      afru._WorkCenterType,
      afru._WorkCenter,
      afru._Plant,
      _ProductionPlant,
      aufv._ProductionSupervisor,
      aufv._MRPController,
      afru._Capacity,
      afru._ShiftGrouping,
      afru._ShiftDefinition,
      aufv._BusinessArea,
      aufv._CompanyCode,
      aufv._ControllingArea,
      aufv._ProfitCenter,
      aufv._ProductCostCollector,
      _BusinessProcess,
      afru._BusinessProcessUnit,
      afru._WorkQuantityUnit1,
      afru._WorkQuantityUnit2,
      afru._WorkQuantityUnit3,
      afru._WorkQuantityUnit4,
      afru._WorkQuantityUnit5,
      afru._WorkQuantityUnit6,
      afru._BreakDurationUnit,
      afru._VarianceReason,
      afru._EmployeeWageGroup,
      afru._EmployeeSuitability,
      afru._Employee,
      afru._LongTextIndicator,   
      afru._LongText  
}
where   afru.OrderOperationInternalID > '00000000' //Conf. on Oper. Level only

  and ( afru.ConfirmationApplicationOrigin = '2'
     or afru.ConfirmationApplicationOrigin = '6'   //Manufacturing Orders only

     or afru.ConfirmationApplicationOrigin = '8'); //including results recording

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDER",
"I_ORDERCONFIRMATIONBASIC"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_BUSINESSPROCESS",
"I_CAPACITY",
"I_COMPANYCODE",
"I_CONFIRMATIONGROUP",
"I_CONFIRMATIONRECORDTYPE",
"I_CONTROLLINGAREA",
"I_EMPLOYEESUITABILITY",
"I_EMPLOYEEWAGEGROUP",
"I_FINALCONFIRMATIONTYPE",
"I_INDICATOR",
"I_LANGUAGE",
"I_MANUFACTURINGORDER",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDEROPERATIONBASIC",
"I_MFGORDERSEQUENCE",
"I_MFGORDERTYPE",
"I_MRPCONTROLLER",
"I_ORDERCONFIRMATION",
"I_ORDERCONFLONGTEXT",
"I_ORDERINTERNALID",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANT",
"I_PRODUCTCOSTCTRLGORDER",
"I_PRODUCTIONSUPERVISOR",
"I_PROFITCENTER",
"I_SHIFTDEFINITION",
"I_SHIFTGROUPING",
"I_UNITOFMEASURE",
"I_USER",
"I_VARIANCEREASON",
"I_WORKCENTER",
"I_WORKCENTERTYPE",
"I_WORKFORCEPERSON"
],
"BASE":
[
"I_LOGISTICSORDER",
"I_ORDERCONFIRMATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/