I_MatlDocWeightedStock

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IMATWEIGHTSTK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Weighted stock for average calc'
@VDM: {
        private: false,
        viewType: #COMPOSITE,
        lifecycle.contract.type: #SAP_INTERNAL_API
        }
define view I_MatlDocWeightedStock 
with parameters  
    P_StartDate: sydate, 
    @Environment.systemField: #SYSTEM_DATE
    P_EndDate: sydate
as select from I_MaterialDocumentRecord 

  association [0..1] to I_Purreqvaluationarea as _ValuationArea on $projection.valuationarea = _ValuationArea.ValuationArea

{
  key StockIdentifyingMaterial, 
  key Plant,
  key MaterialDocumentYear,
  key MaterialDocument,
  key MaterialDocumentItem,
  key InventorySpecialStockType,
  key InventoryStockType,
  key CostEstimate,
  CompanyCode,
  InventoryValuationType,
  PostingDate,
  GoodsMovementType,
  
  ReversedMaterialDocument,
  GoodsMovementIsCancelled,
  GoodsMovementCancellationType,
  
  _Plant.ValuationArea,
  
  @Semantics.unitOfMeasure: true 
  MaterialBaseUnit,
  
  -- how much weighted time has the posting be effective within the period?
  -- postings assumed at noon --> 0.5
  -- StartDate assumed at early morning, EndDate assumed at late evening --> 1
  -- Perform aggration on top of this view and calculate the SUM over the
  -- weighted property PeriodWeightedStockQuantity to get the average stock
  -- quantity for the aggregation level and the defined period.
  -- This allows HANA to calculate the Average Stock Quantity in linear time.
  @DefaultAggregation:#NONE
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  case
    when PostingDate < $parameters.P_StartDate then cast(MatlStkChangeQtyInBaseUnit as abap.fltp)
    when PostingDate > $parameters.P_EndDate then cast(0 as abap.fltp)
    else cast(MatlStkChangeQtyInBaseUnit as abap.fltp)
        * (1.0 + cast(dats_days_between(PostingDate, $parameters.P_EndDate) as abap.fltp))
        / (1.0 + cast(dats_days_between($parameters.P_StartDate, $parameters.P_EndDate) as abap.fltp))
  end as WgtdPerdStkChgQtyInBaseUnit,
  
  _Plant,
  _ValuationArea,
  _MaterialBaseUnit,
  _CompanyCode
} 
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD",
"I_PLANT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_PLANT",
"I_PURREQVALUATIONAREA",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MATERIALDOCUMENTRECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/