I_MatlBasedCompositionTP

@EndUserText.label: 'Material Based Composition'

@AbapCatalog:
{
  sqlViewName: 'IMCOMPOSITIONTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  --Authority Check for Composition
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser', '_ReleasedByUser']
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel:
{
  --Transactional Annotations for the generated BO
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  transactionalProcessingEnabled: true,
  createEnabled: 'EXTERNAL_CALCULATION',
  updateEnabled: 'EXTERNAL_CALCULATION',
  deleteEnabled: true,
  draftEnabled: true,
  writeDraftPersistence: 'EHFNDW_MCMPS',
  writeActivePersistence: 'EHFNDV_CCMPS',
  entityChangeStateId: 'LastChangeUTCDateTime',
  sapObjectNodeType.name: 'ProductMaterialBsdComposition',
  semanticKey:  [ 'ChmlCompositionUUID' ],
  representativeKey: 'ChmlCompositionUUID',
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

define view I_MatlBasedCompositionTP
  --Select data from basic view 'Composition'
  as select from I_ChmlComposition as MaterialBasedComposition 

  -- Nodes/Detaildata;
  -- Before production material-based components
  association [0..*] to I_MatlBsdBeforeProdnCompTP    as _MatlBsdComponentBeforeProd on $projection.ChmlCompositionUUID = _MatlBsdComponentBeforeProd.ChmlCompositionUUID

  -- After production material-based components
  association [0..*] to I_MatlBsdAfterProdnCompTP     as _MatlBsdComponentAfterProd  on $projection.ChmlCompositionUUID = _MatlBsdComponentAfterProd.ChmlCompositionUUID

  --Produced Substances
  association [0..*] to I_MatlBsdProducedSubstTP      as _ProducedSubstance          on $projection.ChmlCompositionUUID = _ProducedSubstance.ChmlCompositionUUID
  
  --legal deviation 
  association [0..*] to I_MatlBsdCmpstnLglDeviationTP as _LegalDeviation             on $projection.ChmlCompositionUUID = _LegalDeviation.ChmlCompositionUUID
{

      --UUID of composition
      @ObjectModel.mandatory: true
  key ChmlCompositionUUID,

      --Active UUID of composition
      @ObjectModel.readOnly: true
      ChmlCompositionUUID as ActiveChmlCompositionUUID,

      --Create date/time of composition
      @ObjectModel.readOnly: true
      CreationUTCDateTime,

      --Created by user
      @ObjectModel.readOnly: true
      CreatedByUser,

      --Change date/time of composition
      @ObjectModel.readOnly: true
      LastChangeUTCDateTime,

      --Changed by user
      @ObjectModel.readOnly: true
      LastChangedByUser,

      --UUID of chemical compliance info
      ChmlCmplncInfoUUID,

      --Composition Type
      @ObjectModel.mandatory: true
      ChmlCompositionType,

      --Release Status
      @ObjectModel.mandatory: true
      ChmlCompositionStatus,

      --Released by user
      ReleasedByUser,

      -- Valid from date
      ValidityStartDateTime,

      -- Valid to Date
      ValidityEndDateTime,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _MatlBsdComponentBeforeProd,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _MatlBsdComponentAfterProd,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _ProducedSubstance,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _LegalDeviation,

      _CreatedByUser,
      _LastChangedByUser,
      _ReleasedByUser,
      _ChmlCmplncInfo,
      _CompositionStatus,
      _CompositionType
}
where
  ChmlCompositionType = 'MATLBSD2'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCOMPOSITION"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CHMLCOMPOSITIONSTATUS",
"I_CHMLCOMPOSITIONTYPE",
"I_MATLBSDAFTERPRODNCOMPTP",
"I_MATLBSDBEFOREPRODNCOMPTP",
"I_MATLBSDCMPSTNLGLDEVIATIONTP",
"I_MATLBSDPRODUCEDSUBSTTP",
"I_USER"
],
"BASE":
[
"I_CHMLCOMPOSITION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/