I_MatlProcurementProfileText

@AbapCatalog.sqlViewName: 'IMATLPROCPRFLTXT'
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'MaterialProcurementProfile'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Material Procurement Profile - Text'

define view I_MatlProcurementProfileText
  as select from t460t as txt
  association [1..1] to I_Plant                  as _Plant    on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Language               as _Language on  $projection.Language = _Language.Language
  association [1..1] to I_MatlProcurementProfile as _Profile  on  $projection.MaterialProcurementProfile = _Profile.MaterialProcurementProfile
                                                              and $projection.Plant                      = _Profile.Plant
{
      @ObjectModel.foreignKey.association: '_Profile'
      @ObjectModel.text.element: ['MaterialProcurementProfileName']
  key cast(txt.sobsl as pph_sobsl preserving type)                      as MaterialProcurementProfile,
      @ObjectModel.foreignKey.association: '_Plant'
  key txt.werks                                                         as Plant,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(txt.spras as spras preserving type)                          as Language,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(txt.ltext as materialprocurementprofilename preserving type) as MaterialProcurementProfileName,

      // Associations

      _Profile,
      _Plant,
      _Language
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T460T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_MATLPROCUREMENTPROFILE",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/