I_MfgOrderOperationCompCube

@AbapCatalog.sqlViewName: 'IPPMFGORDOPCOMPC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_MRPController', '_AssemblyMRPController', '_ProductionSupervisor']
@Analytics.dataCategory: #CUBE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #ANALYTICAL_CUBE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_PROVIDER]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Operation Component - Cube'

define view I_MfgOrderOperationCompCube
  as select from I_MfgOrderOperationComponent as comp
    inner join   P_PPH_ReportingDate3         as repdate on comp.MatlCompRequirementDate = repdate.ReportingDate

  association [1..1] to I_CalendarDate    as _RequirementDate         on  $projection.MatlCompRequirementDate = _RequirementDate.CalendarDate
  association [0..1] to I_CalendarMonth   as _RequirementDateMonth    on  $projection.RequirementDateMonth = _RequirementDateMonth.CalendarMonth
  association [0..1] to I_CalendarYear    as _RequirementDateYear     on  $projection.RequirementDateYear = _RequirementDateYear.CalendarYear
  association [0..1] to I_WeekDay         as _RequirementDateWeekDay  on  $projection.RequirementDateWeekDay = _RequirementDateWeekDay.WeekDay
  association [0..1] to I_ReportingPeriod as _ReportingPeriod         on  $projection.ReportingPeriod = _ReportingPeriod.ReportingPeriod
  association [0..1] to I_Currency        as _CompanyCodeCurrency     on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_MRPController   as _MRPController           on  $projection.Plant         = _MRPController.Plant
                                                                      and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_MaterialPlant   as _MaterialPlant           on  $projection.Plant    = _MaterialPlant.Plant
                                                                      and $projection.Material = _MaterialPlant.Material
  association [1..1] to I_OrderReservationDocument   as _Reservation  on  $projection.Reservation = _Reservation.Reservation
  association [0..1] to I_WBSElementBasicData        as _WBSElementBasicData        on  $projection.WBSElementInternalID_2 = _WBSElementBasicData.WBSElementInternalID        
  association [1..1] to I_ManufacturingOrder         as _ManufacturingOrder         on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [0..1] to I_ManufacturingOrderSequence as _ManufacturingOrderSequence on  $projection.ManufacturingOrder         = _ManufacturingOrderSequence.ManufacturingOrder
                                                                                    and $projection.ManufacturingOrderSequence = _ManufacturingOrderSequence.ManufacturingOrderSequence                                                
{
      // Key

      @ObjectModel.foreignKey.association: '_Reservation'
  key comp.Reservation,
      @ObjectModel.text.element: ['BOMItemDescription']
  key comp.ReservationItem,
      @ObjectModel.foreignKey.association: '_ReservationDocRecordType'
  key comp.RecordType,

      // Order and operation data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      comp.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      comp.ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ManufacturingOrder'
      comp.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_ManufacturingOrderSequence'
      comp.ManufacturingOrderSequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ManufacturingOrderOperation_2'
      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemanKey'
      comp.ManufacturingOrderOperation,
      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemKey'
      comp.ManufacturingOrderOperation_2,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      comp.ProductionPlant,
      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
      comp.OrderInternalBillOfOperations,
      @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      comp.OrderIntBillOfOperationsItem,
      @ObjectModel.foreignKey.association: '_AssemblyMRPController'
      comp.AssemblyMRPController,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      comp.ProductionSupervisor,      

      // Date and Time

      @Semantics.businessDate.at: true
      comp.MatlCompRequirementDate,
      comp.MatlCompRequirementTime,
      @ObjectModel.foreignKey.association: '_RequirementDateWeekDay'
      repdate.ReportingDateWeekDay as RequirementDateWeekDay,
      @Semantics.calendar.week: true
      repdate.ReportingDateWeek    as RequirementDateWeek,
      @ObjectModel.foreignKey.association: '_RequirementDateMonth'
    //@Semantics.calendar.month: true

      repdate.ReportingDateMonth   as RequirementDateMonth,
      @ObjectModel.foreignKey.association: '_RequirementDateYear'
    //@Semantics.calendar.year: true

      repdate.ReportingDateYear    as RequirementDateYear,
      cast(concat(repdate.ReportingDateYear, repdate.ReportingDateMonth) as vdm_yearmonth) as RequirementDateYearMonth,
      @ObjectModel.foreignKey.association: '_ReportingPeriod'
      cast(repdate.ReportingPeriod as pph_reportingperiod preserving type) as ReportingPeriod,

      // Attributes

      comp.ReservationItemCreationCode,
      comp.ReservationIsFinallyIssued,
      comp.MatlCompIsMarkedForDeletion,
      comp.MaterialComponentIsMissing,
      comp.IsBulkMaterialComponent,
      comp.MatlCompIsMarkedForBackflush,
      comp.MaterialCompIsAlternativeItem,
      comp.MatlCompIsTextItem,
      @ObjectModel.foreignKey.association: '_MatlCompDiscontinuationType'
      comp.MatlCompDiscontinuationType,
      comp.MatlCompIsConfigurable,
      comp.MaterialCompIsCostRelevant,
      comp.MaterialComponentIsClassified,
      comp.MaterialCompIsIntraMaterial,
      comp.UsageProbabilityPercent,

      //Order Status -- no longer required in query, but kept for compatibility reasons

      cast('X' as xfeld preserving type) as OrderIsReleased,
      cast(' ' as xfeld preserving type) as OrderIsConfirmed,
      cast(' ' as xfeld preserving type) as OrderIsDeleted,
      cast(' ' as xfeld preserving type) as OrderIsTechnicallyCompleted,
      cast(' ' as xfeld preserving type) as OrderIsClosed,
      cast(' ' as xfeld preserving type) as OrderIsMarkedForDeletion,

      // Long Text

      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      comp.LongTextLanguageCode,
      comp.LongTextExists,

      // Assignments

      @ObjectModel.foreignKey.association: '_RequirementType'      
      comp.RequirementType,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      comp.MaterialGroup,
      @ObjectModel.foreignKey.association: '_Material'
      comp.Material,
      @ObjectModel.foreignKey.association: '_Plant'
      comp.Plant,
      @ObjectModel.foreignKey.association: '_MRPController'
      cast(_MaterialPlant.MRPController as pph_dispo preserving type) as MRPController,
      @ObjectModel.foreignKey.association: '_SalesOrder'
      comp.SalesOrder,
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      comp.SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementInternalID_2'
      @ObjectModel.foreignKey.association: '_WBSElement'
      comp.WBSElementInternalID,  
      @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      comp.WBSElementInternalID_2,
      comp.ProductConfiguration,
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      comp.ChangeNumber,
      comp.EffectivityParameterVariant,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialComponentSortText'
      comp.SortField,
      comp.MaterialComponentSortText,

      // Assignments BOM

      comp.BillOfMaterialCategory,
      comp.BillOfMaterialInternalID_2                                  as BillOfMaterialInternalID,
      comp.BillOfMaterialVariant,
      @ObjectModel.text.element: ['BOMItemDescription']
      comp.BOMItem                                                     as BillOfMaterialItemNodeNumber,
      comp.BOMItemCategory                                             as BillOfMaterialItemCategory,
      @ObjectModel.text.element: ['BOMItemDescription']
      comp.BillOfMaterialItemNumber_2                                  as BillOfMaterialItemNumber,
      @Semantics.text: true
      comp.BOMItemDescription,
      @ObjectModel.foreignKey.association: '_BOMExplosion'
      comp.BOMExplosionDateID,

      // Assignments Purchasing

      comp.PurchasingInfoRecord,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      comp.PurchasingGroup,
--    @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      comp.PurchaseRequisition,
--    @ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
      comp.PurchaseRequisitionItem,
--    @ObjectModel.foreignKey.association: '_PurchaseOrder'
      comp.PurchaseOrder,
--    @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
      comp.PurchaseOrderItem,
      @Semantics.calendarItem.duration: true
      comp.DeliveryDurationInDays,

      // Goods Movement data

      comp.GoodsMovementIsAllowed,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      comp.StorageLocation,
      comp.Batch,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'     
      comp.DebitCreditCode,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      comp.GoodsMovementType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      comp.InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockValnType'      
      comp.InventorySpecialStockValnType,
      @ObjectModel.foreignKey.association: '_ConsumptionPosting'      
      comp.ConsumptionPosting,
      @ObjectModel.foreignKey.association: '_SupplyArea'
      comp.SupplyArea,
      @Semantics.text: true
      comp.GoodsRecipientName,
      @Semantics.text: true
      comp.UnloadingPointName,
      comp.StockSegment,
      comp.RequirementSegment,

      // Assignments WM

      @ObjectModel.foreignKey.association: '_Warehouse'
      comp.Warehouse,
      comp.StorageType,
      comp.StorageBin,

      // Assignments FI/CO

      @ObjectModel.foreignKey.association: '_BusinessArea'
      comp.BusinessArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      comp.CompanyCode,
      @ObjectModel.foreignKey.association: '_GLAccount'
      comp.GLAccount,
      @ObjectModel.foreignKey.association: '_AccountAssignmentCategory'
      comp.AccountAssignmentCategory,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      comp.FunctionalArea,

      // Batch split data

      @ObjectModel.foreignKey.association: '_BatchSplitType'      
      comp.BatchSplitType,
      comp.BatchMasterReservationItem,

      // Variable-size comp. data

      comp.MaterialCompIsVariableSized,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'VariableSizeItemQuantity'
      cast(comp.NumberOfVariableSizeComponents as int2) as NumberOfVariableSizeComponents,
      @Semantics.unitOfMeasure: true
      comp.VariableSizeItemUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeItemUnit'
      @Aggregation.default: #SUM
      comp.VariableSizeItemQuantity,
      @Semantics.unitOfMeasure: true      
      comp.VariableSizeComponentUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      @Aggregation.default: #SUM
      comp.VariableSizeComponentQuantity,
      comp.FormulaKey,

      // Phantom assembly

      comp.MaterialComponentIsPhantomItem,
      comp.OrderPathValue,
      comp.OrderLevelValue,

      // Lead-Time offset

      comp.LeadTimeOffset,
      @Semantics.unitOfMeasure: true
      comp.OperationLeadTimeOffsetUnit,
      comp.OperationLeadTimeOffset,

      // Quantities and UoM

      comp.QuantityIsFixed,
      comp.IsNetScrap,
      @Aggregation.default: #MAX
      comp.ComponentScrapInPercent,
      @Aggregation.default: #MAX
      comp.OperationScrapInPercent,
      @Semantics.unitOfMeasure: true
      comp.BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      cast(comp.RequiredQuantity as requirementquantity preserving type) as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      comp.WithdrawnQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      (comp.RequiredQuantity - comp.WithdrawnQuantity) as OpenQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      cast((comp.WithdrawnQuantity - comp.RequiredQuantity) as deviationquantity) as DeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      comp.ConfirmedAvailableQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      comp.MaterialCompOriginalQuantity,   
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      cast(division( cast(comp.RequiredQuantity as abap.dec(16,5)),(1 + division(comp.ComponentScrapInPercent,100,3)),3) as originaldemandquantity) as OriginalDemandQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      cast(comp.WithdrawnQuantity -
      (division( cast(comp.RequiredQuantity as abap.dec(16,5)),(1 + division(comp.ComponentScrapInPercent,100,3)),3)) as excessconsumptionquantity) as ExcessConsumptionQuantity,

      @Semantics.unitOfMeasure: true
      comp.EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @Aggregation.default: #SUM
      comp.GoodsMovementEntryQty,

      // Amounts and Currencies

      @Semantics.currencyCode: true
      comp.Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      comp.WithdrawnQuantityAmount,

      @Semantics.currencyCode: true
      cast(comp._CompanyCode.Currency as vdm_v_company_code_currency preserving type) as CompanyCodeCurrency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case
        when comp.Currency = comp._CompanyCode.Currency
          then comp.WithdrawnQuantityAmount
        else  
          cast(currency_conversion( amount => comp.WithdrawnQuantityAmount,
                            source_currency => comp.Currency,
                            round => 'X',
                            target_currency => comp._CompanyCode.Currency,
                            exchange_rate_date => comp.MatlCompRequirementDate,
                            error_handling => 'SET_TO_NULL' ) as wihthdrawnamountcocurcy preserving type)
      end as WithdrawnQtyAmountInCoCodeCry,

      // no longer needed and consumed - but kept for MDES compatibility reasons

      @Consumption.hidden: true
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(1 as usrcurr13) as FreeDefinedAmount1,

      // Associations

      _Reservation,
      comp._ReservationItem,
      comp._ReservationDocRecordType,
      comp._MfgOrderCategory,
      comp._MfgOrderType,
      _ManufacturingOrder,
      _ManufacturingOrderSequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ManufacturingOrder'
      comp._MfgOrder,
      comp._MfgOrderSequence,
      comp._MfgOrderOperation,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MfgOrderOperationBySemKey'
      comp._MfgOrderOperationBySemanKey,
      comp._MfgOrderOperationBySemKey,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_OrderInternalID'
      comp._OrdInternalBillOfOperations,
      comp._OrderInternalID,
      comp._ProductionPlant,
      comp._AssemblyMRPController,
      comp._ProductionSupervisor,
      comp._RequirementType,
      comp._MaterialGroup,
      comp._Material,
      _MaterialPlant,
      comp._Product,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProductPlant2'
      comp._ProductPlant,
      comp._ProductPlant2,
      comp._Plant,
      _MRPController,
      comp._MatlCompDiscontinuationType,
      comp._StorageLocation,
      comp._Batch,
      comp._BatchSplitType,
      comp._DebitCreditCode,
      comp._GoodsMovementType,
      comp._InventorySpecialStockType,
      comp._InventorySpecialStockValnType,
      comp._ConsumptionPosting,
      comp._SupplyArea,
      comp._Warehouse,
      comp._BOMExplosion,
      comp._BOMItemCategory,
      comp._SalesOrder,
      comp._SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_WBSElementBasicData'
      comp._WBSElement,
      _WBSElementBasicData,
      comp._ChangeNumber,
      comp._PurchasingGroup,
      comp._PurchasingInfoRecord,
      comp._PurchaseOrder,
      comp._PurchaseOrderItem,
      comp._PurchaseRequisition,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_PurchaseRequisitionItem2'
      comp._PurchaseRequisitionItem,
      comp._PurchaseRequisitionItem2,
      comp._CompanyCode,
      comp._BusinessArea,
      comp._FunctionalArea,
      comp._GLAccount,
      comp._AccountAssignmentCategory,
      comp._BaseUnit,
      comp._EntryUnit,
      comp._Currency,
      comp._LongTextLanguage,
      _CompanyCodeCurrency,
      _RequirementDate,
      _RequirementDateMonth,
      _RequirementDateYear,      
      _RequirementDateWeekDay,
      _ReportingPeriod
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_MANUFACTURINGORDER",
"I_MATERIALPLANT",
"I_MFGORDEROPERATIONCOMPONENT",
"P_PPH_REPORTINGDATE3"
],
"ASSOCIATED":
[
"I_ACCOUNTASSIGNMENTCATEGORY",
"I_BATCH",
"I_BATCHSPLITTYPE",
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMEXPLOSIONDATE",
"I_BUSINESSAREA",
"I_CALENDARDATE",
"I_CALENDARMONTH",
"I_CALENDARYEAR",
"I_CHANGEMASTER",
"I_COMPANYCODE",
"I_CONSUMPTIONPOSTING",
"I_CURRENCY",
"I_DEBITCREDITCODE",
"I_FUNCTIONALAREA",
"I_GLACCOUNT",
"I_GOODSMOVEMENTTYPE",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_INVTRYSPECIALSTOCKVALNTYPE",
"I_LANGUAGE",
"I_MANUFACTURINGORDER",
"I_MANUFACTURINGORDERSEQUENCE",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_MATERIALPLANT",
"I_MATERIALREQUIREMENTTYPE",
"I_MATLCOMPDISCONTINUATIONTYPE",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDEROPERATIONBASIC",
"I_MFGORDEROPERATIONBYSEMANKEY",
"I_MFGORDEROPERATIONBYSEMKEY",
"I_MFGORDERSEQUENCE",
"I_MFGORDERTYPE",
"I_MRPCONTROLLER",
"I_ORDERINTERNALID",
"I_ORDERRESERVATIONDOCUMENT",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTIONSUPERVISOR",
"I_PRODUCTIONSUPPLYAREA",
"I_PRODUCTPLANT",
"I_PRODUCTPLANTBASIC",
"I_PURCHASEORDERAPI01",
"I_PURCHASEORDERITEMAPI01",
"I_PURCHASEREQUISITION",
"I_PURCHASEREQUISITIONITEMAPI01",
"I_PURCHASEREQUISITION_API01",
"I_PURCHASINGGROUP",
"I_PURCHASINGINFORECORDAPI01",
"I_REPORTINGPERIOD",
"I_RESERVATIONDOCRECORDTYPE",
"I_RESERVATIONDOCUMENTITEM",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_STORAGELOCATION",
"I_UNITOFMEASURE",
"I_WAREHOUSE",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYINTERNALKEY",
"I_WEEKDAY"
],
"BASE":
[
"I_MFGORDEROPERATIONCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/