I_MfgExecEventHistory

@AbapCatalog.sqlViewName: 'IMPEEXECHIST'
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@VDM.private: false
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Manufacturing Execution Event History'
define view I_MfgExecEventHistory
  as select from P_MfgExecEventHistOrder as h
    inner join   I_OrderItem             as OrderItem on  OrderItem.OrderID   = h.ManufacturingOrder
                                                      and OrderItem.OrderItem = '0001'

  association [1..1] to I_MfgOrder                   as _MfgOrder                     on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_MfgOrderCategory           as _MfgOrderCategory             on  $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
  association [1..1] to I_MfgOrderType               as _MfgOrderType                 on  $projection.ManufacturingOrderType = _MfgOrderType.ManufacturingOrderType
  association [0..1] to I_MfgOrderOperation          as _MfgOrderOperation            on  $projection.OrderInternalID          = _MfgOrderOperation.OrderInternalBillOfOperations
                                                                                      and $projection.OrderOperationInternalID = _MfgOrderOperation.OrderIntBillOfOperationsItem
  association [0..1] to I_MfgOrderOperationBasic     as _MfgOrderOperationBasic       on  $projection.OrderInternalID          = _MfgOrderOperationBasic.OrderInternalBillOfOperations
                                                                                      and $projection.OrderOperationInternalID = _MfgOrderOperationBasic.OrderIntBillOfOperationsItem
  association [0..1] to I_OrderOperationBasic        as _OrderOperationBasic          on  $projection.OrderInternalID          = _OrderOperationBasic.OrderInternalID
                                                                                      and $projection.OrderOperationInternalID = _OrderOperationBasic.OrderOperationInternalID
  association [1..1] to I_Plant                      as _ProductionPlant              on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_Plant                      as _MRPPlant                     on  $projection.MRPPlant = _MRPPlant.Plant
  association [0..1] to I_StorageLocation            as _StorageLocation              on  $projection.ProductionPlant = _StorageLocation.Plant
                                                                                      and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..1] to I_MRPController              as _MRPController                on  $projection.MRPPlant      = _MRPController.Plant
                                                                                      and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_ProductionSupervisor       as _ProductionSupervisor         on  $projection.ProductionPlant      = _ProductionSupervisor.Plant
                                                                                      and $projection.ProductionSupervisor = _ProductionSupervisor.ProductionSupervisor
  association [0..1] to I_Defect                     as _Defect                       on  $projection.DefectInternalID = _Defect.DefectInternalID
  association [0..1] to I_Notification               as _Notification                 on  $projection.Notification = _Notification.Notification
  association [0..1] to I_NotificationItem           as _NotificationItem             on  $projection.Notification     = _NotificationItem.Notification
                                                                                      and $projection.NotificationItem = _NotificationItem.NotificationItem
  association [0..1] to I_Material                   as _Material                     on  $projection.Material = _Material.Material
  association [0..1] to I_MaterialText               as _MaterialText                 on  $projection.Material   = _MaterialText.Material
                                                                                      and _MaterialText.Language = $session.system_language
  association [0..1] to I_Material                   as _MaterialComponent            on  $projection.MaterialComponent = _MaterialComponent.Material
  association [0..1] to I_OpActyNtwkInstance         as _OpActyNtwkInstance           on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [0..1] to I_OperationActivityInstance  as _OperationActivityInstance    on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                      and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [0..1] to I_ShopFloorItem              as _ShopFloorItem                on  $projection.ShopFloorItem = _ShopFloorItem.ShopFloorItem
  association [0..1] to I_OperationActivitySFIGroup  as _OperationActivitySFIGroup    on  $projection.OperationActivitySFIGroup = _OperationActivitySFIGroup.OperationActivitySFIGroup
  association [0..1] to I_ShopFloorItem              as _AssembledShopFloorItem       on  $projection.AssembledShopFloorItem = _AssembledShopFloorItem.ShopFloorItem
  association [0..1] to I_MfgProcgExecAction         as _MfgProcgExecAction           on  $projection.MfgProcgExecAction = _MfgProcgExecAction.MfgProcgExecAction
  association [0..1] to I_MfgObjectLogEventType      as _MfgObjectLogEventType        on  $projection.MfgObjectLogEventType = _MfgObjectLogEventType.MfgObjectLogEventType
  association [0..1] to I_Inspectioncatalog          as _MfgActionReasonCodeGroupCtlg on  $projection.MfgActionReasonCodeGroupCtlg = _MfgActionReasonCodeGroupCtlg.InspectionCatalog
  association [0..1] to I_MfgActionReasonCodeGroup   as _MfgActionReasonCodeGroup     on  $projection.MfgActionReasonCodeGroupCtlg = _MfgActionReasonCodeGroup.MfgActionReasonCodeGroupCtlg
                                                                                      and $projection.MfgActionReasonCodeGroup     = _MfgActionReasonCodeGroup.MfgActionReasonCodeGroup
  association [0..1] to I_MfgActionReasonCode        as _MfgActionReasonCode          on  $projection.MfgActionReasonCodeGroupCtlg  = _MfgActionReasonCode.MfgActionReasonCodeGroupCtlg
                                                                                      and $projection.MfgActionReasonCodeGroup      = _MfgActionReasonCode.MfgActionReasonCodeGroup
                                                                                      and $projection.ManufacturingActionReasonCode = _MfgActionReasonCode.ManufacturingActionReasonCode
                                                                                      and _MfgActionReasonCode.Version              = '000001'
  association [0..1] to I_ManufacturingObjectLog     as _ManufacturingObjectLog       on  $projection.MfgExecDocumentCategory        = 9
                                                                                      and $projection.ManufacturingExecutionDocument = _ManufacturingObjectLog.ManufacturingObjectLog
  association [0..1] to I_OpActyConfirmationAction   as _OpActyConfirmationAction     on  $projection.MfgExecDocumentCategory        = 1
                                                                                      and $projection.ManufacturingExecutionDocument = _OpActyConfirmationAction.OperationActivityConfirmation
                                                                                      and $projection.MfgProcgExecAction             = _OpActyConfirmationAction.MfgProcgExecAction
  association [0..1] to I_OpActyNtwkSegmentType      as _OpActyNtwkSegmentType        on  $projection.OpActyNtwkSegmentType = _OpActyNtwkSegmentType.OpActyNtwkSegmentType
  association [0..1] to I_SASSchema                  as _SASSchema                    on  $projection.StatusAndActionSchema = _SASSchema.StatusAndActionSchema
  association [0..1] to I_ShopFloorItemConfirmation  as _ShopFloorItemConfirmation    on  $projection.MfgExecDocumentCategory        = 2
                                                                                      and $projection.ManufacturingExecutionDocument = _ShopFloorItemConfirmation.ShopFloorItemStatusChangeDoc
  association [0..1] to I_MfgOrderComponentAssembly  as _MfgOrderComponentAssembly    on  $projection.MfgExecDocumentCategory        = 3
                                                                                      and $projection.ManufacturingExecutionDocument = _MfgOrderComponentAssembly.AssemblyDocument
                                                                                      and $projection.MfgExecutionDocumentItem       = _MfgOrderComponentAssembly.AssemblyDocumentItem
  association [0..1] to I_UnitOfMeasure              as _ProductionUnit               on  $projection.ProductionUnit = _ProductionUnit.UnitOfMeasure
  association [0..*] to I_PlannedInvtryUsblyCodeText as _PlannedInvtryUsblyCodeText   on  $projection.MfgExecDocumentCategory = 3
                                                                                      and $projection.InventoryUsabilityCode  = _PlannedInvtryUsblyCodeText.PlannedInventoryUsabilityCode
{
  key h.MfgExecDocumentCategory        as MfgExecDocumentCategory,
  key h.ManufacturingExecutionDocument as ManufacturingExecutionDocument,
  key h.MfgExecutionDocumentItem       as MfgExecutionDocumentItem,
  key h.MfgProcgExecAction             as MfgProcgExecAction,
      @ObjectModel.foreignKey.association: '_MfgOrder'
  key h.ManufacturingOrder             as ManufacturingOrder,
  key h.OrderOperationInternalID       as OrderOperationInternalID,
  key h.InspectionCharacteristic       as InspectionCharacteristic,
  key h.InspectionSubsetInternalID     as InspectionSubsetInternalID,
  key h.InspResultValueInternalID      as InspResultValueInternalID,
  key h.ChangeDocDatabaseTableField    as ChangeDocDatabaseTableField,
  key h.ChangeDocument,
      h.MfgBuyOffAction                as MfgBuyOffAction,
      h.Equipment                      as Equipment,
      @ObjectModel.foreignKey.association: '_MfgObjectLogEventType'
      h.MfgObjectLogEventType          as MfgObjectLogEventType,
      @Semantics.businessDate.at: true
      h.EventDateTime                  as EventDateTime,
      h.ShopFloorExecutionUser         as ShopFloorExecutionUser,
      @Semantics.user.createdBy: true
      h.CreatedByUser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      h.CreationDateTime               as CreationDateTime,
      h.ManufacturingOrderText         as ManufacturingOrderText,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      h.ManufacturingOrderType         as ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      h.ManufacturingOrderCategory     as ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      h.ProductionPlant                as ProductionPlant,
      @ObjectModel.foreignKey.association: '_MRPPlant'
      OrderItem.MRPPlant               as MRPPlant,
      h.OrderInternalID                as OrderInternalID,
      @ObjectModel.foreignKey.association: '_Material'
      OrderItem.Material               as Material,
      @Semantics.text: true
      _MaterialText.MaterialName       as MaterialName,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      h.ProductionSupervisor           as ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_MRPController'
      h.MRPController                  as MRPController,
      h.ManufacturingObject            as ManufacturingObject,
      h.ManufacturingOrderSequence     as ManufacturingOrderSequence,
      h.ManufacturingOrderOperation    as ManufacturingOrderOperation,
      h.MfgOrderOperationText          as MfgOrderOperationText,
      h.WorkCenterInternalID           as WorkCenterInternalID,
      h.WorkCenterTypeCode             as WorkCenterTypeCode,
      h.WorkCenterPlant                as WorkCenterPlant,
      h.SortField                      as SortField,
      @ObjectModel.foreignKey.association: '_ShopFloorItem'
      h.ShopFloorItem                  as ShopFloorItem,
      @ObjectModel.foreignKey.association: '_OperationActivitySFIGroup'
      h.OperationActivitySFIGroup      as OperationActivitySFIGroup,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
      h.OpActyNtwkInstance             as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
      h.OpActyNtwkElement              as OpActyNtwkElement,
      h.OperationActivityName          as OperationActivityName,
      @ObjectModel.foreignKey.association: '_OpActyNtwkSegmentType'
      h.OpActyNtwkSegmentType          as OpActyNtwkSegmentType,
      h.OperationActivityNetwork       as OperationActivityNetwork,
      h.OpActyNtwkVersionCounter       as OpActyNtwkVersionCounter,
      h.OpActyNtwkElementExternalID    as OpActyNtwkElementExternalID,
      h.OperationActivity              as OperationActivity,
      h.OperationActyVersionCounter    as OperationActyVersionCounter,
      h.StatusAndActionSchema          as StatusAndActionSchema,
      @ObjectModel.foreignKey.association: '_Defect'
      h.DefectInternalID               as DefectInternalID,
      @ObjectModel.foreignKey.association: '_Notification'
      h.Notification                   as Notification,
      h.NotificationItem               as NotificationItem,
      @ObjectModel.foreignKey.association: '_MaterialComponent'
      h.MaterialComponent              as MaterialComponent,
      h.MaterialComponentName          as MaterialComponentName,
      h.AssembledShopFloorItem         as AssembledShopFloorItem,
      h.AssembledSerialNumber          as AssembledSerialNumber,
      h.AssembledMfrSerialNumber       as AssembledMfrSerialNumber,
      h.AssembledBatch                 as AssembledBatch,
      h.ReplacedShopFloorItem          as ReplacedShopFloorItem,
      h.ReplacedSerialNumber           as ReplacedSerialNumber,
      h.ReplacedBatch                  as ReplacedBatch,
      h.MfgOrderSplitChildOrder        as MfgOrderSplitChildOrder,
      h.BOMExplosionDate               as BOMExplosionDate,
      h.ReferenceDesignatorValue       as ReferenceDesignatorValue,
      h.StorageLocation                as StorageLocation,
      h.InventoryUsabilityCode         as InventoryUsabilityCode,
      h.CompDisassemblyPermanence      as CompDisassemblyPermanence,
      h.MaterialComponentHasReltdComp  as MaterialComponentHasReltdComp,
      h.Defect                         as Defect,
      h.DefectText                     as DefectText,
      h.QltyTaskFollowUpAction         as QltyTaskFollowUpAction,
      h.MfgBuyOffInternalID            as MfgBuyOffInternalID,
      h.MfgBuyOffDescription           as MfgBuyOffDescription,
      h.MfgBuyOffReferencedStep        as MfgBuyOffReferencedStep,
      h.MfgBuyOffAdhocStepDescription  as MfgBuyOffAdhocStepDescription,
      h.MfgBuyOffCycle                 as MfgBuyOffCycle,
      h.RespyMgmtTeamID                as RespyMgmtTeamID,
      h.RespyMgmtFunction              as RespyMgmtFunction,
      @ObjectModel.foreignKey.association: '_MfgActionReasonCode'
      h.MfgActionReasonCodeGroupCtlg   as MfgActionReasonCodeGroupCtlg,
      h.MfgActionReasonCodeGroup       as MfgActionReasonCodeGroup,
      h.ManufacturingActionReasonCode  as ManufacturingActionReasonCode,
      h.InspectionSpecificationText    as InspectionSpecificationText,
      h.ChangeDocPreviousFieldValue    as ChangeDocPreviousFieldValue,
      h.ChangeDocNewFieldValue         as ChangeDocNewFieldValue,
      h.InspectionResultMeanValue      as InspectionResultMeanValue,
      h.InspectionResultMeasuredValue  as InspectionResultMeasuredValue,
      h.CharacteristicAttributeCode    as CharacteristicAttributeCode,
      h.InspectionValuationResult      as InspectionValuationResult,
      h.InspectionSpecificationUnit    as InspectionSpecificationUnit,
      h.InspSpecDecimalPlaces          as InspSpecDecimalPlaces,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #SUM
      h.BusinessProcessConfirmedQty    as BusinessProcessConfirmedQty,
      @Semantics.unitOfMeasure: true
      h.ProductionUnit                 as ProductionUnit,
      h.OpActyActualDurnInSeconds      as OpActyActualDurnInSeconds,
      h.PostingIsRetroactive           as PostingIsRetroactive,
      h.MfgExecutionDocumentNote       as MfgExecutionDocumentNote,
      h.SystemMessageNumber            as SystemMessageNumber,
      h.SystemMessageIdentification    as SystemMessageIdentification,
      h.MfgExecHistMsgVarblField1      as MfgExecHistMsgVarblField1,
      h.MfgExecHistMsgVarblField2      as MfgExecHistMsgVarblField2,
      h.MfgExecHistMsgVarblField3      as MfgExecHistMsgVarblField3,
      h.MfgExecHistMsgVarblField4      as MfgExecHistMsgVarblField4,
      h.MfgProcgExecAttachmentName     as MfgProcgExecAttachmentName,

      _MfgOrder,
      _MfgOrderType,
      _MfgOrderCategory,
      _MfgOrderOperation,
      _MfgOrderOperationBasic,
      _OrderOperationBasic,
      _ProductionPlant,
      _MRPPlant,
      _StorageLocation,
      _Defect,
      _Notification,
      _NotificationItem,
      _Material,
      _MaterialText,
      _MRPController,
      _ProductionSupervisor,
      _MaterialComponent,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _ShopFloorItem,
      _OperationActivitySFIGroup,
      _AssembledShopFloorItem,
      _MfgProcgExecAction,
      _MfgObjectLogEventType,
      _ProductionUnit,
      _MfgActionReasonCodeGroupCtlg,
      _MfgActionReasonCodeGroup,
      _MfgActionReasonCode,
      _ManufacturingObjectLog,
      _OpActyConfirmationAction,
      _OpActyNtwkSegmentType,
      _SASSchema,
      _ShopFloorItemConfirmation,
      _MfgOrderComponentAssembly,
      _PlannedInvtryUsblyCodeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALTEXT",
"I_ORDERITEM",
"P_MFGEXECEVENTHISTORDER"
],
"ASSOCIATED":
[
"I_DEFECT",
"I_INSPECTIONCATALOG",
"I_MANUFACTURINGOBJECTLOG",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MFGACTIONREASONCODE",
"I_MFGACTIONREASONCODEGROUP",
"I_MFGOBJECTLOGEVENTTYPE",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDERCOMPONENTASSEMBLY",
"I_MFGORDEROPERATION",
"I_MFGORDEROPERATIONBASIC",
"I_MFGORDERTYPE",
"I_MFGPROCGEXECACTION",
"I_MRPCONTROLLER",
"I_NOTIFICATION",
"I_NOTIFICATIONITEM",
"I_OPACTYCONFIRMATIONACTION",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKSEGMENTTYPE",
"I_OPERATIONACTIVITYINSTANCE",
"I_OPERATIONACTIVITYSFIGROUP",
"I_ORDEROPERATIONBASIC",
"I_PLANNEDINVTRYUSBLYCODETEXT",
"I_PLANT",
"I_PRODUCTIONSUPERVISOR",
"I_SASSCHEMA",
"I_SHOPFLOORITEM",
"I_SHOPFLOORITEMCONFIRMATION",
"I_STORAGELOCATION",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/