I_MfgOrderOpComponentPickList

@AbapCatalog.sqlViewName: 'IPPMOROPCOMPPICK'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Mfg Order Component (Pick List)'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE

define view I_MfgOrderOpComponentPickList
  as select from I_MfgOrderOperationComponent as MfgOrderOperationComponent

  association [1..1] to I_Product                    as _Product                    on  $projection.Material = _Product.Product
  association [1..1] to I_MfgOrderOperationComponent as _MfgOrderOperationComponent on  $projection.Reservation     = _MfgOrderOperationComponent.Reservation
                                                                                    and $projection.ReservationItem = _MfgOrderOperationComponent.ReservationItem
                                                                                    and $projection.RecordType      = _MfgOrderOperationComponent.RecordType
  association [1..1] to E_ReservationDocumentItem    as _Extension                  on  $projection.Reservation     = _Extension.Reservation // Extensibility

                                                                                    and $projection.ReservationItem = _Extension.ReservationItem
                                                                                    and $projection.RecordType      = _Extension.RecordType

{
      // key

  key MfgOrderOperationComponent.Reservation                    as Reservation,
  key MfgOrderOperationComponent.ReservationItem                as ReservationItem,
  key MfgOrderOperationComponent.RecordType,

      MfgOrderOperationComponent.ManufacturingOrder             as ManufacturingOrder,

      // operation

      MfgOrderOperationComponent.OrderInternalBillOfOperations  as OrderInternalBillOfOperations,
      MfgOrderOperationComponent.OrderIntBillOfOperationsItem   as OrderIntBillOfOperationsItem,

      // position

      MfgOrderOperationComponent.BOMItemCategory                as BOMItemCategory,
      MfgOrderOperationComponent.BillOfMaterialItemNumber       as BillOfMaterialItemNumber,

      // Date

      MfgOrderOperationComponent.MatlCompRequirementDate        as MatlCompRequirementDate,

      // Material

      MfgOrderOperationComponent.Material                       as Material,

      MfgOrderOperationComponent.BOMItemDescription             as BOMItemDescription,

      MfgOrderOperationComponent.Batch                          as Batch,
      MfgOrderOperationComponent.StorageLocation                as StorageLocation,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MfgOrderOperationComponent.RequiredQuantity               as RequiredQuantity,
      @Semantics.unitOfMeasure: true
      MfgOrderOperationComponent.BaseUnit                       as BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      MfgOrderOperationComponent.GoodsMovementEntryQty          as GoodsMovementEntryQty,
      @Semantics.unitOfMeasure: true
      MfgOrderOperationComponent.EntryUnit                      as EntryUnit,

      // Other

      MfgOrderOperationComponent.MaterialComponentSortText      as MaterialComponentSortText,


      _BaseUnit,
      _MfgOrderOperationComponent,
      _Product
}

where
      GoodsMovementIsAllowed         =  'X'
  and MatlCompIsMarkedForDeletion    =  ' '
  and MatlCompIsMarkedForBackflush   =  ' '
  and ReservationIsFinallyIssued     =  ' '
  and MaterialIsDirectlyProduced     =  ' '
  and MaterialIsDirectlyProcured     =  ' '
  and MaterialComponentIsPhantomItem =  ' '
  and IsBulkMaterialComponent        =  ' '
  and DebitCreditCode                <> 'S'
  and BatchSplitType                 <> '1'
  and RequirementType                <> 'BB'
  and RequiredQuantity               >  WithdrawnQuantity
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDEROPERATIONCOMPONENT"
],
"ASSOCIATED":
[
"E_RESERVATIONDOCUMENTITEM",
"I_MFGORDEROPERATIONCOMPONENT",
"I_PRODUCT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MFGORDEROPERATIONCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/