I_MaterialTimeDependentStock

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'List of Time Dependent Stock Materials'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
define root view entity I_MaterialTimeDependentStock
  as select from I_MRPMaterial             as Material
    inner join   I_SDMAreaOfResponsibility as SDMAreaOfResponsibility on  Material.MRPController         = SDMAreaOfResponsibility.MRPController
                                                                      and Material.MRPPlant              = SDMAreaOfResponsibility.Plant
                                                                      and SDMAreaOfResponsibility.UserID = $session.user
    inner join   marc                      as MaterialPlant           on  MaterialPlant.matnr = Material.Material
                                                                      and MaterialPlant.werks = Material.MRPPlant
  association [0..1] to mdma                          as _MaterialMRPArea             on  $projection.MRPArea  = _MaterialMRPArea.berid
                                                                                      and $projection.Material = _MaterialMRPArea.matnr
  association [0..1] to I_MRPArea                     as _MRPArea                     on  $projection.MRPArea = _MRPArea.MRPArea
  association [0..1] to I_MRPType                     as _MRPType                     on  $projection.MRPType = _MRPType.MRPType
  association [0..1] to I_ProductPlantAdvPlanEnhanced as _ProductPlantAdvPlanEnhanced on  $projection.Material = _ProductPlantAdvPlanEnhanced.Product
                                                                                      and $projection.MRPPlant = _ProductPlantAdvPlanEnhanced.Plant
  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure               on  _UnitOfMeasure.UnitOfMeasure = Material.BaseUnit
  association [0..1] to I_SafetyStockMethodVH         as _SafetyStockMethod           on  $projection.SafetyStockMethod = _SafetyStockMethod.SafetyStockMethod
  association [0..1] to I_AdvncdPlngSftyStkMethTxt    as _AdvncdPlngSftyStkMeth       on  $projection.advncdplngsftystkmeth = _AdvncdPlngSftyStkMeth.AdvncdPlngSftyStkMeth
                                                                                      and _AdvncdPlngSftyStkMeth.Language   = $session.system_language
  association [0..1] to I_AdvncdPlngTgtStkLvlMethTxt  as _AdvncdPlngTgtStkLvlMeth     on  $projection.advncdplngtgtstklvlmeth = _AdvncdPlngTgtStkLvlMeth.AdvncdPlngTgtStkLvlMeth
                                                                                      and _AdvncdPlngTgtStkLvlMeth.Language   = $session.system_language
{

  key  Material.Material,
  key  Material.MRPPlant,
  key  Material.MRPArea,
       Material.MaterialName,
       Material.PlantName,
       Material.MRPType,
       Material.MRPTypeName,
       Material.MRPAreaText,
       _MRPType.MRPProcedure,
       Material.MRPController,
       _UnitOfMeasure.UnitOfMeasureISOCode,
       _UnitOfMeasure.UnitOfMeasure,
       _UnitOfMeasure.UnitOfMeasureNumberOfDecimals,
       _UnitOfMeasure.UnitOfMeasureDspNmbrOfDcmls,
       case when _MRPArea.MRPAreaCategory = '03' then _MaterialMRPArea.sfty_stk_meth
            when _MRPArea.MRPAreaCategory = '02' then _MaterialMRPArea.sfty_stk_meth
           else MaterialPlant.sfty_stk_meth
        end                as SafetyStockMethod,
       MaterialPlant.ppskz as AdvancedPlanningIsSupported,
       _ProductPlantAdvPlanEnhanced.AdvncdPlngSftyStkMeth,
       _ProductPlantAdvPlanEnhanced.AdvncdPlngTgtStkLvlMeth,
       _AdvncdPlngSftyStkMeth,
       _AdvncdPlngTgtStkLvlMeth,
       _SafetyStockMethod,
       _UnitOfMeasure._ISOCode,
       _MRPType._MRPProcedure
}
where
  _MRPType.MRPProcedure != 'C';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MRPAREA",
"I_MRPMATERIAL",
"I_MRPTYPE",
"I_PRODUCTPLANTADVPLANENHANCED",
"I_SDMAREAOFRESPONSIBILITY",
"I_UNITOFMEASURE",
"MARC",
"MDMA"
],
"ASSOCIATED":
[
"I_ADVNCDPLNGSFTYSTKMETHTXT",
"I_ADVNCDPLNGTGTSTKLVLMETHTXT",
"I_MRPPROCEDURE",
"I_SAFETYSTOCKMETHODVH",
"I_UNITOFMEASUREISOCODE"
],
"BASE":
[
"I_MRPTYPE",
"I_UNITOFMEASURE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/