I_MeasuringPointCategory

@AbapCatalog.sqlViewName: 'IMEASPOINTCAT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Measuring Point Category'

@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'MeasuringPointCategory'

@ObjectModel: {
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #C,
    sizeCategory: #S
  }
}
@Metadata.ignorePropagatedAnnotations:true
@Analytics: {dataExtraction.enabled: true }
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE , #EXTRACTION_DATA_SOURCE ]

define view I_MeasuringPointCategory
  as select from t370p
  association [0..*] to I_MeasuringPointCatText as _MeasuringPointCategoryText on $projection.MeasuringPointCategory = _MeasuringPointCategoryText.MeasuringPointCategory
  association [0..1] to I_Inspectioncatalog     as _MeasuringPointCatalog      on $projection.MeasuringPointCatalogType = _MeasuringPointCatalog.InspectionCatalog
{
      @ObjectModel.text.association: '_MeasuringPointCategoryText'
  key mptyp     as MeasuringPointCategory,

      suniq     as MeasurementPositionNumber,

      @ObjectModel.foreignKey.association: '_MeasuringPointCatalog'
      codct     as MeasuringPointCatalogType,

      mrmes     as OnlineMessageType,

      toler     as MsmtDocumentTimeDiffThreshold,

      valid     as MsrgPtCategoryIsValid,

      lfe_ind   as MsrgPtHasLinearAttributes,

      event_ind as MsrgPtCategoryIsBusEvtEnabled,

      // Propagate association(s)

      _MeasuringPointCategoryText,
      _MeasuringPointCatalog

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T370P"
],
"ASSOCIATED":
[
"I_INSPECTIONCATALOG",
"I_MEASURINGPOINTCATTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/