I_MfgOrderDocumentLinkOriginal

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Document Link Original'
// CDS view for originals used in MfgOrder Document Links


define view entity I_MfgOrderDocumentLinkOriginal
  as select from I_DocumentInfoRecordAttachment as orig
      inner join I_MfgOrderDocumentLink         as docl on  docl.DocumentType       = orig.DocumentInfoRecordDocType
                                                        and docl.DocumentInfoRecord = orig.DocumentInfoRecordDocNumber
                                                        and docl.DocumentVersion    = orig.DocumentInfoRecordDocVersion
                                                        and docl.DocumentPart       = orig.DocumentInfoRecordDocPart
{
      // Key

  key orig.DocumentInfoRecordDocType,
  key orig.DocumentInfoRecordDocNumber,
  key orig.DocumentInfoRecordDocVersion,
  key orig.DocumentInfoRecordDocPart,
  key orig.DocumentIndex,
  key cast(orig.FileUUID as edoc_file_guid preserving type)        as FileUUID,
  key orig.PhysicalDocument,

      // Original admin data

      @Semantics.systemDateTime.createdAt: true
      cast(orig.CreationDateTime as hp_created_at preserving type) as CreationDateTime,
      @Semantics.user.createdBy: true
      orig.CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(orig.ChangedDateTime as hp_changed_at preserving type)  as ChangedDateTime,
      @Semantics.user.lastChangedBy: true
      orig.LastChangedByUser,
      orig.OriginalCheckedOutTime                                  as OriginalCheckedOutDateTime,
      orig.OriginalCheckedOutUser,

      // Original details

      cast(orig.FileName as filen_type preserving type)            as FileName,
      orig.FileSize,
      orig.WorkstationApplication,
      orig.MimeType,
      orig.StorageCategory,
      cast(orig.OriginalIsProtected as pp_cvflag preserving type)  as OriginalIsProtected,
      orig.DocumentTitle,
      orig.DocumentFormat,

      //  LOIO and PHIO Details

      orig.LogicalDocument,
      orig.LogicalDocumentClass,
      orig.PhysicalDocumentClass,
      @Semantics.booleanIndicator: true
      orig.LogicalDocumentIsReference,
      orig.OriginalType,
      orig.PhysicalDocTechnicalStatus,
      @Semantics.text: true
      orig.InternalComment
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DOCUMENTINFORECORDATTACHMENT",
"I_MFGORDERDOCUMENTLINK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/