I_MfgBusinessPartnerTP

@AbapCatalog.sqlViewName: 'IMFGBPTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manufacturing Business Partner'
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.modelCategory: #BUSINESS_OBJECT

@ObjectModel.writeActivePersistence: 'mpev_usr_profile'
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: ['MfgBusinessPartner']

@ObjectModel.compositionRoot: true
@ObjectModel.transactionalProcessingEnabled: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define view I_MfgBusinessPartnerTP
  as select from I_MfgBusinessPartner

  association [1..*] to I_MfgBPQualifnCertAssgmtTP as _MfgBPCert   on  $projection.MfgBusinessPartner = _MfgBPCert.MfgBusinessPartner
  association [1..*] to I_MfgBPWrkCtrAssgmtTP      as _MfgBPWrkCtr on  $projection.MfgBusinessPartner = _MfgBPWrkCtr.MfgBusinessPartner
  association [1..1] to I_WorkCenterBySemanticKey  as _WorkCenter  on  $projection.WorkCenter = _WorkCenter.WorkCenter
                                                                   and $projection.Plant      = _WorkCenter.Plant
  association [1..1] to I_Plant                    as _Plant       on  $projection.Plant = _Plant.Plant
{
  key I_MfgBusinessPartner.MfgBusinessPartner,
      @ObjectModel.readOnly: true
      I_MfgBusinessPartner._User.UserDescription,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      I_MfgBusinessPartner.WorkCenter,
      @ObjectModel.foreignKey.association: '_Plant'
      I_MfgBusinessPartner.Plant,
      @Semantics.user.createdBy: true
      I_MfgBusinessPartner.CreatedByUser,
      I_MfgBusinessPartner.CreationDateTime,
      I_MfgBusinessPartner.LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      I_MfgBusinessPartner.LastChangedByUser,
      @ObjectModel.readOnly: true
      I_MfgBusinessPartner._User.UserID,
      // Field for DPP

      @ObjectModel.readOnly: true
      I_MfgBusinessPartner.IsBusinessPurposeCompleted,
      @ObjectModel.readOnly: true
      I_MfgBusinessPartner.AuthorizationGroup,
      I_MfgBusinessPartner.BusinessPartnerUUID,
      // Field for BP Data controller

      @Consumption.hidden:true
      @UI.hidden:true
      I_MfgBusinessPartner.BusinessPartner,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _MfgBPCert,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _MfgBPWrkCtr,
      _WorkCenter,
      _Plant,
      I_MfgBusinessPartner._BusinessPartner
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGBUSINESSPARTNER",
"I_USER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_MFGBPQUALIFNCERTASSGMTTP",
"I_MFGBPWRKCTRASSGMTTP",
"I_PLANT",
"I_WORKCENTERBYSEMANTICKEY"
],
"BASE":
[
"I_MFGBUSINESSPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/